常用函数

来源:互联网 发布:湖北网络推广外包公司 编辑:程序博客网 时间:2024/03/29 14:41

<%
 dim db
 db="dbms.mdb"

 '******************************************************************
 '执行sql语句,不返回值,sql语句最好是如下:
 'update 表名 set 字段名=value,字段名=value where 字段名=value
 'delete from 表名 where 字段名=value
 'insert into 表名 (字段名,字段名) values (value,value)
 '******************************************************************

 Sub NoResult(sql)
  dim conn
  dim connstr
  Set conn = Server.CreateObject("ADODB.Connection")
  connstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(""&db&"")
  conn.Open connstr
  conn.execute sql
  conn.close
  set conn=nothing
 End Sub
 
 '*******************************************************************
 '执行select语句,返回recordset对象。该对象只读。也就是不能更新
 '*******************************************************************

 Function Result(sql)
  dim conn
  dim connstr
  dim rcs
  Set conn = Server.CreateObject("ADODB.Connection")
  connstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(""&db&"")
  conn.Open connstr
  Set rcs = Server.CreateObject("ADODB.Recordset")
  rcs.open sql,conn,1,1
  set Result = rcs
 End Function
 
 '*******************************************************************
 ' 弹出对话框
 '*******************************************************************

 Sub alert(message)
  message = replace(message,"'","/'")
  Response.Write ("<script>alert('" & message & "')</script>")
 End Sub
 
 '*******************************************************************
 ' 返回上一页,一般用在判断信息提交是否完全之后
 '*******************************************************************

 Sub GoBack()
  Response.write ("<script>history.go(-1)</script>")
 End Sub
 
 '*******************************************************************
 ' 重定向另外的连接
 '*******************************************************************

 Sub Go(url)
  Response.write ("<script>location.href('" & url & "')</script>")
 End Sub

 '*******************************************************************
 ' 把html标记替换
 '*******************************************************************

function htmlencode2(str)
    dim result
    dim l
    if isNULL(str) then
       htmlencode2=""
       exit function
    end if
    l=len(str)
    result=""
 dim i
 for i = 1 to l
     select case mid(str,i,1)
            case "<"
                 result=result+"&lt;"
            case ">"
                 result=result+"&gt;"
              case chr(13)
                 result=result+"<br>"
            case chr(34)
                 result=result+"&quot;"
            case "&"
                 result=result+"&amp;"
              case chr(32)           
                 'result=result+"&nbsp;"
                 if i+1<=l and i-1>0 then
                    if mid(str,i+1,1)=chr(32) or mid(str,i+1,1)=chr(9) or mid(str,i-1,1)=chr(32) or mid(str,i-1,1)=chr(9)  then                      
                       result=result+"&nbsp;"
                    else
                       result=result+" "
                    end if
                 else
                    result=result+"&nbsp;"                    
                 end if
            case chr(9)
                 result=result+"    "
            case else
                 result=result+mid(str,i,1)
         end select
       next
       htmlencode2=result
   end function

   '*******************************************************************
   ' 检查sql字符串中是否有单引号,有则进行转化
   '*******************************************************************

   function CheckStr(str)
       dim tstr,l,i,ch
         str = Trim(str)
    l=len(str)
    for i=1 to l
        ch=mid(str,i,1)
        if ch="'" then
        tstr=tstr+"'"
     end if
     tstr=tstr+ch
    next
    CheckStr=tstr
   end function
%>

原创粉丝点击