Visual Basic 2005新功能——泛型

事实上，泛型是.NET Framework 2.0所支持的一项特别的功能，Visual Basic 2005只不过从语言层面上支持他，就像C#和C++/CLI一样。首先，我们从泛型本身介绍起。

需求

我们常常会有一种需求，就是我们编写的代码能够针对多种类型执行。比如排序，检索，集合的操作等等。这些操作的代码应该能够只编写一次，就能够广泛地用于所有类型。.NET Framework 1.1或更早版本提供的方案是，用继承树的根——Object，承载任何类型。这样针对Object的算法就等于兼容于所有的类型。但是以Object作为所有类型的承载容器有两个重要的问题：首先值类型在转换成Object时要进行“装箱”操作，该操作的速度非常缓慢，因此性能就成最大的问题。其次是对Object进行操作必须通过运行时类型转换才能进行，这样就不能在编译期间发现类型不兼容的操作。比如我们有一个自定义的结构——Customer，我们希望用ArrayList来保存一个Customer的列表：

Dim customerList As New ArrayList()
customerList.Add(New Customer("Harry Potter", 13, "Hogwarts School"))

'当我们要使用这条记录时
MsgBox(CType(customerList(0), Customer).Name)

初看起来这没有任何问题，但是如果我们添加的语句写成这样：

customerList.Add("Hello")

会怎么样呢？String根本不能转换成Customer类型，但是没有任何提示阻止你这样做。这个错误直到运行时才会体现出来。我们需要强类型的方法，编译时的类型检查和更高的性能，所以我们需要泛型。

感受泛型

现在我们就来看看针对上述需求的泛型解决方案。.NET Framework 2.0支持一种新的泛型列表——List(Of T)。这里我们引入了Of语句，他就是Visual Basic为实现泛型而增加的。其中T称为“类型参数”，它接受任意一个.NET类型作为元素的类型。于是我们可以将上述Customer的代码写成：

Dim customerList As New List(Of Customer)
customerList.Add(New Customer("Harry Potter", 13, "Hogwarts School"))

MsgBox(customerList(0).Name)

我们来看看这段代码中改变的地方。首先List(Of Customer)对T进行了指定，所以现在customerList对象就是一个只能装Customer类型元素的列表。这件事是在编译期间决定的，因此编译期始终知道customerList元素的类型，所以在取出其中对象时无需再进行任何类型装换。更重要的是，现在再向customerList中放入不是Customer类型的变量就会出现编译错误，而不是原来的运行时错误了。泛型能让编译期明确正在操作的类型，它就不会对值类型进行装箱操作，于是性能也大大提高了。使用泛型的另外一个好处是，Visual Basic的IDE能够为你提供智能感知，当你使用customerList.Add时，含有正确信息的提示出现了：

开始编写泛型的代码

泛型提供给你的不仅仅是使用.NET Framework中已经设计好的泛型类型，你完全可以自己书写泛型的代码。仍然是使用Of语句：

Class MyGeneric(Of T)

这时，Of语句的作用不再是为类型参数提供所需的类型，而是定义新的类型参数。现在MyGeneric就接受一个名为T的类型参数。在MyGeneric泛型类的内部T被看作一个类型。你应当将T想象成使用该泛型类时能在Of语句之后提供的任何类型。现在只要对T进行编码就行了，比如：

Class MyGeneric(Of T)
    Private myVar As T

    Public Sub SetVar(ByVal newValue As T)
        myVar = newValue
    End Sub

    Public Function GetVar() As T
        Return myVar
    End Function
End Class

相当简单吧。当你要使用这个泛型类的时候，如同Framework提供的泛型类一样，要指定类型参数T的真实类型。如这一语句：

Dim obj As New MyGeneric(Of Integer)

这时obj的类型实际上就是一个将上述定义中所有T都换成Integer的类型。而

Dim obj As New MyGeneric(Of String)

这条语句中，obj则是一个T为String型的实例。你可以任意指定类型参数，以便创建出更多适于不同类型的对象，这就是泛型的精髓——“书写一次，使用于广泛的类型”。

泛型不仅仅能用于类型的定义，你还能够定义泛型的方法。其语法和泛型类型基本一样：

Public Function IIf(Of T)(Expression As Boolean, TruePart As T, _
    FalsePart As T) As T

这就是一个泛型方法，其参数和返回类型都可以使用类型参数T所表示的类型。泛型方法可以像泛型类型那样，使用Of语句来确定类型参数T：

max = IIf(Of Integer)(a > b, a, b)

通过指定类型参数为Integer，我们的IIf(Of T)函数就成了专门针对Integer的IIf函数。其实，Visual Basic还支持类型参数的隐式指定，就是说当参数或返回值能够有足够的信息确定类型参数时，Of语句就不必写了。比如

Dim max, a, b As Integer
a = 100
b = 50

max = IIf(a > b, a, b)

着段代码中a和b的类型已经都确定为Integer因此IIf(Of T)函数不必通过明确制定类型参数也能知道此处的类型参数应该是Integer。这将大大简化代码的书写，又不失泛型带来的性能好处。

 

