批处理命令

                                                                                                      批处理命令

批处理，也称为批处理脚本，英文译为BATCH，批处理文件后缀BAT就取的前三个字母。它的构成没有固定格式，只要遵守以下这条就ok了：每一行可视为一个命令，每个命令里可以含多条子命令，从第一行开始执行，直到最后一行结束，它运行的平台是DOS。批处理有一个很鲜明的特点：使用方便、灵活，功能强大，自动化程度高。

例一、将下面的几行命令保存为name.bat然后执行（以后文中只给出代码，保存和执行方式类似）：

ping sz.tencent.com > a.txt

ping sz1.tencent.com >> a.txt

ping sz2.tencent.com >> a.txt

ping sz3.tencent.com >> a.txt

ping sz4.tencent.com >> a.txt

ping sz5.tencent.com >> a.txt

ping sz6.tencent.com >> a.txt

ping sz7.tencent.com >> a.txt

exit

>>的作用，和>的相同，区别是把结果追加到前一行得出的结果的后面，具体的说是下一行，而前面一行命令得出的结果将保留，这样可以使这个a.txt文件越来越大（想到如何搞破坏了？？）。By the way，这个批处理还可以和其他命令结合，搞成完全自动化判断服务器速度的东东，执行后直接显示速度最快的服务器IP。

例二、删除带广告的QQ（a.bat）：

@echo off

if exist C:\Progra~1\Tencent\AD\*.gif del C:\Progra~1\Tencent\AD\*.gif

a. bat

例三，使用批处理脚本查是否中冰河。脚本内容如下：

@echo off

netstat -a -n > a.txt

type a.txt | find "7626" && echo "Congratulations! You have infected GLACIER!"

del a.txt 

pause & exit

这里利用了netstat命令，检查所有的网络端口状态，只需要你清楚常见木马所使用的端口，就能很easy的判断出来是否被人种了冰河。然这不是确定的，因为冰河默认的端口7626，完全可以被人修改。这里介绍的只是方法和思路。这里介绍的是方法和思路稍做改动，就变成可以检查其他木马的脚本了，再改动一下，加进去参数和端口及信息列表文件后，就变成自动检测所有木马的脚本了。

例四，借批处理自动清除系统垃圾，脚本如下：

@echo off

if exist c:\windows\temp\*.* del c:\windows\temp\*.* 

if exist c:\windows\Tempor~1\*.* del c:\windows\Tempor~1\*.* 

if exist c:\windows\History\*.* del c:\windows\History\*.* 

if exist c:\windows\recent\*.* del c:\windows\recent\*.* 

将以上脚本内容保存到autoexec.bat里，每次开机时就把系统垃圾给自动删除了。这里需要注意两点：一、DOS不支持长文件名，所以就出现了Tempor~1这个东东；二、可根据自己的实际情况进行改动，使其符合自己的要求。

例五：

echo @echo off > a.bat 

echo echo This is a pipeline command example. >> a.bat

echo echo It is very easy? >> a.bat

echo echo Believe your self! >> a.bat

echo pause >> a.bat

echo exit >> a.bat

依次在DOS提示符下输入以上各行命令，一行一个回车，将在当前目录下生成一个a.bat文件，里面的内容如下：

@echo off 

echo This is a pipeline command example.

echo It is very easy?

echo Believe your self!

pause

exit

例六：用批处理禁用文件

@echo off   

:start   

set /p filename=请输入要禁用的文件:   

set alldrive=c d e f g   

for %%i in (%alldrive%) do if exist %%i: (dir /s /b %%i:\%filename%)>>"%cd%\file.txt"  

set /p filepath=< file.txt   

echo y|cacls %filepath% /d everyone   

del /f/q file.txt   

echo 如果要继续请按1,退出请按2   

set /p num=请输入相应的数字：   

if /i "%num:~0,1%"=="1" goto start   

if /i "%num:~0,2%"=="2" goto end   

:end  

例七：

@echo off

title IP自动设置 作者：所谓的黑幕

MODE con: COLS=60 lines=20

color 0a

:main

cls

echo 请选择要设置IP地址的方法：

echo.

echo 1、把IP设置为学校用的IP

echo 2、把IP设置为自动获取

echo 3、退出

echo.

@rem 上一句是空一行

set /p choice=您的选择：

echo.

if "%choice%"=="1" goto ip1

if "%choice%"=="2" goto ip2

if "%choice%"=="3" goto end

if "%choice%"=="4" goto test

goto main

:ip1

echo   IP自动设置开始....

echo.

echo 正在设置IP及子网掩码

netsh interface ip set address name="本地连接" source=static addr=192.168.0.5 mask=255.255.255.0

@rem 以上这句是设置IP为192.168.0.5 子网掩码为255.255.255.0

echo 正在设置网关地址

netsh interface ip set address name="本地连接" gateway=192.168.0.1 gwmetric=0

