CXGRID问题大荟萃

公司目前这个项目要大量的用CxGrid,以前我从未用过,所以被逼得焦头烂额.加之我用的这电脑系统貌似有问题(老出些莫明其妙的事儿,如:突然不能编译出exe,上班开机突然丢失大堆的DLL文件,F9执行后关掉EXE Delphi就死掉了...)有时候做得想骂娘.
现在特将收集的一些文章与大家分享,也希望大家不要重蹈我的覆辙.
  http://www.delphibbs.com/keylife/iblog_show.asp?xid=19911大富翁论坛-富翁笔记-cxgrid （数据库控件）控件的使用
  http://www.delphifans.com/infoView/Article_722.html『Delphi园地』-分享一下ExpressQuantumGrid4的cxGrid的一些使用方法和经验
  http://www.delphibbs.com/delphibbs/dispq.asp?lid=2843325CxGrid显示数据时有多少条记录就画多表格线，其它地方为空，有没有办法可以像DbGrid一样画满
  http://www.delphibbs.com/keylife/iblog_show.asp?xid=16001大富翁论坛-富翁笔记-ExpressQuantumGrid中如何将满足条件的记录用不同颜色显示？
  http://soft.etcell.com/topicView.aspx?Id=35970 开个贴子,专门讨论一下cxGrid,用过的进来看看 
  http://blog.csdn.net/nhconch/archive/2007/03/02/1519254.aspx让cxGrid像Excel那样高亮显示选区的行号列标
  http://community.csdn.net/Expert/topic/5642/5642196.xml?temp=.5949365关于手动向Cxgrid里面添加内容的问题。
  http://download.csdn.net/source/15030DevExpress QuantumGrid4.5 教程
欢迎大家在此帖中提问和解答,在此先谢谢大家!

分享一下ExpressQuantumGrid4的cxGrid的一些使用方法和经验
日期：2006年2月6日 作者：wangxian11 人气： 8659 查看:[大字体 中字体 小字体] 
使用cxGrid有一些时间了，在这里总结一下使用cxGrid的一些方法，希望给刚开始接触cxGrid的人一些帮助。

1.简单介绍：cxGrid右下方的cxGrid1Level1是表示Grid表的层，cxGrid可以有多层，这相当于集合了PageControl的

功能,而cxGrid1Level1右边的cxGrid1DBTableView1相当于DBGrid一样。右击cxGrid1可以添加cxGrid1Level2，右击

cxGrid1Level2，可以选择Create View , Add level 或者Delete Level。Add level可以增加子Level，Create View

里面可以选择很多不同总类的View。其中
   1)DB Table可以和数据库连接的View，更一般的DBGrid类似，它比DBGrid多了比如鼠标中键可以用，可以统计，

查询，等等功能；
   2)DB Banded Table 则可以实现比如：
                     ---------------------------------
                     |     说明1     |     说明2     |
                     ---------------------------------
                     | 字段1 | 字段2 | 字段3 | 字段4 |
等类似的功能；
   3)DB Card View 则提供了卡片方式的显示数据的功能，这个用在比如人事档案管理比较不错；
   4)其它不一一赘述。
 
