批处理

批处理（批处理脚本）

批处理就是对某对象进行批量的处理，通常被认为是一种简化的脚本语言，它应用于DOS和Windows系统中。

批处理文件的扩展名为bat。

目前比较常见的批处理包含两类：DOS批处理和PS批处理。

PS批处理是基于强大的图片编辑软件Photoshop的，用来批量处理图片的脚本；

DOS批处理则是基于DOS命令的，用来自动地批量地执行DOS命令以实现特定操作的脚本。

一、 定义：

批处理是一种简化的脚本语言，也称作宏。它是由DOS或者Windows系统内嵌的命令解释器解释运行。批处理文件具有.bat或者.cmd的扩展名。

批处理文件，或称为批处理程序，是由一条条的DOS命令组成的普通文本文件，可以用记事本直接编辑或用DOS命令创建，也可以用DOS下的文本编辑器Edit.exe来编辑。

二、 命令简介：

1、 echo命令

打开回显或关闭请求回显功能，或显示消息。如果没有任何参数，echo命令将显示当前回显设置。

语法：

echo [{on|off}] [message]

eg:  @echo off / echo hello world

2、 rem命令

注释命令，：：也具有rem的功能，但区别在于当关闭回显时，rem和：：后的内容都不会显示。但是当打开回显时，rem后的内容会显示出来，然而：：后的内容仍然不会显示。

语法：

Rem [注释内容]

eg:  rem 你好

3、 pause命令

暂停命令。运行pause命令时，将显示下面的消息：

Press any key to continue…（或：请按任意键继续…）

eg:  @echo off

:begin

Copy G:*.* d:\back

echo 请插入另一张光盘…

pause

goto begin

4、 call命令

从一个批处理程序调用另一个批处理程序，并且不终止父批处理程序。Call命令接受用作调用目标的标签。如果在脚本或者批处理外使用call，它将不会在命令行起作用。

语法：

Call [路径文件名][标签]

参数

[Drive:}[Path] FileName

5、 start命令

调用外部程序，所有的DOS命令和命令行程序都可以由start命令来调用。

eg:  start calc.exe即可打开Windows的计算器

常用参数：

MIN 开始时窗口最小化

SEPARATE在分开的空间内开始16位的Window程序

HIGH 在HIGH优先级类别开始应用程序

REALTIME 在REALTIME优先级类别开始应用程序

WAIT 启动应用程序并等候它结束

Parameters 传送到命令/程序的参数

6、 goto命令

跳转命令。程序指针跳转到指定的标签，从标签的第一条命令开始继续执行批处理程序。

语法：

：1

start

goto 1

7、 Set命令

显示、设置或删除变量。

显示变量：set或set s前者显示批处理当前已定义的所有变量及其值，后者显示所有以s开头的变量及值。

设置和调用变量：如set aa=abcd，就是把aa定义为abcd。如果要调用这个变量，就把aa两边加上个百分号。

eg:  set aa=abcd

echo %aa%

pause

删除变量：set aa=此句命令即可删除变量aa。若变量aa已被定义，则删除变量aa；若aa尚未定义，则此句命令无实质意义。

批处理的变量是不区分类型的。

三、 符号简介：

1、 回显屏蔽@

表示不显示@后面的命令，在入侵过程中自然不能让对方看到你使用的命令。

2、 重定向1  > ; 与>>

将输出信息重定向到指定的设备或文件。系统默认输出到显示器。

eg:  echo aaaa>a.txt

ehco aaaa>>a.txt

二者区别在于，>会擦出文件中的原有内容，而>>会在文件末尾进行追加。

3、 重定向2  <

将输入信息来源重定向为指定的设备或文件。系统默认从显示器读取输入信息。

eg:  @echo off

echo abcdef

echo 请任意输入字符，以回车结束：

set /p ifo=

cls

echo [从屏幕获得的输入信息]

echo %ifo%

set /p ifo=<a.txt

echo [从文件a.txt获得的输入信息]

echo %ifo%

pause>nul

4、 管道符号 |

将管道符号前面命令的输出结果重定向输出到管道符号后面的命令中去，作为后面命令的输入。

格式：

