支持自动TOC超文本目录生成的chm转换器(perl脚本)

早些时候为自已使用方便编写了一个将chm解压结果文件压中的hhc文件转换成目录式html的脚本。如果大家需要这个功能，可以从这里找到。两个脚本程序都是使用perl语言编写，所以你需要一个比较IN的perl发行版(区区推荐是ActivePerl)。

 

用google很容易就能找到windows系统内置的chm解压方式:

HH.EXE -decompile [解压至路径] [被解压chm文件路径]

 

对比了一下HH.exe和区区常用的7z，发现hh.exe decompile出来的文件更加干净一些（没有meta信息文件），这正是区区想要的，所以，将原来的hhc2idx.pl改写成chm2htm.pl，支持直接由chm直接生成一个目录，其中的所有hhc文件会分别产生一个名字类似"CHTOC_XXXXX.htm"的超文本目录网页。

 

有两个原因使得这个工具很有用：

• 不是所有环境下看chm都很方便，比如linux/手机/NDS
• hh真的不是很便捷的htm查看器，相比于现代化的Browser，它太弱

 

程序使用方法很简单（尤其对于程序员而言），在安装好ActivePerl之后，在命令行中输入(最好先cd到chm文件所在目录) ：

chm2htm.pl [你的chm文件名]

命令成功运行的话，会以chm文件名为目录名新建一个导出目录。

 

如果在使用中发现有任何问题，欢迎反馈。

 

下面是程序源码，因为CSDN对perl脚本的处理有bug(会自行加如型如"mce_ref=xxxx"之类的无关文本)，所以是自行调色的：

 

 

---

 

use feature qw(say);
use HTML::TreeBuilder;
use File::Basename;
if ($#ARGV < 0) {
    say "/n/nusage: chm2htm.pl your.chm1 [your.chm2 ...]";
    exit;
}

sub dump_chm
{
    my ($chm_name) = @_;
    say "processing file : ".$chm_name;
    my $base_name = basename($chm_name, ".chm");
    system("hh -decompile $base_name $chm_name");
    my @hhcs = glob("$base_name/*.hhc");
    for my $hhc_file (@hhcs) {
        my $tree = HTML::TreeBuilder->new; # build empty tree
       
        $tree->parse_file($hhc_file); #parse hhc file as HTML
        $tree->elementify(); #optional prevent reparse
       
        @objects = $tree->look_down("_tag","object"); #all object
        #say "there ar $#objects ob";
        for my $ob (@objects) {
            my ($el, $dst, $name);
            $el = $ob->look_down("name", "Local"); #Local val as <a> href URL
            if (defined($el)) {
                $dst = $el->attr('value')
            }
            $el = $ob->look_down("name", "Name");  #Name val as <a> text
            if (defined($el)) {
                $name = $el->attr('value')
            }
            #say sprintf('<a href="%s">%s</a>', $dst, $name);
            if (defined($dst) && defined($name)) {
                $ob->replace_with(
                    sprintf('<a href="%s">%s</a>', $dst, $name)
                    );
            } else {
                $ob->replace_with(
                    sprintf('<strong>trans by chm2htm : meet some unkown object</strong>', $dst, $name)
                    );
            }
        }
        my $outfilename = $base_name . "/CHTOC_" . basename($hhc_file, ".hhc") . ".htm";
        say 'TOC file put into : '.$outfilename;
        my $outfile;
        open $outfile, ">", $outfilename;
        say $outfile $tree->as_HTML("", " "); #say out the new html text
# Now that we're done with it, we must destroy it.
        $tree = $tree->delete;
    }
}

dump_chm($_) for (@ARGV);

 

 

---