如何得到listview的总列数与总行数

一个很有趣的问题，因为Listview带有的属性会让我们忽略去思考某些问题。

主要方法使用sendmessage，知道使用哪个常数。

VB自带的浏览器是查找不到，所以可以通过MSDN查或者网站查(http://vbnet.mvps.org/index.html?code/comctl/lvmembers.htm)

思路：通过LVM_GETHEADER获得listview的头的窗口句柄，获得了这个窗口的句柄就可以通过HDM_消息来操作了。

感谢下老大提供的支持.

'*************************************************************************
'**日    期：2006-03-09 22:48:52
'**描    述：如何使用API得到Listview的总列数和总行数
'*************************************************************************
Option Explicit

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

Private Const LVM_FIRST = &H1000
Private Const LVM_GETITEMCOUNT = (LVM_FIRST + 4)
Private Const LVM_GETCOLUMNORDERARRAY = (LVM_FIRST + 59)
Const LVM_GETHEADER = (LVM_FIRST + 31)
Const HDM_FIRST = &H1200
Const HDM_GETITEMCOUNT = (HDM_FIRST + 0)

Private Sub Command1_Click()
    '直接得到总行数
    Debug.Print "总行数是" & Me.ListView1.ListItems.count
    Debug.Print "总列数是" & Me.ListView1.ColumnHeaders.count
End Sub

Private Sub Command2_Click()
    '利用API得到

    Dim i As Long
    Dim j As Long
    Dim n As Long

    i = SendMessage(ListView1.hwnd, LVM_GETHEADER, 0, ByVal 0&)
    j = SendMessage(i, HDM_GETITEMCOUNT, 0, ByVal 0&)
    n = SendMessage(Me.ListView1.hwnd, LVM_GETITEMCOUNT, 1, ByVal 0&)
    Debug.Print "总列数是:" & j
    Debug.Print "总行数是:" & n
End Sub

Private Sub Form_Load()
    Dim i As Integer

    With Me.ListView1
        .View = lvwReport
        .ColumnHeaders.Add , , "a"
        .ColumnHeaders.Add , , "b"

        For i = 1 To 33
            .ListItems.Add , , i
            .ListItems(i).SubItems(1) = i + 1
        Next
    End With
End Sub