泛型的类型系统

泛型类型（Generic Type）通过赋予类型参数，在使用时可以表现为多种构造类型（Constructed Type）。如TheClass(Of T)在使用时可以是TheClass(Of Int32)，也可以是TheClass(Of String)他们都是不同的类型。这些类型之间没有任何继承关系，也没有互相包容的功能。TheClass(Of Object)并不是其他TheClass(Of T)构造类型的基类，也没有一种写法可以表示类型参数为任意类型的情况。这种类型衍生往往会连带泛型类内嵌类型一起衍生。比如在TheClass(Of T)中内嵌定义有枚举（或结构、委托、类等）TypeA，则TheClass(Of Int32).TypeA和TheClass(Of String).TypeA也非相同类型。在.Net Framwork的类库中，这种情形频繁出现，如List(Of T).Enumerator。因此，注意让你的内嵌类性与泛型的类型参数有关，否则就应该将内嵌类型定义到泛型类型的外部，以免发生类型衍生。一般不要在泛型类型中内嵌定义另一个泛型类型，如ClassA(Of T1).ClassB(Of T2)，他在衍生类型的时候就更复杂了，因为两个类型参数都可以赋予不同的类型，会产生大量你也不知道有什么用的构造类型。

.NET Framework还增强了反射的功能以便在运行时研究泛型类型及其所有构造类型。每个构造类型都有确定的类型，可以通过obj.GetType()获取运行时类型的Type对象，还可以用GetType运算符获取泛型类型本身或其任何构造类型的Type对象。现在Type类有HasGenericParameters属性以指示此类型是否源自泛型类型，以及HasUnboundGenericParameters属性以指示此泛型类型的所有类型参数是否已经确定等。你还可以通过Type对象的相关方法检测泛型类型每个类型参数的详细状况。

约束

约束（Constraint）这一功能的本意是缩小类型参数所能取值的范围。比如你希望你的类ClassA(Of T)中类型参数T只能接受Exception或其子类等要求，可以通过约束这一功能达成。约束会带来一种“副作用”，事实上更多人把这个副作用当成约束的主要功能来用，我们下边详细叙述。约束的语法是：

Definition(Of TypeParam As Constraints)

比如我们要给ClassA定义类型参数T，并约束T只能为Exception或其子类的定义为：

Class ClassA(Of T As Exception)

如果我们要写ClassA(Of Integer)就会产生编译错误，因为T已经不能去Int32作类型参数了。T的取值范围已经缩小，除此之外约束还有什么功能呢。我们可以在ClassA中定义一个方法：

Public Sub ThrowIt(ByVal ex As T)
    Throw ex
End Sub

我们写了Throw ex，为什么可以这样写？可以试试将类型定义中的“As Exception”去除，这里立即就会有编译错误。这是因为.NET默认情况下不允许对类型参数的对象施以任何操作，除了能对Object类型进行的操作以外。就是说默认情况下T类型的对象没有除Object类型所具有的方法/属性以外的任何成员，也不能使用任何运算符。这通常是一个很大的限制。但当你使用约束时，类型参数就会自动具有继承自约束类型的所有功能。比如继承自Exception就可以用于Throw语句，而约束了Exception的类型参数T的对象同样可以用于Throw语句。我们常常这样写：

Class ClassB(Of T As IDisposable)

这样T的取值范围就被限定在实现了IDisposable的所有类型中，而副作用是T型对象具有IDisposable接口的成员：Dispose()方法。比如书写这样的过程。

Public Sub DisposeIt(ByVal obj As T)
    obj.Dispose()
End Sub

我要强调约束的主要功能是减少类型参数的取值范围，而不是给类型参数增加可操作的功能（那只是副作用）。一般不要为了这种目的给类型参数加约束。比如你想让操作对象有Dispose方法，不妨用这种写法代替约束：

Public Sub DisposeIt(ByVal obj As IDisposable)
    obj.Dispose()
End Sub

只有当你的类型参数一定要有某种功能，否则整个泛型类都无法工作的时候，才使用约束。不然你会发现约束了很多类型后，你的泛型类型的用途大大减少了。

还有一种特殊的约束——构造器约束。他约束你的类型参数只能取那些有一个不带参数的公有构造器的类型。其副作用是，你可以在这个泛型类中创建类型参数的实例：

Public Class ClassB(Of T As New)
    Public Sub MySub()
        Dim o As T
        o = New T()
    End Sub
End Class

注意构造器的写法：用New关键字作约束类型。构造器约束看起来很有用。

如果你要约束两个以上的类型，你可以把要约束的类型放在花括号里{}，就像数组一样。比如你的类型参数同时需要约束构造器和IDisposable，就这样写：

Public Class ClassC(Of T As {IDisposable, New})

你还可以用多约束做一些以前只用接口做不到的事情，比如这样：

Sub MyMethod(Of T As {IDisposable, ICloneable})(ByVal obj As T)

这个定义实现了让参数obj的类型只能为同时实现了两个接口的类型，不用泛型你以前可以做到吗？