数据库批量备份存储过程(判断盘符、路径，错误盘符返回，不存在的路径自动创建)
来源：互联网 发布：淘宝新店第二天没流量 编辑：程序博客网 时间：2024/05/22 06:59
--------------------------------------------------------------------------
-- Author : htl258(Tony)
-- Date : 2010-04-18 10:45:18
-- Version:Microsoft SQL Server 2008 (RTM) - 10.0.1600.22 (Intel X86)
-- Jul 9 2008 14:43:34
-- Copyright (c) 1988-2008 Microsoft Corporation
-- Developer Edition on Windows NT 5.1 <X86> (Build 2600: Service Pack 2)
-- Blog :http://blog.csdn.net/htl258
-- Subject:数据库备份存储过程(判断盘符、路径，错误盘符返回，不存在的路径自动创建)
--------------------------------------------------------------------------
--适用环境：SQL Server 2005及以上版本(主要用于作业中调用以及程序开发中调用)
--新增功能：备份文件保留天数，超出保留天数以外的自动删除。（2010-05-07）
USE master
GO
--1.周期性备份数据库代码(保留原来备份的):
--备份文件名为：原数据库名称+'_'+备份日期.bak
IF OBJECT_ID('sp_backupdatabase') IS NOT NULL
DROP PROC sp_backupdatabase
GO
CREATE PROC sp_backupdatabase
@path NVARCHAR(100),--输入备份路径，如：F:/BackUp
@savedays int=0 --保留天数,值为0时保留所有
AS
SET NOCOUNT ON
--路径名格式标准化
IF RIGHT(@path,1)<>'/' SET @path=@path+'/'
SET @path=REPLACE(@path,'：',':')
--获取文件夹信息
DECLARE @t TABLE(id INT IDENTITY,a INT,b INT,c INT)
DECLARE @fpath NVARCHAR(3)
SET @fpath=LEFT(@path,3)
INSERT @t EXEC master..xp_fileexist @fpath
INSERT @t EXEC master..xp_fileexist @path
--如果指定盘符有误不存在，则返回错误提示：
IF EXISTS(SELECT 1 FROM @t WHERE id=1 AND c=0)
BEGIN
RAISERROR(N'输入的盘符不存在，请重新输入!',16,1)
RETURN
END
--如果不存在指定的文件夹，则创建:
ELSE IF EXISTS(SELECT 1 FROM @t WHERE b=0 AND id=2)
BEGIN
DECLARE @mddir NVARCHAR(100)
SET @mddir='md '+@path
EXEC master..xp_cmdshell @mddir
END
--只保留指定天数的数据，删除指定天数外的数据
IF @savedays>0
BEGIN
DECLARE @tb TABLE(dbname nvarchar(100))
DECLARE @path2 nvarchar(500),@del nvarchar(500)
SET @PATH2='dir '+@path+' /b'
INSERT @tb EXEC master..xp_cmdshell @path2
DECLARE c CURSOR FOR
SELECT 'del '+@path+dbname FROM @tb
WHERE RIGHT(REPLACE(dbname,'.bak',''),CHARINDEX('_',REVERSE(REPLACE(dbname,'.bak','')))-1)
< DATEADD(DD,-@savedays,GETDATE())-1
OPEN c
FETCH c INTO @del
WHILE @@fetch_status=0
BEGIN
EXEC master..xp_cmdshell @del
FETCH c INTO @del
END
CLOSE c
DEALLOCATE c
END
--开始备份数据库到指定的目录
DECLARE @s nvarchar(4000)
SELECT @s=ISNULL(@s+';','')
+N'BACKUP database ['+name+'] TO DISK = '''
+@path+name+'_'+CONVERT(NVARCHAR(8),getdate(),112)+N'.bak'''-- SQL2008 加 WITH COMPRESSION 可压缩备份
FROM master..sysdatabases
WHERE name NOT IN('master','tempdb','model','msdb','pubs')--这里筛选不参加备份的数据库
--WHERE name IN ('db1','db2','db3') --或注释上一行，取消注释本行，选择参加备份的数据库
EXEC(@S)
SET NOCOUNT OFF
GO
--调用方法：
EXEC sp_backupdatabase 'F:/Backup/tony',30 --30 表示保留当前日期（不包括）以前天内的数据，其余自动删除。
/*
--返回信息：
已为数据库'mydb'，文件'mydb' (位于文件上)处理了页。
已为数据库'mydb'，文件'mydb_log' (位于文件上)处理了页。
BACKUP DATABASE 成功处理了页，花费.733 秒(3.336 MB/秒)。
已为数据库'test'，文件'test' (位于文件上)处理了页。
已为数据库'test'，文件'test_log' (位于文件上)处理了页。
BACKUP DATABASE 成功处理了页，花费.413 秒(3.951 MB/秒)。
--备份后的文件列表：
mydb_20100507.bak
test_20100507.bak
*/
--2.周期性备份数据库代码(自动删除原备份文件):
--备份文件名为：原数据库名称.bak
IF OBJECT_ID('sp_backupdatabase') IS NOT NULL
DROP PROC sp_backupdatabase
GO
CREATE PROC sp_backupdatabase
@path NVARCHAR(100)--路径
AS
--路径名格式标准化
IF RIGHT(@path,1)<>'/' SET @path=@path+'/'
--获取文件夹信息
DECLARE @t TABLE(id INT IDENTITY,a INT,b INT,c INT)
DECLARE @fpath NVARCHAR(3)
SET @fpath=LEFT(@path,3)
INSERT @t EXEC master..xp_fileexist @fpath
INSERT @t EXEC master..xp_fileexist @path
--如果指定盘符有误不存在，则返回错误提示：
IF EXISTS(SELECT 1 FROM @t WHERE id=1 AND c=0)
BEGIN
RAISERROR(N'输入的盘符不存在，请重新输入!',16,1)
RETURN
END
--如果不存在指定的文件夹，则创建:
ELSE IF EXISTS(SELECT 1 FROM @t WHERE b=0 AND id=2)
BEGIN
DECLARE @mddir NVARCHAR(100)
SET @mddir='md '+@path
EXEC master..xp_cmdshell @mddir
END
--开始备份数据库到指定的目录
DECLARE @s nvarchar(4000)
SELECT @s=ISNULL(@s+';','')
+N'BACKUP database ['+name+'] TO DISK = '''
+@path+name+N'.bak'' WITH INIT'
FROM master..sysdatabases
WHERE name NOT IN('master','tempdb','model','msdb','pubs')--这里筛选不参加备份的数据库
EXEC(@S)
GO
--调用方法：
EXEC sp_backupdatabase 'f:/Backup/tony2'
/*
--返回信息：
已为数据库'mydb'，文件'mydb' (位于文件1 上)处理了312 页。
已为数据库'mydb'，文件'mydb_log' (位于文件1 上)处理了1 页。
BACKUP DATABASE 成功处理了313 页，花费0.599 秒(4.082 MB/秒)。
已为数据库'test'，文件'test' (位于文件1 上)处理了208 页。
已为数据库'test'，文件'test_log' (位于文件1 上)处理了1 页。
BACKUP DATABASE 成功处理了209 页，花费0.351 秒(4.651 MB/秒)。
--备份后的文件列表：
mydb.bak
test.bak
*/
--以下转自:perfectaction (2010-05-07)
create proc sp_backupdatabase
@bak_path nvarchar(4000)='' --备份路径;
,@baktype int = null --备份类型为全备,1为差异备,2为日志备份
,@type int = null --设置需要备份的库,0为全部库,1为系统库,2为全部用户库,3为指定库,4为排除指定库;
,@dbnames nvarchar(4000)='' --需要备份或排除的数据库，用,隔开，当@type=3或4时生效
,@overdueDay int = null --设置过期天数，默认天;
,@compression int =0 --是否采用sql2008的压缩备份,0为否,1为采用压缩
as
--sql server 2005/2008备份/删除过期备份T-sql 版本v1.0
/*
author:perfectaction
date :2009.04
desc :适用于sql2005/2008备份，自动生成库文件夹，可以自定义备份类型和备份库名等
可以自定义备份过期的天数
删除过期备份功能不会删除最后一次备份，哪怕已经过期
如果某库不再备份，那么也不会再删除之前过期的备份
如有错误请指正，谢谢.
*/
set nocount on
--开启xp_cmdshell支持
exec sp_configure 'show advanced options', 1
reconfigure with override
exec sp_configure 'xp_cmdshell', 1
reconfigure with override
exec sp_configure 'show advanced options', 0
reconfigure with override
print char(13)+'------------------------'
--判断是否填写路径
if isnull(@bak_path,'')=''
begin
print('error:请指定备份路径')
return
end
--判断是否指定需要备份的库
if isnull(ltrim(@baktype),'')=''
begin
print('error:请指定备份类型aa:0为全备,1为差异备,2为日志备份')
return
end
else
begin
if @baktype not between 0 and 2
begin
print('error:指定备份类型只能为,1,2: 0为全备,1为差异备,2为日志备份')
return
end
end
--判断是否指定需要备份的库
if isnull(ltrim(@type),'')=''
begin
print('error:请指定需要备份的库,0为全部库,1为系统库,2为全部用户库,3为指定库,4为排除指定库')
return
end
else
begin
if @type not between 0 and 4
begin
print('error:请指定需要备份的库,0为全部库,1为系统库,2为全部用户库,3为指定库,4为排除指定库')
return
end
end
--判断指定库或排除库时，是否填写库名
if @type>2
if @dbnames=''
begin
print('error:备份类型为'+ltrim(@type)+'时，需要指定@dbnames参数')
return
end
--判断指定指定过期时间
if isnull(ltrim(@overdueDay),'')=''
begin
print('error:必须指定备份过期时间,单位为天,0为永不过期')
return
end
--判断是否支持压缩
if @compression=1
if charindex('2008',@@version)=0 or charindex('Enterprise',@@version)=0
begin
print('error:压缩备份只支持sql2008企业版')
return
end
--判断是否存在该磁盘
declare @drives table(drive varchar(1),[size] varchar(20))
insert into @drives exec('master.dbo.xp_fixeddrives')
if not exists(select 1 from @drives where drive=left(@bak_path,1))
begin
print('error:不存在该磁盘:'+left(@bak_path,1))
return
end
--格式化参数
select @bak_path=rtrim(ltrim(@bak_path)),@dbnames=rtrim(ltrim(@dbnames))
if right(isnull(@bak_path,''),1)!='/' set @bak_path=@bak_path+'/'
if isnull(@dbnames,'')!='' set @dbnames = ','+@dbnames+','
set @dbnames=replace(@dbnames,' ','')
--定义变量
declare @bak_sql nvarchar(max),@del_sql nvarchar(max),@i int,@maxid int
declare @dirtree_1 table (id int identity(1,1) primary key,subdirectory nvarchar(600),depth int,files int)
declare @dirtree_2 table (id int identity(1,1) primary key,subdirectory nvarchar(600),depth int,files int,
dbname varchar(300),baktime datetime,isLastbak int)
declare @createfolder nvarchar(max),@delbackupfile nvarchar(max),@delbak nvarchar(max)
--获取需要备份的库名--------------------start
declare @t table(id int identity(1,1) primary key,name nvarchar(max))
declare @sql nvarchar(max)
set @sql = 'select name from sys.databases where state=0 and name!=''tempdb'' '
+ case when @baktype=2 then ' and recovery_model!=3 ' else '' end
+ case @type when 0 then 'and 1=1'
when 1 then 'and database_id<=4'
when 2 then 'and database_id>4'
when 3 then 'and charindex('',''+Name+'','','''+@dbnames+''')>0'
when 4 then 'and charindex('',''+Name+'','','''+@dbnames+''')=0 and database_id>4'
else '1>2' end
insert into @t exec(@sql)
--获取需要备份的库名---------------------end
--获取需要创建的文件夹------------------start
insert into @dirtree_1 exec('master.dbo.xp_dirtree '''+@bak_path+''',0,1')
select @createfolder=isnull(@createfolder,'')+'exec master.dbo.xp_cmdshell ''md '+@bak_path+''+name+''',no_output '+char(13)
from @t as a left join @dirtree_1 as b on a.name=b.subdirectory and b.files=0 and depth=1 where b.id is null
--获取需要创建的文件夹-------------------end
--生成处理过期备份的sql语句-------------start
if @overdueDay>0
begin
insert into @dirtree_2(subdirectory,depth,files) exec('master.dbo.xp_dirtree '''+@bak_path+''',0,1')
if @baktype =0
delete from @dirtree_2 where depth=1 or files=0 or charindex('_Full_bak_',subdirectory)=0
if @baktype =1
delete from @dirtree_2 where depth=1 or files=0 or charindex('_Diff_bak_',subdirectory)=0
if @baktype=2
delete from @dirtree_2 where depth=1 or files=0 or charindex('_Log_bak_',subdirectory)=0
if exists(select 1 from @dirtree_2)
delete from @dirtree_2 where isdate(
left(right(subdirectory,19),8)+' '+ substring(right(subdirectory,20),11,2) + ':' +
substring(right(subdirectory,20),13,2) +':'+substring(right(subdirectory,20),15,2)
)=0
if exists(select 1 from @dirtree_2)
update @dirtree_2 set dbname = case when @baktype=0 then left(subdirectory,charindex('_Full_bak_',subdirectory)-1)
when @baktype=1 then left(subdirectory,charindex('_Diff_bak_',subdirectory)-1)
when @baktype=2 then left(subdirectory,charindex('_Log_bak_',subdirectory)-1)
else '' end
,baktime=left(right(subdirectory,19),8)+' '+ substring(right(subdirectory,20),11,2) + ':' +
substring(right(subdirectory,20),13,2) +':'+substring(right(subdirectory,20),15,2)
from @dirtree_2 as a
delete @dirtree_2 from @dirtree_2 as a left join @t as b on b.name=a.dbname where b.id is null
update @dirtree_2 set isLastbak= case when (select max(baktime) from @dirtree_2 where dbname=a.dbname)=baktime
then 1 else 0 end from @dirtree_2 as a
select @delbak=isnull(@delbak,'')+'exec master.dbo.xp_cmdshell ''del '+@bak_path+''+dbname+'/'
+subdirectory+''',no_output '+char(13) from @dirtree_2 where isLastbak=0 and datediff(day,baktime,getdate())>@overdueDay
end
--生成处理过期备份的sql语句--------------end
begin try
print(@createfolder) --创建备份所需文件夹
exec(@createfolder) --创建备份所需文件夹
end try
begin catch
print 'err:'+ltrim(error_number())
print 'err:'+error_message()
return
end catch
select @i=1 ,@maxid=max(id) from @t
while @i<=@maxid
begin
select @bak_sql=''+char(13)+'backup '+ case when @baktype=2 then 'log ' else 'database ' end
+quotename(Name)+' to disk='''+@bak_path + Name+'/'+
Name+ case when @baktype=0 then '_Full_bak_' when @baktype=1 then '_Diff_bak_'
when @baktype=2 then '_Log_bak_' else null end + case when @compression=1 then 'compression_' else '' end+
replace(replace(replace(convert(varchar(20),getdate(),120),'-',''),' ','_'),':','')+
case when @baktype=2 then '.trn' when @baktype=1 then '.dif' else '.bak' end +''''
+ case when @compression=1 or @baktype=1 then ' with ' else '' end
+ case when @compression=1 then 'compression,' else '' end
+ case when @baktype=1 then 'differential,' else '' end
+ case when @compression=1 or @baktype=1 then ' noformat' else '' end
from @t where id=@i
set @i=@i+1
begin try
print(@bak_sql)--循环执行备份
exec(@bak_sql) --循环执行备份
end try
begin catch
print 'err:'+ltrim(error_number())
print 'err:'+error_message()
end catch
end
begin try
print(@delbak) --删除超期的备份
exec(@delbak) --删除超期的备份
end try
begin catch
print 'err:'+ltrim(error_number())
print 'err:'+error_message()
end catch
--关闭xp_cmdshell支持
--exec sp_configure 'show advanced options', 1
--reconfigure with override
--exec sp_configure 'xp_cmdshell', 1
--reconfigure with override
--exec sp_configure 'show advanced options', 0
--reconfigure with override
/*
调用示例：
--备份系统库(全备)
exec master.dbo.sp_backupdatabase
--备份路径;
@bak_path ='D:/temp/dbbak'
--备份类型为全备,1为差异备,2为日志备份
,@baktype = 0
--设置需要备份的库,0为全部库,1为系统库,2为全部用户库,3为指定库,4为排除指定库;
,@type = 1
--需要备份或排除的数据库，用,隔开，当@type=3或4时生效
,@dbnames =''
--设置过期天数，默认天;
,@overdueDay = 31
--是否采用sql2008的压缩备份,0为否,1为采用压缩
,@compression =0
--备份用户库(全备)--建议一周一次
exec master.dbo.sp_backupdatabase
--备份路径;
@bak_path ='D:/temp/dbbak'
--备份类型为全备,1为差异备,2为日志备份
,@baktype = 0
--设置需要备份的库,0为全部库,1为系统库,2为全部用户库,3为指定库,4为排除指定库;
,@type = 3
--需要备份或排除的数据库，用,隔开，当@type=3或4时生效
,@dbnames ='db1,db2'
--设置过期天数，默认天;
,@overdueDay = 15
--是否采用sql2008的压缩备份,0为否,1为采用压缩
,@compression =0
--备份用户库(差异备)--建议一天一次
exec master.dbo.sp_backupdatabase
--备份路径;
@bak_path ='D:/temp/dbbak'
--备份类型为全备,1为差异备,2为日志备份
,@baktype = 1
--设置需要备份的库,0为全部库,1为系统库,2为全部用户库,3为指定库,4为排除指定库;
,@type = 3
--需要备份或排除的数据库，用,隔开，当@type=3或4时生效
,@dbnames ='db1,db2'
--设置过期天数，默认天;
,@overdueDay = 15
--是否采用sql2008的压缩备份,0为否,1为采用压缩
,@compression =0
--备份用户库(日志备)--建议1小时一次
exec master.dbo.sp_backupdatabase
--备份路径;
@bak_path ='D:/temp/dbbak'
--备份类型为全备,1为差异备,2为日志备份
,@baktype = 2
--设置需要备份的库,0为全部库,1为系统库,2为全部用户库,3为指定库,4为排除指定库;
,@type = 3
--需要备份或排除的数据库，用,隔开，当@type=3或4时生效
,@dbnames ='db1,db2'
--设置过期天数，默认天;
,@overdueDay = 15
--是否采用sql2008的压缩备份,0为否,1为采用压缩
,@compression =0
*/
本文来自CSDN博客，转载请标明出处：http://blog.csdn.net/htl258/archive/2010/04/18/5498882.aspx
- 数据库批量备份存储过程(判断盘符、路径，错误盘符返回，不存在的路径自动创建)
- 数据库批量备份存储过程(判断盘符、路径，错误盘符返回，不存在的路径自动创建)[
- 数据库批量备份存储过程(判断盘符、路径，错误盘符返回，不存在的路径自动创建)
- 数据库批量备份存储过程(判断盘符、路径，错误盘符返回，不存在的路径自动创建)
- 判断路径文件夹是否存在,不存在创建
- 判断路径目录不存在，则创建目录
- 数据库批量备份存储过程
- sql server 脚本创建备份数据库的存储过程及利用前述存储过程自动备份数据库的作业
- SQL1052N 数据库路径*不存在问题错误的解决
- 判断路径是否存在，不存在则创建该路径
- db2 创建数据库 提示路径不存在
- 日记 C++输入输出流 以及创建一个路径的过程（可以是不存在的路径）
- Java 判断多级路径是否存在，不存在就创建
- windows创建DB2数据库时报错--SQL1052N 数据库路径不存在
- Java API 自带的日志管理，可配置文件路径，并自动创建不存在的目录
- Java API 自带的日志管理，可配置文件路径，并自动创建不存在的目录
- 数据库--sql作业，执行自动备份的存储过程
- Delphi中调用oracle的存储过程返回数据集报“列不存在”错误
- SQL2005备份与还原相关参数与方法说明
- hdu 2006 求奇数的乘积
- Android平台Activity
- 字符数据类型转换代码
- Dijkstra和Floyd算法
- 数据库批量备份存储过程(判断盘符、路径，错误盘符返回，不存在的路径自动创建)
- SQL数据库不同备份名称存放不同路径还原方法
- hdu 2007 平方和与立方和
- POJ 1179 Polygon(DP)
- SQL数据备份
- SQL SERVER数据库置疑后恢复步骤
- hdu 2008 数值统计
- 三个SQL Server 2005的实例在同一台机器上存在的方法(不允许端口相同)
- Zw*与Nt*的区别