2.一些使用方法：
   1)有图片和MEMO的例子：
     拖入一个cxGrid1，Table1，DataSource1。 Table1的DatabaseName设为DBDEMOS，TableName设为biolife.db，

    Active设为True;DataSource1的DataSet设为Table1；cxGrid1DBTableView1的DataController中的DataSource  

    设为DataSource1;右击cxGrid1DBTableView1选择Create All Columns；双击cxGrid1，在弹出的窗口中找到    

   cxGrid1DBTableView1Notes和cxGrid1DBTableView1Graphic，将它们的Properties属性设为BlobEdit；运行看看 

   结果。再将cxGrid1DBTableView1Graphic的Properties属性设为Image，再将Properties下的Stretch设为True， 

   将cxGrid1DBTableView1->optionsview->CellAutoHeight 设为True，看看结果。

   2)如何让“Drag a column here to group by that column”不显示
     解决：点击cxGrid1上的cxGrid1DBTableView1
     在cxGrid1DBTableView1->optionsview->groupbybox:=false即可 
     注：OptionsView里面有很多属性可能经常要用，比如：ColumnAutoWith,Navigator等等，慢慢琢磨吧:)
    
   3)GroupPanel上面的英文[Drag a column header to group by that column]怎么可以改成中文？
     解决：最简单的方法是 TcxGridTableView.OnCustomDrawPartBackground ，也可用 OnCustomDrawGroupCell：

     procedure TForm1.cxGrid1DBTableView1CustomDrawPartBackground(
                Sender: TcxGridTableView; ACanvas: TcxCanvas;
               AViewInfo: TcxCustomGridCellViewInfo; var ADone: Boolean);
     begin
       AViewInfo.Text:='动态设置 GroupBox 的显示内容';
       ACanvas.FillRect(AViewInfo.Bounds);
     end;

   4)如何实现如下功能：
            +财务部
            +原材料仓库
            +成品库
            +冲压车间
            +软件开发部
     这个是部门的名称,点击加号就可以将本部门的人员情况显示出来。
     解决：其实这是一个主从表关系，1：填好主表的keyfieldnames
                                   2：填好从表的keyfieldnames
                                   3：填好从表的　detaikeyfieldNames与masterkeyfieldnames
                                   4: 从表的数据源一定要按与主表关联的字段排序
    注：其它地方设置了主从表结构那样就显示不出来，比如设置了从表的Table或者Query的mastersource和
    asterfield就会不能显示数据！如果是两个cxGrid的主从关系，这样设置就很OK了。

  
  5)统计功能
    解决：cxGrid1DBTableView1->optionsview->Footer 设为True
          cxGrid1DBTableView1->DataController->Summary设置FooterSummaryItems即可 

  6)类似PageControl显示
    解决：增加一个Level,将cxGrid1->RootLevelOptions->DetailTabsPosition设为dtpTop，然后相应的设置cxGrid1Level1,和cxGrid1Level2的Caption值。

   未完待续。。。。。。。。。

   以上是在用cxGrid时候碰到的一些问题，我总结了一部分，还有很多问题等待解决。在这里我希望用过cxGrid的人帮着一起总结一下，让后学者可以少走点弯路！

   7)如何设定左边几列，不能滚动?
    解决：使用DB Banded Table才可以实现，
          在cxGrid1DBBandedTableView里建立Band0,Band1
          Band0的Fixed=tfLeft
          Band1的Fixed=tfnone
          设置要锁定的字段的BandIndex=0,其它为1，就OK了。  
 
  8)怎样实现如EXCEL一样的，当前格=G14+G15+G16 这样的功能
    解决：举一个简单的例子：label1.Caption := cxGrid1DBTableView1.DataController.Values[2,

3]+cxGrid1DBTableView2.DataController.Values[1, 1]+cxGrid1DBTableView3.DataController.Values[1, 1];
所以不同cxGrid1DBTableView中的数据都可以给当前格，这样就做到了EXCEL中的当前格=G14+G15+G16 类似的功能。
 
  9)鼠标右击cxGrid1DBBandedTableView1菜单里的Edit Layout什么用，怎么使用？
    解决：可以拖动字段，并列的可以拖成有层次感（一层层）， 拖动时会显示箭头的，就是说可以拖一个字段放

到最上面，就可以使记录按此字段进行分组。点击其中一个字段，上面还会出现一个上升或者下降的小三角形，这个

小三角形的作用是在运行阶段，数据就会按照这个字段上升或者下降排序。
     还有一个Set as Default的作用是保持当前TableView的参数，下此产生新的TableView的时候就会可以和上次保持的参数一样。
10）怎样将cxGrid里的数据导入到EXCEL，HTML，XML和TEXT
  解决：这个问题在用了cxGrid以后变得异常简单，
uses
 cxExportGrid4Link;

procedure TForm1.Button1Click(Sender: TObject);
begin
 ExportGrid4ToEXCEL('d:/wang.xsl',cxGrid1,True,True);
 ExportGrid4ToTEXT('d:/wang.txt',cxGrid1,True,True);
 ExportGrid4ToXML('d:/wang.xml',cxGrid1,True,True);
 ExportGrid4ToHTML('d:/wang.html',cxGrid1,True,True);
end;

11)如何使满足条件的数据显示不同的颜色？
 解决：
var
  AYellowStyle: TcxStyle;

