vb6.0 控件适应窗口大小

我们在编写vb6.0控件适应窗口大小时，往往使用以下方法：(按照窗体尺寸缩放比例自动调整控件的大小)

　　窗体和控件的大小由窗体和控件的Width属性和Height属性确定。所以当用户界面设计完成之后，窗体及其内部的各控件的Width, Height属性便随之确定下来；从而窗体相对于每一个控件，它们的宽度之比、高度之比均被确定。如果窗体Forml内的一个文本框Text1的宽(即Text1的Width属性值)为3610，高度(即Text1的Height属性值)为1935;而窗体Form1的上述两个值分别为4890和3615，则它们的宽度之比和高度之比分别为：361014890、193513615。当用户在程序启动后调整了窗体的尺寸，窗体的宽度和高度将分别为Form1.ScaleWidth，Form1.ScaleHeight；此时应该按上述比例来调整文本框Textl的的高度和宽度值。即：

　　(调整后的Text1的Width属性值)/( Form1.ScaleWidth)=3610/4890；

　　(调整后的Text1的Height属性值)/(Form1.Scale-Height)=1935/3615；

　　所以调整后的Text1的Width属性值=(3610/4890)* Form1.ScaleWidth；

　　调整后的Text1的Height属性值=(1935/3615) * Form1.ScaleHeight；

　　对于一般控件来说，应该有：

　　调整后的控件的Width属性值=(控件原Width属性值/窗体原Width属性值)*窗体.ScaleWidth

调整后的控件的Height属性值=(控件原Height属性值/窗体值/窗体原Height属性值)*窗体.ScaleHeight

按照上述方法确定窗体缩放后控件Width和Height属性值，则当窗体尺寸被调整后，控件的大小将按比例得到相应的调整。

但是当遇到窗体中有多个控件，并且有的控件没有width等属性，如timer控件。则首先要进行多控件处理，然后加入相应代码避免某些控件检查。以一工程范例说明如下：

1、新建一vb6.0工程，随意加入几个控件，如下图所示：

2、标准模块声明写入(自定义类型)：

Type cp
  wp As Single
  hp As Single
  tp As Single
  lp As Single
End Type

3、主窗口(Form1)，添加如下代码：

Dim ap() As cp  '定义窗体数组
'定义窗体过程
Private Sub ai()
Dim i As Integer
On Error GoTo uerror   '跳过无width属性控件
For i = 0 To Controls.Count - 1
With ap(i)
.wp = Controls(i).Width / Form1.ScaleWidth
.hp = Controls(i).Height / Form1.ScaleHeight
.lp = Controls(i).Left / Form1.ScaleWidth
.tp = Controls(i).Top / Form1.ScaleHeight
End With
Next i
Exit Sub
uerror:
    Resume Next
End Sub
'窗体初始化
Private Sub Form_Load()
ReDim ap(0 To Controls.Count - 1)
ai
End Sub
'窗体尺寸改变时
Private Sub Form_Resize()
Dim i As Integer
On Error GoTo uerror
For i = 0 To Controls.Count - 1
Controls(i).Move ap(i).lp * Form1.ScaleWidth, ap(i).tp * Form1.ScaleHeight, ap(i).wp * Form1.ScaleWidth, ap(i).hp * Form1.ScaleHeight
Next i
Exit Sub
uerror:
    Resume Next
End Sub

4、点击运行，拖动窗体改变尺寸，既可以看到控件适应窗体大小改变。