REACTOS分析（1）Dosmbr.asm源码分析

来源：互联网发布：java常见的类编辑：程序博客网时间：2024/05/22 10:28

ReactOs引导代码dosmbr.asm

; normal DOS boot sector

; Ported to nasm from FreeDOS fdisk 1.2.0 by:

; Casper Hornstrup (chorns@users.sourceforge.net)

;

align 2, db 0

global _bootnormal_code

_bootnormal_code:

;-----------------------------------------------------------------------

; ENTRY (copied from freedos bootsector)

; IN: DL = boot drive

;OUT: DL = boot drive

;-----------------------------------------------------------------------

real_start: cli

cld

xor ax, ax

mov ss, ax ; initialize stack

mov ds, ax

mov bp, 0x7c00

lea sp, [bp-0x20]

sti

mov ax, 0x1FE0

mov es, ax

mov si, bp

mov di, bp

mov cx, 0x0100

rep movsw

jmp word 0x1FE0:0x7c00+ cont-real_start

//BIOS会将磁盘MBR读到内存中 0x0000：0x7c00

//首先将MBR代码移动到 0x1FE0：0x7c00

//注意下面两条规则：

//1）在改变SS：SP之前，必须用cli指令屏蔽中断，然后等操作执行完立即用sti指令恢复

//2）SS：SP需要设置在空闲的内存地址，不要建立在其他的程序（尤其是系统的）代码区

cont: mov ds, ax

mov ss, ax

xor ax,ax

mov es,ax

//重新设置数据、堆栈段寄存器->0x1FE0

//搜索MBR的4个分区表，找到引导分区

; search for active partition

lea di, [bp+0x1be] ; start of partition table

test_next_for_active:

test byte [di],0x80

jne active_partition_found

add di,0x10 ; next table

cmp di, 07c00h+0x1fe; scanned beyond end of table ??

jb test_next_for_active

;*****************************************************************

call print

db 'no active partition found',0

WAIT_FOR_REBOOT:

jmp $

;*****************************************************************

trouble_reading_drive:

call print

db 'read error while reading drive',0

jmp WAIT_FOR_REBOOT

;*****************************************************************

invalid_partition_code:

call print

db 'partition signature != 55AA',0

jmp WAIT_FOR_REBOOT

;*****************************************************************

active_partition_found:

; call print

; db 'loading active partition',0

//准备载入引导分区

call read_boot_sector

jc trouble_reading_drive

cmp word [es:0x7c00+0x1fe],0xaa55

jne invalid_partition_code

//执行引导代码

jmp word 0x0:0x7c00 ; and jump to boot sector code

;*****************************

; read_boot_sector

; IN: DI--> partition info

;OUT:CARRY

;*****************************

read_boot_sector:

; /* check for LBA support */

mov bx,0x55aa

mov ah,0x41

int 0x13

//使用 BIOS int 13测试LBA支持

jc StandardBios ; if (regs.b.x != 0xaa55 || (regs.flags & 0x01))

cmp bx,0xaa55 ; goto StandardBios;

jne StandardBios

; /* if DAP cannot be used, don't use LBA */

; if ((regs.c.x & 1) == 0)

; goto StandardBios;

test cl,1

jz StandardBios

jmp short LBABios

//使用LBA地址以及BIOS int13扩展IO指令读磁盘，参考int 13扩展指令资料

//读取4个扇区->0x0000：0x7c00

_bios_LBA_address_packet:

db 0x10

db 0

db 4 ; read four sectors - why not

db 0

dw 0x7c00 ; fixed boot address for DOS sector

dw 0x0000

_bios_LBA_low dw 0

_bios_LBA_high dw 0

dw 0,0

LBABios:

; copy start address of partition to DAP

mov ax,[di+8]

mov [0x7c00+ (_bios_LBA_low-real_start)],ax

mov ax,[di+8+2]

mov [0x7c00+ (_bios_LBA_high-real_start)],ax

