asp中用jmail，Cdonts组件和Aspemail组件发邮件

JMAIL安装配置

 

jmail发送邮件的实例代码网上很多.但是有些细节如果不配置好,发送失败的可能性很大.

首先说明一下jmail安装配置步骤:

1. JMail 下载地址
http://hbdx3.skycn.com/down/w3JMail43Personal.exe

2.安装

本人在Windows 2003下面配置,其它系统还没有测试.

安装到目录比如: C:/Program Files/Dimac/w3JMail4/jmail.dll

然后还需要把jmail.dll复制到系统目录,比如C:/WINDOWS/system32

再运行:regsvr32 jmail.dll

这样才算把jmail安装好了.

 

 

------------------------------------------------------

 

 

可以选择性使用jmail，CDO组件和Aspemail组件其中一个。默认的话，将使用Jmail组件发邮件。把以下文件另存成SendMail.asp.改一下里面的e_开头的变量的设置.用 <!--#include file="SendMail.asp"--> 包含.然后要发邮件的时候.用 SendEmail "[e-mail]","test","this is test!","Jmail"
函数。'以上是测试的过程 .第一项是MAIL收件人,第二项为主题,第三项为正文,第三为发件模式.分别是Jmail,Cdonts,Aspemail注意大小写。

sendmail.asp的代码:

 

<!--#include file="SendMail.asp"-->

<%
E_Server = "mail.am8way.com"   ''发件服务器地址
E_ServerUser = "[e-mail]"  ''发件服务器登录用户名(如果不需要邮件验证.就不用写)
E_ServerPass = "123456"   ''发件服务器登录密码(如果不需要邮件验证.就不用写)
E_SendManMail = "[e-mail]"  ''发件人邮件地址
E_SendManName = "系统管理员"   ''发件人姓名

 

Sub Jmail(Email,Topic,Mailbody)'Jmail组件发信
On Error Resume Next
Dim JMail
Set JMail = Server.CreateObject("JMail.Message")
JMail.silent=true
JMail.Logging = True
JMail.Charset = "gb2312"
If Not(E_ServerUser = "" Or E_ServerPass = "") Then
  JMail.MailServerUserName = E_ServerUser
  JMail.MailServerPassword = E_ServerPass
End If
JMail.ContentType = "text/html"
JMail.Priority = 1
JMail.From = E_SendManMail
JMail.FromName = E_SendManName
JMail.AddRecipient Email
JMail.Subject = Topic
JMail.Body = Mailbody
JMail.Send (E_Server)
Set JMail = Nothing
SendMail = "OK"
If Err Then SendMail = "False"
End Sub

Sub Cdonts(Email,Topic,Mailbody)'Cdonts函数发信
On Error Resume Next
Dim ObjCDOMail
Set ObjCDOMail = Server.CreateObject("CDONTS.NewMail")
ObjCDOMail.From = E_SendManMail
ObjCDOMail.To = Email
ObjCDOMail.Subject = Topic
ObjCDOMail.BodyFormat = 0
ObjCDOMail.MailFormat = 0
ObjCDOMail.Body = Mailbody
ObjCDOMail.Send
Set ObjCDOMail = Nothing
SendMail = "OK"
If Err Then SendMail = "False"
End Sub

 

Sub Aspemail(Email,Topic,Mailbody)'Aspemail组件发信函数
On Error Resume Next
Dim Mailer
Set Mailer = Server.CreateObject("Persits.MailSender")
Mailer.Charset = "gb2312"
Mailer.IsHTML = True
Mailer.username = E_ServerUser
Mailer.password = E_ServerPass
Mailer.Priority = 1
Mailer.Host = E_Server
Mailer.Port = 25
Mailer.From = E_SendManMail
Mailer.FromName = E_SendManName
Mailer.AddAddress Email,Email
Mailer.Subject = Topic
Mailer.Body = Mailbody
Mailer.Send
SendMail = "OK"
If Err Then SendMail = "False"
End Sub
dim SendMail
Sub SendEmail(Mailto,Subject,HtmlCode,SendMode)'定义函数sendemail
if SendMode="" then SendMode="Jmail"'默认的发邮件的组件
if SendMode="Jmail" then
  Jmail MailTo,Subject,HtmlCode
elseif SendMode="Cdonts" then
  Cdonts MailTo,Subject,HtmlCode
elseif SendMode="Aspemail" then
  Aspemail MailTo,Subject,HtmlCode
end if
End Sub

%>

sendmail.asp代码结束！

一般经常使用在用户在注册的同时，系统自动发一封确认信或通知信。那么Mailto,Subject,HtmlCode三个变量一般是表单提交的。例如：Mailto=request.form("****")。大家如果有企业邮局的话，可以据此制作一个简单的会员注册同时系统发通知信的ASP程序。