procedure TForm1.FormCreate(Sender: TObject);
begin
   //行颜色
  AYellowStyle := TcxStyle.Create(Self);
  AYellowStyle.Color := $0080FFFF;
  AYellowStyle.TextColor := clMaroon;
end;

procedure TForm1.cxGrid1DBBandedTableView1StylesGetContentStyle(
  Sender: TcxCustomGridTableView; ARecord: TcxCustomGridRecord;
  AItem: TcxCustomGridTableItem; out AStyle: TcxStyle);
begin
  if ARecord.Values[cxGrid1DBBandedTableView1Lengthcm.Index] < 81 then
    AStyle := AYellowStyle;
end;

这里cxGrid1DBBandedTableView1Lengthcm.Index小于81时就显示黄色
 

问题12）如何从外边的TXT文件导入到cxGrid？
解决：    procedure CustomizeColumns;
          procedure LoadData;

procedure TForm1.CustomizeColumns;
const
 cDistance = 1;
 cRadius = 5;
 cPeriod = 4;
 cPstring = 0;
var
 I: Integer;
begin
 DecimalSeparator := '.';
 with cxGrid1TableView2 do
 for I := 0 to ColumnCount - 1 do
   if I in [cDistance, cRadius] then
     Columns[I].DataBinding.ValueTypeClass := TcxIntegerValueType//1，5列为Integer
   else
     if I in [cPstring,cPeriod] then
     Columns[I].DataBinding.ValueTypeClass := TcxStringValueType//0，4列为String
     else
      Columns[I].DataBinding.ValueTypeClass := TcxFloatValueType;//其他为Float
end;

procedure TForm1.LoadData;
const
 AFileName = '资产负债表.txt';
 AHeaderLineCount = 2;

var
 ARecords, AValues: TStringList;
 I: Integer;

 procedure InitRecord(const Str: string);
 var
   J: Integer;
   V: Variant;
 begin
   AValues.CommaText := Str;
   for J := 0 to AValues.Count - 1 do
    if AValues.Strings[J] <> '-' then
    begin
     V := AValues.Strings[J];
     if not VarIsNull(V) then
       cxGrid1TableView2.DataController.Values[I, J] := V;
    end;
 end;

begin
 if not FileExists(AFileName) then
   raise Exception.Create('Data file not found');

 ARecords := TStringList.Create;
 AValues := TStringList.Create;

 with ARecords do
 try
   LoadFromFile(AFileName);
   cxGrid1TableView2.BeginUpdate;
   cxGrid1TableView2.DataController.RecordCount := Count - AHeaderLineCount;
   for I := 0 to Count - (AHeaderLineCount + 1) do
     InitRecord(Strings[I + AHeaderLineCount]);
 finally
   cxGrid1TableView2.EndUpdate;
   ARecords.Free;
   AValues.Free;
 end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
 CustomizeColumns;
 LoadData_Zcfz;
end;

其中“资产负债表.txt”中的数据如下：

资        产  行次  年  初  数  期  末  数  负债及所有者权益  行次  年  初  数  期  末  数
---------       ----    -----           --------        ----------             ----     --------        ---------
流动资产：  1  0.00          0.00          流动负债：          2  0.00          0.00 

 
13）如何改变列的颜色？
var
 AFirstColumnStyle: TcxStyle;

procedure TForm1.FormCreate(Sender: TObject);
begin
 //列颜色
 AFirstColumnStyle := TcxStyle.Create(Self);
 AFirstColumnStyle.Color := clAqua;
 AFirstColumnStyle.TextColor := clBlue;
 cxGrid1TableView1.Columns[1].Styles.Content := AFirstColumnStyle;
end;
14）Set as default的用法？
 解决：Set as default的用法是为了解决设置参数的方便而做的，比如：
       连好数据库以后，更改cxGrid1DBBandedTableView1->OptionsCustomize->ColumnFiltering 设为False。（这个设置可以将字段名的下拉单给去掉）更改cxGrid1DBBandedTableView1->OptionsView->Navigator 设置为True。然后右击cxGrid1DBBandedTableView1，在弹出的菜单栏里面点击Set as default。
  OK，下次你再产生一个新的cxGrid1DBBandedTableView1时这些设置和刚才的一样了。如果需要设置的参数很多的时候，这个Set as default很有用！