mov ax,0x4200 ; regs.a.x = LBA_READ;

mov si,0x7c00+ (_bios_LBA_address_packet-real_start); regs.si = FP_OFF(&dap);

int 0x13

ret

;*****************************************************************

; read disk, using standard BIOS

;

StandardBios:

mov ax,0x0204 ; regs.a.x = 0x0201;

mov bx,0x7c00 ; regs.b.x = FP_OFF(buffer);

mov cx,[di+2] ; regs.c.x =

; ((chs.Cylinder & 0xff) << 8) + ((chs.Cylinder & 0x300) >> 2) +

; chs.Sector;

; that was easy ;-)

mov dh,[di+1] ; regs.d.b.h = chs.Head;

; regs.es = FP_SEG(buffer);

int 0x13

ret

;****** PRINT

; prints text after call to this function.

print_1char:

xor bx, bx ; video page 0

mov ah, 0x0E ; else print it

int 0x10 ; via TTY mode

print: pop si ; this is the first character

print1: lodsb ; get token

push si ; stack up potential return address

cmp al, 0 ; end of string?

jne print_1char ; until done

ret ; and jump to it

times 0x1fe-$+$$ db 0

db 0x55,0xaa

; http://en.wikipedia.org/wiki/INT_13

; http://en.wikipedia.org/wiki/INT_10

硬盘主引导扇区 = 硬盘主引导记录（MBR）+ 硬盘分区表（DPT）
--------------------------------------------------------------
物理位置：0面0道1扇区（clindyer 0, side 0, sector 1)
大小： 512字节
其中：MBR 446字节（0000--01BD），DPT 64字节（01BE--01FD），结束标志2字节（55 AA）
功能：MBR通过检查DPT分区信息引导系统跳转至DBR；
读取: 使用NORTON DISKEDIT, 在OBJECT菜单中选择DRIVE——>PHYSICAL DISK-—HARD DISK,
然后, 在OBJECT菜单中选择DISK PARTITION TABLE即可读取, 并使用TOOLS菜单中的WRITE OBJECT TO 选项存入指定文件备份;
写入: 使用NORTON DISKEDIT, 在OBJECT菜单中选择DRIVE——>FLOOPY DISK, 选择备份的DPT
文件, 然后使用TOOLS菜单中的WRITE OBJECT TO——>PHYSICAL SECTOR 选项写入001
(clindyer 0, side 0, sector 1);

详解:
000H--08AH MBR启动程序(寻找开机分区)
08BH--0D9H MBR启动字符串
0DAH--1BCH 保留("0")
1BEH--1FDH 硬盘分区表
1FEH--1FFH 结束标志(55AA)

活动分区主引导扇区（DBR）
--------------------------
物理位置：1面0道1扇区（clindyer 0, side 1, sector 1)
大小： FAT16 1扇区 512字节
FAT32 3扇区 1536字节
功能：包含机器CMOS等信息（0000--0059）, 核对该信息并引导指定的系统文件, 如NTLDR等；
读取: 使用NORTON DISKEDIT, 在OBJECT菜单中选择DRIVE——>LOGICAL DISK-—DISK C,
然后, 在OBJECT菜单中选择BOOT RECORD即可读取, 并使用TOOLS菜单中的
WRITE OBJECT TO 选项存入指定文件备份;
写入: 使用NORTON DISKEDIT, 在OBJECT菜单中选择DRIVE——>FLOOPY DISK, 选择备份的DBR
文件, 然后使用TOOLS菜单中的WRITE OBJECT TO——>PHYSICAL SECTOR 选项写入011
(clindyer 0, side 1, sector 1);

详解:

000H--002H 3 BYTE的跳转指令(去启动程序, 跳到03EH)
003H--03DH BIOS参数区
03EH--19DH DOS启动程序
19EH--1E5H 开机字符串
1E6H--1FDH 文件名(IO.SYS, MSDOS.SYS)
1FEH--1FFH 结束标记(55AA)

