sql判断函数???
来源:互联网 发布:淘宝c店保证金怎么办 编辑:程序博客网 时间:2024/06/12 03:04
功能:小写金额转换成大写
参数:@LowerMoney 小写金额 加上小数点最长可以保留38位
输出:大写金额
简介:SQL版 小写金额转换成大写金额(最多可以精确到小数点四位)
注: Decimal 数据类型最多可存储 38 个数字
转载:请保留以上信息,谢谢!!!
********************************************************/
SET QUOTED_IDENTIFIER ON
GO
SET ANSI_NULLS ON
GO
Create Function LowerToUpper(@LowerMoney Decimal(38,4))
Returns Varchar(200) --返回的大写金额的字符
As
Begin
Declare @LowerStr Varchar(50) --小写金额
Declare @UpperStr Varchar(200) --大写金额
Declare @UpperTmp Varchar(15) --大写金额的临时字符串
Declare @i Int --递增量
Declare @LowerLen Int --小写金额的总长度
Set @LowerStr = @LowerMoney --把Decimal型的值全部赋给字符串变量 注:(赋值过去的话如8 在字符串变量中是显示8.0000 因为小数位精确到四位,没有的话,它会自动补0)
Set @LowerStr = Replace(@LowerStr,'.','') --把小数点替换成空字符 --精确到小数点的四位 角分厘毫
Set @LowerLen = Len(@LowerStr) --获取小写金额的总长度(包括四个小数位)
Select @i = 1,@UpperStr = '',@UpperTmp = '' --设置默认初始值
While @i <= @LowerLen
Begin
Set @UpperTmp = Case
When SubString(@LowerStr,@LowerLen - @i + 1,1) = '0' And @i = 5 And (Convert(Int,Right(@LowerStr,4)) = 0 Or @LowerLen > 5) Then '元' --注:如果个位为0的话,并且四位小数都是0或者它的长度超过5(也就是超过元),则为元
--When SubString(@LowerStr,@LowerLen - @i + 1,1) = '0' Then ''
Else
+ Case SubString(@LowerStr,@LowerLen - @i + 1,1) --看当前位是数字几,就直接替换成汉字繁体大写
When '0' Then '零'
When '1' Then '壹'
When '2' Then '贰'
When '3' Then '叁'
When '4' Then '肆'
When '5' Then '伍'
When '6' Then '陆'
When '7' Then '柒'
When '8' Then '捌'
When '9' Then '玖'
End
+ Case @i
When 1 Then '毫'
When 2 Then '厘'
When 3 Then '分'
When 4 Then '角'
When 5 Then '元'
When 9 Then '萬'
When 13 Then '亿'
When 17 Then '兆'
When 21 Then '京'
When 25 Then '垓'
When 29 Then '杼'
When 33 Then '穰'
When 37 Then '沟' --Decimal型最大长度是38 后面的就不用再考虑了
Else
+ Case @i%4
When 2 Then '拾' --拾 6 10 14 18 22 26 30 34 38 …………
When 3 Then '佰' --佰 7 11 15 19 23 27 31 35 39 …………
When 0 Then '仟' --仟 8 12 16 20 24 28 32 36 40 …………
End
End
End
Set @UpperStr = Isnull(@UpperTmp,'') + Isnull(@UpperStr,'')
Set @i = @i + 1
End
If Convert(Int,Right(@LowerStr,4)) = 0 Set @UpperStr = Left(@UpperStr,Len(@UpperStr)-8) + '整' --判断小数位数是不是都是0,是0就可以取整
While Patindex('%零[仟佰拾角分厘毫零]%',@UpperStr) <> 0 --把零拾或零佰或零零变成一个零
Begin
Set @UpperStr = stuff(@UpperStr,patindex('%零[仟佰拾角分厘毫零]%',@UpperStr),2,'零')
End
While Patindex('%[沟穰杼垓京兆亿萬]零[沟穰杼垓京兆亿萬]%',@UpperStr) <> 0 --把零萬或零亿的清空掉
Begin
Select @UpperStr = Stuff(@UpperStr,Patindex('%[沟穰杼垓京兆亿萬]零[沟穰杼垓京兆亿萬]%',@UpperStr)+1,2,'')
End
While Patindex('%[仟佰拾]零[沟穰杼垓京兆亿萬]%',@UpperStr) <> 0 --把类似拾零萬或佰零萬或仟零萬中间的零清空掉
Begin
Select @UpperStr = Stuff(@UpperStr,Patindex('%[仟佰拾]零[沟穰杼垓京兆亿萬]%',@UpperStr)+1,1,'')
End
If Patindex('%_零[元]%',@UpperStr) <> 0 --把类似拾零元或百零元中间的零清空掉
Begin
Select @UpperStr = Stuff(@UpperStr,Patindex('%_零[元]%',@UpperStr) + 1,1,'')
End
Else If (Patindex('零[元]%',@UpperStr) <> 0) And (Convert(Int,Right(@LowerStr,4)) <> 0) --判断当前否是零元开头,并且后面的四个小数不为0
Begin
Select @UpperStr = Stuff(@UpperStr,Patindex('零[元]%',@UpperStr),2,'') --把零元清空掉
End
If Right(@UpperStr,1) = '零' Set @UpperStr = Left(@UpperStr,Len(@UpperStr)-1) --如果最后一位是零也清空掉
If @UpperStr = '元整' Set @UpperStr = '零' + @UpperStr --如果只是0的话,就显示零元整
Return @UpperStr --返回大写金额
End
GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO
--调用方法
Select dbo.LowerToUpper(120000000) --壹亿贰仟萬元整
Select dbo.LowerToUpper(102000000) --壹亿零贰佰萬元整
Select dbo.LowerToUpper(100200000) --壹亿零贰拾萬元整
Select dbo.LowerToUpper(100020000) --壹亿零贰萬元整
Select dbo.LowerToUpper(100002000) --壹亿贰仟元整
- sql判断函数???
- SQL Server中判断闰年的函数
- 判断远程服务器是否运行的SQL Server函数
- mssql判断一个函数名是否存在脚本sql
- sql server 中判断是否为中文的函数
- Sql Server判断数据库、表、存储过程、函数是否存在
- Sql Server判断数据库、表、存储过程、函数是否存在
- sql 创建表、存储过程、函数 时,判断已存在
- replace MYSQL字符替换函数sql语句分享(正则判断)
- sql 判断 函数 存储过程是否存在的方法
- SQL Server判断数据库、表、存储过程、函数是否存在
- Sql Server判断数据库、表、存储过程、函数是否存在
- sql 判断 函数 存储过程是否存在的方法
- Sql Server判断数据库、表、存储过程、函数是否存在
- sql函数能判断字段是否包含英文
- sql 判断 函数 存储过程是否存在的方法
- sql 判断 函数 存储过程是否存在的方法
- sql 判断 函数 存储过程是否存在的方法
- android 截获键盘事件
- DebugView for Vista Windows 7 打印显示问题
- 文件上传 测试用例
- 微软VC各版本BUG: error C2660: 'new' : function does not take 3 parameters[转]
- 创建文件夹并在里面写文本内容
- sql判断函数???
- 当你输入一个网址的时候,实际会发生什么?
- SOAP与AXIS2入门教程(附带实例)
- 正则表达式的应用 String.split("ECONFUNC//(//s*//w*//s*,//s*//d*//s*,//s*//w*//s*//)");
- QQ网页登陆密码加密方式(农场、空间、WebQQ等通用)(网摘)
- 如何判断一个float/double是不是一个有效的值
- 第五章
- 如何做一个Excel动态表头
- listbox font