command_1|command_2

eg: @echo off

echo aaa>a.txt

echo y|del /p a.txt

pause

/p仅显示提示

5、 转义符 ^

将特殊符号转化为一般符号，即剥离特殊符号的特殊地位。特殊符号指：| & > <

比如要输出符号”<;”，直接echo是不可以的，必须修改为echo ^<;

6、 逻辑命令符

逻辑命令符包括：&；、&&、||

& 它的作用是用来连接n个DOS命令，并把这些命令按顺序执行，而不管是否有命令执行失败；

&& 当&&前面的命令成功执行时，执行&&后面的命令，否则不执行；

|| 当||前面的命令失败时，执行||后面的命令，否则不执行。

四、 命令释义：

1、 文件夹管理

cd 显示当前目录名或改变当前目录

md 创建目录

rd 删除一个目录

dir 显示目录中的文件和子目录列表

tree 以图形显示驱动器或路径的文件架结构

path 为可执行文件显示或设置一个搜索路径

copy 复制文件和目录树

2、 文件管理

type显示文本文件的内容

copy 将一份或多份文件复制到另一个位置

del 删除一个或数个文件

move 移动文件并重命名文件和目录

ren 重命名文件

replace 替换文件

attrib 显示或更改文件属性

find 搜索字符串

fc 比较两个文件或两个文件集并显示它们之间的不同

3、 网络命令

ping 进行网络连接测试、名称解析

ftp 文件传输

net 网络命令集及用户管理

telnet 远程登录

ipconfig 显示、修改TCP/IP设置

msg 给用户发送消息

arp 显示、修改局域网的IP地址-物理地址映射列表

4、 系统管理

at 安排在特定日期和时间运行命令和程序

shutdown 立即或定时关机或重启

tskill 结束进程

taskkill 结束进程（比tskill高级，但WinXPHome版中无该命令）

sc 系统服务设置与控制

reg 注册表控制台工具

powercfg控制系统上的电源设置

五、 语句结构：

if语句（选择结构）

if语句实现条件判断，包括字符串比较、存在判断、定义判断等。通过条件判断，if语句即可以实现选择功能。

1．字符串比较

if语句仅能够对两个字符（串）是否相同、先后顺序进行判断等。

其命令格式为：

if [not] string1 compare-op string2 command1 [else command2]

其中，比较操作符compare-op有以下几类：

== - 等于

EQU - 等于

NEQ - 不等于

LSS - 小于

LEQ - 小于或等于

GTR - 大于

GEQ - 大于或等于

选择开关/i则不区分字符串大小写；选择not项，则对判断结果进行逻辑非。

字符串比较示例：

=

@echo off

set str1=abcd1233

set str2=ABCD1234

if %str1%==%str2% (echo 字符串相同！) else (echo 字符串不相同！)

if /i %str1% LSS %str2% (echo str1^<str2) else (echo str1^>=str2)

1)echo.

set /p choice=是否显示当前时间？（y/n)

if /i not %choice% EQU n echo 当前时间是：%date% %time%

pause>nul

对于最后一个if判断，当输入n或N时的效果是一样的，都不会显示时间。如果取消开关/i，则输入N时，依旧会显示时间。

注意：1-echo str1^<str2和echo str1^>=str2；2-echo.。

2)存在判断

存在判断的功能是判断文件或文件夹是否存在。

其命令格式为：

if [NOT] EXIST filename command1 [else command2]

@echo off

if exist %0 echo 文件%0是存在的！

if not exist %~df0 (

echo 文件夹%~df0不存在！

） else echo 文件夹%~df0存在！

pause>nul

注意：

1-存在判断既可以判断文件也可以判断文件夹；

2-%0即代表该批处理的全称（包括驱动器盘符、路径、文件名和扩展类型）；

3-%~df0是对%0的修正，只保留了其驱动器盘符和路径，详情请参考for /?，属高级批处理范畴；

4-注意if语句的多行书写，多行书写要求command1的左括号必须和if在同一行、else必须和command1的右括号同行、command2的左括号必须与else同行、command1和command2都可以有任意多行，即command可以是命令集。

3)定义判断