15）怎样使鼠标移动时，相应的单元格里的文字变色？
  解决：
var
 FTrackItem: TcxCustomGridTableItem;
 FTrackRec: TcxCustomGridRecord;

procedure TForm1.cxGrid1DBTableView1CustomDrawCell(
 Sender: TcxCustomGridTableView; ACanvas: TcxCanvas;
 AViewInfo: TcxGridTableDataCellViewInfo; var ADone: Boolean);
begin
 if (AViewInfo.GridRecord = FTrackRec) and (AViewInfo.Item = FTrackItem) then
 begin
   ACanvas.Font.Color := clred;   //红色字体
   ACanvas.Font.Style := [fsUnderline];//带下划线
 end;
end;

procedure TForm1.cxGrid1DBTableView1MouseMove(Sender: TObject;
 Shift: TShiftState; X, Y: Integer);
var
 AHitTest: TcxCustomGridHitTest;
 ATrackItem: TcxCustomGridTableItem;
 ATrackRec: TcxCustomGridRecord;
begin
 ATrackItem := FTrackItem;
 ATrackRec := FTrackRec;

 AHitTest := (Sender as TcxGridSite).GridView.ViewInfo.GetHitTest(X, Y);
 if AHitTest is TcxGridRecordCellHitTest then
 begin
   FTrackItem := TcxGridRecordCellHitTest(AHitTest).Item;
   FTrackRec := TcxGridRecordCellHitTest(AHitTest).GridRecord;
 end
 else
 begin
   FTrackItem := nil;
   FTrackRec := nil;
 end;

 if (ATrackItem <> FTrackItem) or (ATrackRec <> FTrackRec) then
 begin
   // Invalidate old cell
   if ATrackRec <> nil then
     ATrackRec.Invalidate(ATrackItem);
   // Invalidate new cell
   if FTrackRec <> nil then
     FTrackRec.Invalidate(FTrackItem);
 end;
end;

   
16）怎样设计多表头的cxGrid？
  解决：cxGrid可以解决如下的表头：
                   ---------------------------------
                   |     说明1     |     说明2     |
                   ---------------------------------
                   | 字段1 | 字段2 | 字段3 | 字段4 |
                   |      字段5    |     字段6     |
                   |      字段7    | 字段8 | 字段9 |
实现这个很简单，你可以直接在上面拖动字段名，拖动时会显示箭头的，放入你想显示的位置就OK了。或者在鼠标右击cxGrid1DBBandedTableView1菜单里的Edit Layout里也可以拖放。

但是cxGrid不能实现如下的多表头形式：
                   ---------------------------------
                   |     说明1     |     说明2     |
                   ---------------------------------
                   | 说明3 | 说明4 | 说明5 | 说明6 |
                   |      字段1    |     字段2     |
                   |      字段3    | 字段4 | 字段5 |
不知道有谁能实现这样的多表头？  

17）在主从表结构时，当点开“+”时怎样将焦点聚在相应主表的记录上？
解决：
var
 HitTest: TcxCustomGridHitTest;

procedure TColumnsShareDemoMainForm.tvProjectsMouseDown(Sender: TObject;
 Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
 // Note that the Sender parameter is a Site
 HitTest := (Sender as TcxGridSite).GridView.ViewInfo.GetHitTest(X, Y);
 // The point belongs to the [+]/[-] button area
 if HitTest is TcxGridExpandButtonHitTest then
   // Move focus to the record
   TcxGridExpandButtonHitTest(HitTest).GridRecord.Focused := True;
end;  
//点击空白处添加新记录
procedure TFrmAssignProduceTask.cxGrid1DBTableView1MouseDown(
  Sender: TObject; Button: TMouseButton; Shift: TShiftState; X,
  Y: Integer);
var
  AHitTest: TcxCustomGridHitTest;
begin
  with cxGrid1DBTableView1   do
    AHitTest:= ViewInfo.GetHitTest(X, Y);
  if (AHitTest.HitTestCode=0) and (Button= mbLeft) then   //左键点击了grid的空白
  begin
    cdsMain.Append;
  end;
end;

 

本文来自CSDN博客，转载请标明出处：http://blog.csdn.net/henreash/archive/2008/12/05/3454259.aspx