硬盘分区表（DPT）
---------------------
偏移地址字节数含义分析

01BE 1 分区类型：00表示非活动分区：80表示活动分区；其他为无效分区。

01BF~01C1 3 *分区的起始地址（面/扇区/磁道），通常第一分区的起始地址开始
于1面0道1扇区，因此这三个字节应为010100

01C2 1 #分区的操作系统的类型。

01C3~01C5 3 *该分区的结束地址（面/扇/道）

01C6~01C9 4 该分区起始逻辑扇区

01CA~01CD 4 该分区占用的总扇区数

注释: * 注意分区的起始地址（面/扇区/磁道）和结束地址（面/扇/道）中字节分配:

00000000 01000001 00010101
~~~~~~~~ ==^^^^^^ ========

~ 面(磁头) 8 位
^ 扇区 6 位
= 磁道 10 位

# 分区的操作系统类型(文件格式标志码)

4---DOS FAT16<32M
5---EXTEND
6---DOS FAT16>32M
7---NTFS(OS/2)
83---LINUX>64M

DPT 总共64字节（01BE--01FD）, 如上所示每个分区占16个字节, 所以可以表示四个分区, 这也
就是为什么一个磁盘的主分区和扩展分区之和总共只能有四个的原因.

逻辑驱动器
-----------
扩展分区的信息位于以上所示的硬盘分区表（DPT）中, 而逻辑驱动器的信息则位于扩展分区的
起始扇区, 即该分区的起始地址（面/扇区/磁道）所对应的扇区, 该扇区中的信息与硬盘主引导
扇区的区别是不包含MBR, 而16字节的分区信息则表示的是逻辑驱动器的起始和结束地址等.

所以, 在磁盘仅含有一个主分区, 一个扩展分区(包含多个逻辑驱动器)的情况下, 即使由于病毒
或其他原因导致硬盘主引导扇区的数据丢失(包括DPT), 也可以通过逻辑驱动器的数据来恢复整个硬盘.

例如: 以下是一个硬盘的分区情况.

道面扇道面扇起始扇(逻辑) 结束扇总共扇区
MBR 0 0 1 - - - - - -
C 0 1 1 276 239 63 63 4,188,239 4,188,177
扩 277 0 1 554 239 63 4,188,240 8,391,599 4,203,360
D 277 1 1 554 239 63 4,188,303 8,391,599 4,203,297

如果主分区表损坏, 则可以通过手工查找扩展分区表中所包含的逻辑驱动器数据, 在本例中就是D盘所对应的数据, 然后将其起始扇(逻辑)减去63就是所对应的扩展分区的起始扇(逻辑), 将其起始地址（面/扇区/磁道）改为0面就是扩展分区的起始地址. 然后通过扩展分区就可以得到主分区C的信息, 然后就可以使用FDISK/MBR命令和手工填写分区表恢复整个硬盘.

实际使用这种方法比较麻烦, 如果知道每个分区的大小, 则可以通过使用PQ MAGIC 5 将磁盘重新分区为原来大小(注意: 千万不能应用, 我们只是通过它来获得数据), 并查看INFO来获得以上
数据, 记录以后取消该分区操作, 然后使用NORTON DISK2000手工修改DPT表, 恢复整个硬盘.

该例所对应的分区表数据:

80 01
01 00 06 EF 7F 14 3F 00 00 00 11 E8 3F 00 00 00
41 15 05 EF BF 2A 50 E8 3F 00 60 23 40 00 00 00
00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00
00 00 00 00 00 00 00 00 00 00 00 00 00 00 55 AA

扩展分区表数据:
00 01
41 15 07 EF BF 2A 8F E8 3F 00 21 23 40 00

注意: 逻辑起始扇区和总共分区数是左边为低位, 如该例的扩展分区的起始地址为50 E8 3F 00转换十进制时要先变为00 3F E8 50, 总共占用分区数60 23 40 00要先变为00 40 23 60, 同理当手工填写该值时也要进行高低位转换.