定义判断的功能是判断变量是否存在，即是否已被定义。

其命令格式为：

if [not] DEFINED variable command1 [else command2]

存在判断举例：

@echo off

set var=111

if defined var (echo var=%var%) else echo var尚未定义！

set var=% %

if defined var (echo var=%var%) else echo var尚未定义！

pause>nul

对比可知，"set var="可以取消变量，收回变量所占据的内存空间。

4)结果判断

masm %1.asm

if errorlevel 1 pause & edit %1.asm

link %1.obj

先对源代码进行汇编，如果失败则暂停显示错误信息，并在按任意键后自动进入编辑界面；否则用link程序连接生成的obj文件，这种用法是先判断前一个命令执行后的返回码（也叫错误码，DOS程序在运行完后都有返回码），如果和定义的错误码符合（这里定义的错误码为1），则执行相应的操作（这里相应的操作为pause & edit %1.asm部分）。

另外，和其他两种用法一样，这种用法也可以表示否定。用否定的形式仍表达上面三句的意思，代码变为：

masm %1.asm

if not errorlevel 1 link %1.obj

pause & edit %1.asm

for语句（循环结构）

for语句可以实现类似于C语言里面的循环结构，当然for语句的功能要更强大一点，通过不同的开关可以实现更多的功能。for语句有多个开关，不同开关将会实现不同的功能。

1．无开关

无开关的for语句能够对设定的范围内进行循环，是最基本的for循环语句。

其命令格式为：

for %%variable IN (set) DO command

其中，%%variable是批处理程序里面的书写格式，在DOS中书写为%variable，即只有一个百分号（%）；set就是需要我们设定的循环范围，类似于C语言里面的循环变量；do后面的command就是循环所执行的命令，即循环体。

无开关for语句举例：

===============================================

@echo off

for %%i in (a,"b c",d) do echo %%i

pause>nul

===============================================

2．开关/L

含开关/L的for语句，可以根据set里面的设置进行循环，从而实现对循环次数的直接控制。

其命令格式为：

for /L %%variable IN (start,step,end) DO command

其中，start为开始计数的初始值，step为每次递增的值，end为结束值。当end小于start时，step需要设置为负数。

含开关/L的for语句举例（创建5个文件夹）：

===============================================

@echo off

for /l %%i in (1,2,10) do md %%i

pause

===============================================

上例将新建5个文件夹，文件夹名称依次为1．3．5．7．9。可以发现，%%i的结束值并非end的值10，而是不大于end的一个数。

3．开关/F

含开关/F的for语句具有最强大的功能，它能够对字符串进行操作，也能够对命令的返回值进行操作，还可以访问硬盘上的ASCII码文件，比如txt文档等。

其命令格式为：

for /F ["options"] %%variable IN (set) DO command

其中，set为（"string"、'command'、file-set）中的一个；options是（eol=c、skip=n、delims=xxx、tokens=x,y,m-n、usebackq）中的一个或多个的组合。各选项的意义参见for /f。一般情况下，使用较多的是skip、tokens、delims三个选项。

含开关/F的for语句举例：

===============================================

@echo off

echo **No Options:

for /f %%a in ("1,2,10") do echo a=%%a

echo **Options tokens ^& delims:

for /f "tokens=1-3 delims=," %%a in ("1,2,10") do echo a=%%a b=%%b c=%%c

pause

===============================================

@echo off

echo 本文件夹里面的文件有：

for /f "skip=5 tokens=3* delims= " %%a in ('dir') do (

if not "%%a"=="<DIR>" if not "%%b"=="字节" if not "%%b"=="可用字节" echo %%b

)

pause

===============================================

@echo off

echo 本文件夹里面的文件有：

dir>c:\file.txt

for /f "skip=5 tokens=3* delims= " %%a in (c:\file.txt) do (

if not "%%a"=="<DIR>" if not "%%b"=="字节" if not "%%b"=="可用字节" echo %%b

)

del c:\file.txt

pause

===============================================

对于后面的两个例子，其中options里面的delims= 是可以删除的，因为只要添加了/F开关系统就将delims的值默认为空格。

符号字符串中的最后一个字符星号，