@rem 以上这句为设置网关为192.168.0.1

echo 正在设置DNS服务器

netsh interface ip set dns name="本地连接" source=static addr=211.98.4.1 register=PRIMARY

@rem 以上这句为设置DNS为211.98.4.1

echo 设置完成

echo.

echo  Powered By 所谓的黑幕

echo QQ:84735499

echo.  

CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。" 

if errorlevel 2 goto main

if errorlevel 1 goto end 

:ip2

echo   IP自动设置开始....

echo.

echo 自动获取IP地址....

netsh interface ip set address name = "本地连接" source = dhcp

echo 自动获取DNS服务器....

netsh interface ip set dns name = "本地连接" source = dhcp 

@rem 设置自动获取IP

echo 设置完成

echo.  

echo  Powered By 所谓的黑幕

echo QQ:84735499

echo.  

CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。" 

if errorlevel 2 goto main

if errorlevel 1 goto end 

:test

netsh interface ip set address name = "本地连接" source = dhcp

netsh interface ip set dns name = "本地连接" source = dhcp 

netsh interface ip set wins name = "本地连接" source = dhcp 

CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。" 

if errorlevel 2 goto main

if errorlevel 1 goto end 

:end

* 参数说明： 

1. name：网络连接名称，一般为“本地连接”。你可以在“控制面板”->“网络连接”中看到。 

2. source：获取IP的途径。动态获取，则为dhcp，手动设置，则为static。 

3. addr：要设置的IP地址。 

4. mask：子网掩码。 

5. gateway：网关地址。 

6. gwmetric：网关跃点数，可以设置为整型数值，也可以设置为“自动”：auto。 

7. index：设置的DNS的顺序号。

例八：经典批处理实现自动关机1.BAT

@ECHO off

TITLE 自动关机程序 作者:所谓的黑幕

:start

CLS

COLOR 1f

rem 使用COLOR命令对控制台输出颜色进行更改

MODE con: COLS=41 LINES=18

rem MODE语句为设定窗体的宽和高

set tm1=%time:~0,2%

set tm2=%time:~3,2%

set tm3=%time:~6,2%

ECHO %date% %tm1%点%tm2%分%tm3%秒

ECHO =========================================

ECHO 请选择要进行的操作，然后按回车

ECHO ───────────────

ECHO.

ECHO 1. 定时关机

ECHO 2. 倒计时关机

ECHO 3. 删除定时关机任务

ECHO 4. 查看任务状态

ECHO 5. 刷新当前时间

ECHO 6. 重新启动

ECHO 7. 锁定计算机

ECHO 8. 注销

ECHO 9. 退出

ECHO.

:cho 

SET Choice=

SET /P Choice=选择:

rem 设定变量"Choice"为用户输入的字符

IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%

rem 如果输入大于1位,取第1位,比如输入132,则返回值为1

ECHO.

IF /I "%Choice%"=="1" GOTO SetHour

IF /I "%Choice%"=="2" GOTO outtime

IF /I "%Choice%"=="3" GOTO delAt

IF /I "%Choice%"=="4" GOTO view

IF /I "%Choice%"=="5" GOTO start

IF /I "%Choice%"=="6" GOTO restart

IF /I "%Choice%"=="7" GOTO lock

IF /I "%Choice%"=="8" GOTO logoff

IF /I "%Choice%"=="9" GOTO end

rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号

rem 注意,IF语句需要双等于号

rem 如果输入的字符不是以上数字,将返回重新输入

ECHO 选择无效，请重新输入

ECHO.

GOTO cho

:SetHour

CLS

ECHO.

SET ask=

SET /p ask=是否设定为每天执行关机命令(y/n):

IF NOT "%ask%"=="" SET ask=%ask:~0,1%

IF /I "%ask%"=="y" GOTO yes

IF /I "%ask%"=="n" GOTO no

GOTO SetHour

:yes

ECHO 请指定24小时制式时间,格式为 小时:分钟

SET shutdowntime=

SET /p shutdowntime=输入:

at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul

rem 设定为每周的星期一至星期日,即为每天

IF NOT errorlevel 1 GOTO ok

rem 如果输入正确,就执行ok段的语句

ECHO %shutdowntime% 不是标准的时间格式,请重新输入

ECHO.

GOTO yes

:no

ECHO 请指定24小时制式时间,格式为 小时:分钟

SET shutdowntime=

SET /p shutdowntime=输入:

at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul

IF NOT errorlevel 1 GOTO ok

ECHO %shutdowntime% 不是标准的时间格式,请重新输入

ECHO.

GOTO no

:ok

ECHO.

SET h=%shutdowntime:~1,1%

SET ah=%shutdowntime:~0,1%

SET am=%shutdowntime:~2,2%

SET bh=%shutdowntime:~0,2%

SET bm=%shutdowntime:~3,2%

