【原】快速将Windows7 配置为无线…

最近有了小米手机，可以无线上网。苦于宿舍无无线覆盖，亦不能配无线路由器，在宿舍无线上网的梦想险些搁浅。很久之前就在网上看到win7可以原生配置无线网卡，正好可以试试来满足我无线上网的愿望。

其实，win7下配置无线站点，非常容易，命令行下一句命令就可搞定。简单的说，分3步。

1. 设置无线站点。命令行下输入：

netsh wlan set hostednetwork mode=allow ssid=YOURWIFINAME key=PASSWORD

将YOURWIFINAME&PASSWORD换成你想要的名称和密码就可以了，注意，password必须是8位。

2. 将该无线站点与本地连接关联起来。即将本地连接的网络共享给刚配置的wifi站点。注意在你的网络连接里面，有两个无线相关的链接，我们需要的是那个virtual wifi miniport。 将本地连接共享给它。如图。

3. 启动无线站点。命令行输入（需管理员权限）：

netsh wlan start hostednetwork

至此， 你的wifi就配置成功了！开启手机的无线功能，畅游wifi世界吧^^ 

需要说明的是，以后每次开机都要执行步骤3。为了方便使用，将上述的步骤1和3写成下面的批处理文件。

==2013/12/23更新 =============================

---------------------------------------- 以下复制到记事本，另存为 set-wifi.cmd, 右键以管理员身份运行即可-------

@ echo off
:: 本程序用来开关无线站点
:: Author:K.T.
:: Date:2013/1/5
:: Modify:2013/12/20

echo.
echo确保使用管理员身份运行本脚本！若否请退出并右击该文件，选择“使用管理员运行”~
echo.
echo  [1]  Set WIFI.设定wifi热点的名称和使用密码。首次配置wifi时使用该选项。
echo  [2]* Start Wlan Wifi
echo  [3]  Stop Wlan Wifi

echo.

set /p Choice=Choose[2]：

if '%Choice%' == ''  goto START
if '%Choice%' == '2' goto START
if '%Choice%' == '3' goto STOP
if '%Choice%' == '1' goto SET
echo.
echo. Error choice.
echo.
pause

goto END

:START
netsh wlan start hostednetwork
goto SUCCESS

:STOP
netsh wlan stop hostednetwork
goto SUCCESS

:SET
::====================================== 编辑下面 ===
set ssid=KT_WIFI
set passwd=wifiwifi
::====================================== 编辑上面 ===

echo.
echo 热点名称：ssid=%ssid%
echo 使用密码：passwd=%passwd%
echo.

echo确认上述结果？若更改请退出程序并打开重新编辑。
pause

netsh wlan set hostednetwork ssid=%ssid% key=%passwd%

set /pChoice=是否已经将正使用的网络共享给了该wifi热点？(1*:是；2:否)，如果不清楚请选否。[1]
if '%Choice%' == ''  goto SUCCESS
if '%Choice%' == '1' goto SUCCESS
if '%Choice%' == '2' goto DETAIL
echo.
echo. Error choice.
echo.
pause
goto END

:DETAIL
echo请仔细看好弹出的消息。并按其说明一步一步操作。
netsh wlan start hostednetwork

msg %username% 本地wifi站点已经设置，它的SSID是 %ssid%。
msg %username% 在本机的“网络连接”中，该wifi站点可能显示为“本地网络*2/*3”等，它的类别是“Microsoft 托管网络适配器”或“ Microsoft virtual wifiminiport”。请记住这个名字，下面配置会用到。
msg %username% 下面开始4步操作，完成最后的配置。
msg %username% 右键点击电脑右下角的联网图标，打开网络和共享中心
msg %username% 在右上部找到“访问类型”为internet的网络，点击它下面的连接（以太网、本地连接、宽带连接等）
msg %username% 在弹出的窗口中点击左下角的属性
msg %username% 点击“共享”选项卡，选中两个复选框，并将“家庭网络连接”选为刚配置的wifi站点,就是刚才让你记住的那一个，点击“确定”保存配置！
msg %username% 配置完成。点击本窗口的确定后，尽情享受刚配置好的wifi热点%ssid% 吧^^

goto SUCCESS

:SUCCESS
echo 操作完成!==========注意看上面的文字当中有没有否定的反馈！！========！！！
pause

:END

--------------------------------------------------------- 脚本到此结束 -------------------------

===老版本

@ echo off
:: 本程序用来开关无线站点
:: Author:K.T.
:: Date:2013/1/5

echo.
echo  [1] Start Wlan Wifi
echo  [2] Stop Wlan Wifi
echo  [3] Set WIFI. 电脑上首次运行时选3先设置wifi。
echo.

set /p Choice=Choose [1]：

if '%Choice%' == ''  goto START
if '%Choice%' == '1' goto START
if '%Choice%' == '2' goto STOP
if '%Choice%' == '3' goto SET
echo.
echo. Error choice.
echo.
pause
goto END

:START
netsh wlan start hostednetwork
goto SUCCESS

:STOP
netsh wlan stop hostednetwork
goto SUCCESS

:SET
::====================================== 编辑下面 ===
set ssid=1#229WIFI
set passwd=wifiwifi
::====================================== 编辑上面 ===

echo.
echo ssid=%ssid%
echo passwd=%passwd%
echo.

echo 确认上述结果？若更改请退出程序并打开重新编辑。
pause

netsh wlan set hostednetwork ssid=%ssid% key=%passwd%

echo.
echo 本地wifi已经设置，再完成一步就配置完成了
echo 右键点击电脑右下角的联网图标，打开网络和共享中心
echo 点击左侧“更改适配器设置”，右键点击本地连接，选属性
echo 在共享选项卡中，选中两个复选框，并将家庭网络连接选为刚配置的wifi站点
echo (注意：不是无线连接，是 Microsoft virtual wifi miniport那一个)
echo.
pause
goto SUCCESS

:SUCCESS
echo Success!

:END

转发至微博

 

转发至微博