Win7下Grub-4_Dos使用

1, 下载grub4dos-0.4.4

 http://sourceforge.net/projects/grub4dos/

2,将MENU.LST内容修改为：

 

default= 0

timeout =0

 

title DOS
kernel (hd0,0)/grubdos/memdisk
initrd (hd0,0)/grubdos/boot.img
boot

3 ,将grldr.mbr grldr MENU.LST 目录拷贝到C盘根目录下

4, 将boot.img和 memdisk拷贝到C盘grubdos目录下

boot.img为dos启动盘，内含ghost和autoexec.bat和config.sys

memdisk可从网上下载

 

5，运行以下bat批处理，使用bcdedit 在win7下添加grub菜单

 

@echo off
rem by lianjiang
cls
echo.
echo 请以管理员身份运行。
echo.
pause
set gname=GRUB for DOS
set vid=
set timeout=5
bcdedit >bcdtemp.txt
type bcdtemp.txt | find "/grldr.mbr" >nul && echo. && echo BCD启动项中已有grub4dos的项目，无需再安装。&& pause && goto exit
bcdedit /export "Bcd_Backup" >nul
bcdedit /create /d "%gname%" /application bootsector >vid.ini
for,/f,"tokens=2 delims={",%%i,In (vid.ini) Do (
set vida=%%i
)
for,/f,"tokens=1 delims=}",%%i,In ("%vida%") Do (
set vid={%%i}
)
echo %vid%>vid.ini
bcdedit /set %vid% device partition=%systemdrive% >nul
bcdedit /set %vid% path /grldr.mbr >nul
bcdedit /displayorder %vid% /addlast >nul
bcdedit /timeout %timeout% >nul
if exist grldr.mbr copy grldr.mbr %systemdrive%/ /y && goto exit
echo.
echo 稍后请自行把grldr.mbr拷贝到%systemdrive%/根目录
echo.
pause
:exit
del bcdtemp.txt >nul

安装完成

 

---

 

附注：：

1, 卸载：运行以下批处理

@echo off
rem by lianjiang
cls
echo.
echo 要求存在用安装批处理安装时自动保存的临时文件。
echo.
echo 请以管理员身份运行。
echo.
pause
set vid=
set timeout=5
if exist Bcd_Backup bcdedit /import "Bcd_Backup" >nul&& goto 1

if not exist vid.ini (
echo.
echo 因相关文件被删，不能自动删除启动项项目，只能手动删除。
echo.
pause
goto exit
)

for,/f,"tokens=1",%%i,In (vid.ini) Do (
set vid=%%i
)
bcdedit /delete %vid% /cleanup >nul
bcdedit /timeout %timeout% >nul
:1
del vid.ini >nul
if exist %systemdrive%/grldr.mbr (
attrib -h -s -r %systemdrive%/grldr.mbr >nul
del %systemdrive%/grldr.mbr >nul
)

:exit

 

2, 手工卸载
（1）bcdedit /enum >11.txt

查看其中的{ntldr}

（2）

bcdedit /delete {ntldr} /f