IF "%h%"==":" (

SET HM=%ah%时%am%分

) ELSE (

SET HM=%bh%时%bm%分)

rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分 

IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭

IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭

ECHO 设定完毕! 按任意键继续...

PAUSE >nul

GOTO start

:outtime

CLS

ECHO.

ECHO 请输入倒计时秒数

ECHO ────────

ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)

SET timed=

SET /p timed=输入:

tsshutdn %timed% /delay:0 /powerdown >nul

IF not errorlevel 1 GOTO ok

ECHO %timed% 是无效的关机时间,请重新输入

ECHO.

GOTO outtime

:delAt

cls

echo.

at /del /y

echo 定时关机任务已取消,按任意键继续...

pause >nul

GOTO start

:view

MODE con: COLS=85 LINES=18

COLOR 70

ECHO.

at

ECHO 按任意键继续...

PAUSE >nul

GOTO start

:restart

shutdown -r -t 0

:lock

rundll32.exe user32.dll,LockWorkStation

goto start

:logoff

logoff

:end

exit

在这个脚本中出现了如下几个命令：@、echo、::、pause、:和goto、%以及if。而这一章就将讲述这几个命令。 

1、@

这个符号大家都不陌生，email的必备符号，它怎么会跑到批处理中呢？呵呵，不是它的错，批处理本来就离不开它，要不就不完美了。它的作用是让执行窗口中不显示它后面这一行的命令本身（多么绕口的一句话！）。呵呵，通俗一点说，行首有了它的话，这一行的命令就不显示了。在例五中，首行的@echo off中，@的作用就是让脚本在执行时不显示后面的echo off部分。这下懂了吧？还是不太懂？没关系，看完echo命令简介，自然就懂了。

2、echo 

中文为“反馈”、“回显”的意思。它其实是一个开关命令，就是说它只有两种状态：打开和关闭。于是就有了echo on和echo off两个命令了。直接执行echo命令将显示当前echo命令状态（off或on）执行echo off将关闭回显，它后面的所有命令都不显示命令本身，只显示执行后的结果，除非执行echo on命令。在例五中，首行的@命令和echo off命令联合起来，达到了两个目的：不显示echo off命令本身，不显示以后各行中的命令本身。的确是有点乱，但你要是练习一下的话，3分钟包会，不会的退钱！

echo命令的另一种用法一：可以用它来显示信息！如例五中倒数第二行，Default BAT file name is START.BAT将在脚本执行后的窗口中显示，而echo命令本身不显示（为什么？？）。

echo命令的另一种用法二：可以直接编辑文本文件。例六：

echo nbtstat -A 192.168.0.1 > a.bat

echo nbtstat -A 192.168.0.2 >> a.bat

echo nbtstat -A 192.168.0.3 >> a.bat

以上脚本内容的编辑方法是，直接是命令行输入，每行一回车。最后就会在当前目录下生成一个a.bat的文件，直接执行就会得到结果。

3、::

这个命令的作用很简单，它是注释命令，在批处理脚本中和rem命令等效。它后面的内容在执行时不显示，也不起任何作用，因为它只是注释，只是增加了脚本的可读性，和C语言中的/*…………*/类似。地球人都能看懂，就不多说了。

4、pause

中文为“暂停”的意思（看看你的workman上），我一直认为它是批处理中最简单的一个命令，单纯、实用。它的作用，是让当前程序进程暂停一下，并显示一行信息：请按任意键继续. . .。在例五中这个命令运用了两次，第一次的作用是让使用者看清楚程序信息，第二个是显示错误的汇编代码信息（其实不是它想显示，而是masm程序在显示错误信息时被暂它停了，以便让你看清楚你的源代码错在哪里）。

5、:和goto

为什么要把这两个命令联合起来介绍？因为它们是分不开的，无论少了哪个或多了哪个都会出错。goto是个跳转命令，:是一个标签。当程序运行到goto时，将自动跳转到:定义的部分去执行了（是不是分不开？）。例五中倒数第5行行首出现一个:，则程序在运行到goto时就自动跳转到:标签定义的部分执行，结果是显示脚本usage（usage就是标签名称）。不难看出，goto命令就是根据这个冒号和标签名称来寻找它该跳转的地方，它们是一一对应的关系。goto命令也经常和if命令结合使用。至于这两个命令具体用法，参照例五。

goto命令的另一种用法一：提前结束程序。在程序中间使用goto命令跳转到某一标签，而这一标签的内容却定义为退出。如：

……

goto end

……

:end 

这里:end在脚本最后一行！其实这个例子很弱智，后面讲了if命令和组合命令你就知道了。

6、%

这个百分号严格来说是算不上命令的，它只是批处理中的参数而已（多个%一起使用的情况除外，以后还将详细介绍），但千万别以为它只是参数就小看了它（看看例五中有多少地方用到它？），少了它批处理的功能就减少了51%了。