那么额外的变量将在最后一个符号解析之后

分配并接受行的保留文本。

4．开关/D或/R

含开关/D或/R的for语句是与目录或文件有关的命令，一般情况下很少使用。含开关/R的命令有时候被用于通过遍历文件夹来查找某一个文件或文件夹，故而列举此例。

含开关/R的for语句举例（文件夹遍历）：

===============================================

@echo off

setlocal enabledelayedexpansion

for /R d: %%i IN (.) DO (

set dd=%%i

set "dd=!dd:~0,-1!"

echo !dd!

）

pause

exit

===============================================

上例即可以罗列出D盘下的所有文件夹，其速度要比命令"tree d:"慢多了，不过其返回结果的实用性则远远超过了tree命令。

一般情况下我们不推荐通过遍历文件夹来查找文件，特别是在查找某些程序（比如QQ.exe）的位置时。推荐通过reg命令查找注册表来查找QQ的路径，以保证查找效率。

上例中也出现了几个新面孔，如setlocal、感叹号等。其中，感叹号其实就是变量百分号（%）的强化版。之所以要用！而不用%，是因为在for循环中，当一个变量被多次赋值时，%dd%所获取的仅仅是dd第一次被赋予的值；要想刷新dd的值，就必须首先通过命令"setlocal enabledelayedexpansion"来开启延迟变量开关，然后用！dd！来获取dd的值。

六、 字符串：

批处理有着具有非常强大的字符串处理能力，其功能绝不低于C语言里面的字符串函数集。批处理中可实现的字符串处理功能有：截取字符串内容、替换字符串特定字段、合并字符串、扩充字符串等功能。

1、 截取字符串

截取字符串可以说是字符串处理功能中最常用的一个子功能了，能够实现截取字符串中的特定位置的一个或多个字符。

=========================================

@echo off

set ifo=abcdefghijklmnopqrstuvwxyz0 12 3456789

echo 原字符串（第二行为各字符的序号）：

echo %ifo%

echo 1234567890123 45678901234567890123456

echo 截取前5个字符：

echo %ifo:~0,5%

echo 截取最后5个字符：

echo %ifo:~-5%

echo 截取第一个到倒数第6个字符：

echo %ifo:~0,-5%

echo 从第4个字符开始，截取5个字符：

echo %ifo:~3,5%

echo 从倒数第14个字符开始，截取5个字符：

echo %ifo:~-14,5%

pause

=========================================

=========================================

@echo off

echo 当前时间是：%time%即 %time:~0,2%点%time:~3,2%分%time:~6,2%秒%time:~9,2%厘秒

pause

=========================================

2、 替换字符串

替换字符串，即将某一字符串中的特定字符或字符串替换为给定的字符串。

=========================================

@echo off

set aa=伟大的中国！我为你自豪！

echo 替换前：%aa%

echo 替换后：%aa:中国=中华人民共和国%

echo aa = %aa%

set "aa=%aa:中国=中华人民共和国%"

echo aa = %aa%

pause

=========================================

对于上面的例子有一点说明，对比两个echo aa = %aa%可以发现，如果要修改变量aa的内容的话，就需要将修改结果“%aa：中国=中华人民共和国%”赋值给变量aa。

3、 字符串合并

其实，合并字符串就是将两个字符串放在一起就可以了。

=========================================

@echo off

set aa=伟大的中国！

set bb=我为你自豪！

echo %aa%%bb%

echo aa=%aa%

echo bb=%bb%

set "aa=%aa%%bb%"

echo aa=%aa%

pause

=========================================

同样，如果要改变变量aa的内容的话，就需要将合并结果“%aa%%bb%”赋值给变量aa。

4、 扩充字符串

“扩充”这个词汇来自于微软自己的翻译，意思就是对表示文件路径的字符串进行特殊的处理，具体功能如下：

=========================================

~I - 删除任何引号（")，扩充%I

%~fI - 将 %I扩充到一个完全合格的路径名

%~dI - 仅将 %I扩充到一个驱动器号

%~pI - 仅将 %I扩充到一个路径

%~nI - 仅将 %I扩充到一个文件名

%~xI - 仅将 %I扩充到一个文件扩展名

%~sI - 扩充的路径只含有短名

%~aI - 将 %I扩充到文件的文件属性

%~tI - 将 %I扩充到文件的日期/时间

%~zI - 将 %I扩充到文件的大小

%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩充到找到的第一个完全合格的名称。如果环境变量名未被定义，或者没有找到文件，此组合键会扩充到空字符串可以组合修饰符来得到多重结果：

%~dpI - 仅将 %I扩充到一个驱动器号和路径

%~nxI - 仅将 %I扩充到一个文件名和扩展名

%~fsI - 仅将 %I扩充到一个带有短名的完整路径名

%~dp$PATH:i - 查找列在路径环境变量的目录，并将 %I 扩充到找到的第一个驱动器号和路径。

%~ftzaI - 将 %I扩充到类似输出线路的 DIR

=========================================

以上内容引用于for /?帮助信息。其中的I代表变量I，不过需要说明的是，不是所有的变量都能够进行扩充的，有两个条件：1．该字符串代表一个文件路径；2．变量要用%x来表示，x可取a-z A-Z 0-9共62个字符中的任意一个。举例说明：

=========================================

@echo off

echo 正在运行的这个批处理：

echo 完全路径：%0

echo 去掉引号：%~0

echo 所在分区：%~d0

echo 所处路径：%~p0

echo 文件名：%~n0

echo 扩展名：%~x0

echo文件属性：%~a0

echo 修改时间：%~t0

echo 文件大小：%~z0

pause

=========================================

其中的%0是批处理里面的参数，代表当前运行的批处理的完全路径。类似的还有%1-%9，分别代表传递来的第1-9个参数。例子如下：

===============================================

@echo off

set aa=C:\Windows\PPP\a.btx

call :deal aaa %aa% "c c" ddd eee

pause>nul

exit

:deal

echo %%0 = %0

echo %%1 = %1

echo %%2 = %2

echo %%3 = %3

echo %%4 = %4

echo %%5 = %5

===============================================

其中，变量aa在之前是不可以扩充的，通过call命令并将aa作为参数传递给子函数：deal，将aa变量转换成了变量%1，即符合%x格式，从而可以进行字符串扩充。

至于%x中x取a-z A-Z的形式，可以复习一下for语句，for语句里面的变量就是用%x来表示的，因而可以直接进行扩充。

 

七、 数值计算：

批处理里面的数值计算功能较弱，只能够进行整型计算，忽略浮点数的小数部分；同时数值计算的范围也受限于系统位数，对于目前较为常见的32位机来说，数值计算能处理的数值范围为0x80000000h~0x7FFFFFFFh，即-2147483648~+2147483647。

数值计算需要使用set命令，具体格式为“set /a expression”。其中，expression代表计算表达式，计算表达式跟C语言里面的表达式基本上完全一致。set支持的运算符也跟C语言里面的一样，只是没有了増一减一。

set支持的运算符及优先级排序如下：

=========================================

（） - 分组

！ ~ - -一元运算符（逻辑非、按位非、取负）

* / % - 算数运算符（乘、除得商、除得余数，即取余）

+ - - 算数运算符（加、减）

<< >> - 逻辑移位（左移一位、右移一位）

& - 按位“与”

^ - 按位“异”

| - 按位“或”

= *= /= %= += -= - 赋值

&= ^= |= <<= >>=

，-表达式分隔符（set可一次处理多个表达式）

=========================================

批处理中取变量的值是需要用%或者！的，而在set /a 中，直接用变量名称即可取得变量的值。另外，set支持八进制（数字前缀0）、十进制（数字无前缀）和十六进制（数字前缀0x），且支持不同进制之间的计算，如set /a a=123+0123+0x123，计算及显示结果为十进制。

八、 批处理：

（一）环境变量

所谓“环境变量”，实际上就是C语言里面的“变量”的意思。批处理的变量可以分为两类，由系统定义的系统变量和由用户根据需要自定义的用户变量。

【 1．系统变量】

批处理的一些变量是由操作系统事先定义好的，可以适用于任何批处理，我们称这些特殊的变量为“系统变量”。系统变量有很多个，包括硬件类、操作系统类、文件路径类、系统时间类等。要查看所有的系统变量，请新打开一个cmd窗口，输入set回车即可。

对几个比较常用的变量解释如下：

ComputerName 计算机名，即右键我的电脑--属性--计算机名 选项卡中的“完整的计算机名称”

1. ComSpeccmd.exe完整路径名

HomeDrive系统分区盘符，一般都是C盘，故而HomeDrive=C:

Path可执行文件默认搜索路径。

ProgramFiles 就是系统的Program Files的路径啦，一般都是C:\Program Files，这就是安装软件时默认的安装路径了

Prompt 个性化设置cmd提示符的必备武器！

SystemDrive 包含系统根目录的分区，其实就是HomeDrive了

SystemRoot 系统根目录路径，一般都是C:\WINDOWS

Temp、Tmp 文件、程序等可使用的临时目录，默认是C:\WINDOWS\Temp或Tmp。几乎所有的程序在运行时都会在这个目录里面“临时”写入文件。一般情况下，程序写入的临时文件都应该被该程序删除，可惜的是，大部分的程序都很健忘，导致这个文件夹占据的空间越来越大，自然也就使我们的系统增肥喽。所以，我们要把它修改到其他分区，并且时时的清理里面的临时文件。

UserName 当前用户名，即所登陆的账户名

UserProfile 当前用户的配置目录，一般都是C:\Documents and Settings\%UserName%。默认情况下，我们的桌面就是这个目录下面的“桌面”文件夹；我的文档就是这个目录下面的“My Documents”文件夹。所以啦，往桌面上或我的文档里面放东西就是放到这个文件夹下面了，也就是放到C盘了，重装系统时要覆盖C盘内容的，所以桌面上或我的文档里面的东西当然就会Gone with the Wind了~解决方法有两个，一是保持良好的习惯，不把重要文件放到这两个地方；二是，修改默认设置，将这两个文件夹都移到其他分区。

WinDir操作系统路径，其实就是SystemRoot了

（二）用户变量

编写批处理程序时，用户根据需要自己定义的变量称之为用户变量。用户变量类似于C语言里面的变量，仅仅在定义该变量的程序中有效。

用户变量由set命令定义，这是批处理中非常非常重要的一个操作，从而使set命令成为批处理里面使用频率最高的几个命令之一。关于set命令的使用，参考set /?，本教程也会在后面对其进行讲解。

【 3．变量引用】

前面的几节课里面，我们已经看到了如何引用变量，即直接用变量名操作变量，通过"%"或"!"来获取变量的值。其中，只有在for语句里面重复对同一变量多次赋值时才需要使用"!"，并且在使用"!"调用变量时，要首先“启用延迟环境变量扩充”，启动命令为：SetLocal EnableDelayedExpansion。另外需要说明的是，“启用延迟环境变量扩充”后，所有的"!"都将被视为“取变量值”的特殊符号，即使用"^!"也不能输出符号"!"。若要输出"!"，则需要“停用延迟环境变量扩充”，命令为：SetLocal DisableDelayedExpansion

（三）参数

跟C语言类似，在调用函数或其他批处理时可能需要传递参数。批处理的参数传递分为直接和间接两种传递参数的方法。

【 1．直接传递 】

直接传递参数，即在使用call命令时，不使用任何参数，在子函数或子批处理里面直接对主函数（也称父批处理）里面的变量进行修改。这跟汇编语言里面的参数传递方式类似。

直接传递参数举例：

===============================================

@echo off

setlocal enabledelayedexpansion

set var=aCdehiM,?mnrstW y

echo %var%

call :deal

setlocal disabledelayedexpansion

set var=%var:?=!%

echo %var%

pause>nul

exit

:deal

set tm=!var!

set var=

for %%i in (6,3,11,11,16,15,1,4,11,5,12,13,9,0,12,7,15,14,5,10,2,16,18,8) do (

set var=!var!!tm:~%%i,1!

）

goto :eof

===============================================

可以发现，当我们把变量var作为参数赋予子函数：deal后，子函数对var的值进行了修改；当子函数返回后，主函数里面的var的值就已经是子函数里面var被修改后的值了。

该例子中，使用了setlocal enabledelayedexpansion和setlocal disabledelayedexpansion，前者保证了var在for循环里面能够根据我们的意愿进行处理，后者保证了能够正确输出符号"!"。另外例子中还使用了命令set，利用set对字符串进行了处理。还有一个地方使用了语句goto :eof，该语句相当于C语言里面的return或汇编语言里面的RET，即子程序返回命令。需要说明的是，当子函数本身就在批处理文件的末尾的话，我们是可以省略这句话的，比如将此例的goto :eof删除是不会产生任何影响的。

【 2．间接传递 】

间接传递参数，即在使用call命令时，在其后面添加参数，形如call {[:label][ChildBatch]} Parameter1 Parameter2 ... ParameterN。这跟C语言里面传递参数的格式类似。不同于C语言，批处理中的子函数不需要定义形参，更不需要指定参数的个数。传递过来的参数，在子函数或子批处理里面是以%1~%9的形式表示的，即%1~%9分别表示传递过来的第1~9个参数。

===============================================

@echo off

call :deal aaa bbb "c c" ddd eee

pause>nul

exit

:deal

echo %%0 = %0

echo %%1 = %1

echo %%2 = %2

echo %%3 = %3

echo %%4 = %4

echo %%5 = %5

===============================================

通过这个例子就可以清晰的看到%n参数表示法的用法。参数列表中包含空格的依旧要用双引号（")引起来；另外，也可以看到，%0已经变成了子函数的标号了，而不是父批处理的文件名全称。

【 3．区别 】

这两种参数传递方法本质上是没有区别的，形式上，直接传递直接对原变量进行操作，丢失了原变量的值；间接传递则通过%n对原变量进行了简单的备份，并且通用性更强，即不限定原变量的名称。另外，使用%n还有一个非常大的好处，就是可以通过%~*i来加强处理变量的能力。关于%~*i，详细内容参见for /?。

针对二者的差别，可以根据情况决定使用哪种传递方式：

--1．作为参数的变量名固定、且在子函数中不需要对其进行备份的情况下，使用直接传递法；

--2．若将子函数作为一个通用的程序模块，以适应于对不同变量的处理，或者作为参数的变量不需要备份时，使用间接传递法。

具体使用哪种方法，还需根据实际情况或使用习惯进行选择。

（四）返回值

有些命令在执行之后将会返回一定的错误值（errorlevel），可以通过errorlevel的值判断命令执行的状况。这点类似于C语言里面的exit(num），num就是错误代码。

获取返回值errorlevel的方法就是，在执行命令后，立马调用返回值errorlevel，如echo %errorlevel%或者if %errorlevel%==1等命令。

errorlevel举例：

===============================================

@echo off

reg add HKCU /v try /f>nul

reg delete HKCU /v try /f

if errorlevel 0 (echo删除成功！） else (echo删除失败！）

reg delete HKCU /v try /f

if %errorlevel%==0 (echo 删除成功！） else (echo删除失败！）

pause>nul

===============================================

上面例子中，由于第一成功的删除了注册表，导致第二次因为找不到注册表而宣告失败。同时我们也看到了errorlevel的使用方法，即if errorlevel 0和if %errorlevel%==0是一样的。也许你注意到了，里面还有个笑脸呢~O（∩_∩）O哈哈~这就是ASCII码啦，后面跟你讲啊…

一般情况下，程序或命令成功执行时，返回的errorlevel是0，错误时返回1或更高的值。当然，有些命令是没有返回值的，这点需要注意。

嗯，有没有想起前面有个类似的东西啊？对了，那就是||和&&；了，这两个符号就是根据errorlevel的值来进行逻辑判断的。

（五）ASCII码

ASCII码是图形化的符号，可以用来点缀我们的批处理的。

在cmd窗口中我们可以通过任意一个字符的ASCII码来输入该字符，比如Ctrl+G、Ctrl+N等，字母a-z对应ASCII码的97-122。对于ASCII码大于26的字符，可以通过这个方法来输入：按住Alt键不松，通过小键盘输入ASCII码的十进制值，松开Alt键即可。