理解变量字符的截取功能

 http://www.cn-dos.net/forum/viewthread.php?tid=25746

::code by lxmxn @ cn-dos.net .
::目的：帮助新手们更好的理解变量字符截取功能.
::Date 2006-12-16 .
::说明：有的变量截取之后值为空，这是正常的.
@echo off&setlocal EnableDelayedexpansion
::设置变量var的值：
set var=0123456789ABCDEF
call :begin
for /l %%a in (1,3,15) do (
    for /l %%b in (1,4,15) do (
        call :printf %%a %%b
    )
)
call :begin
for /l %%a in (1,4,15) do (
    for /l %%b in (-1,-3,-15) do (
        call :printf  %%a %%b
    )
)
call :begin
for /l %%a in (-2,-3,-15) do (
    for /l %%b in (1,4,15) do (
        call :printf  %%a %%b
    )
)
call :begin
for /l %%a in (-1,-4,-15) do (
    for /l %%b in (-2,-3,-15) do (
        call :printf  %%a %%b
    )
)
pause
endlocal&cls&echo.
echo 演示结束了，任意键退出……
pause>nul
goto :eof

::输出结果：
:printf
    echo %%var:~%1,%2%%        截取之后的字符为:        !var:~%1,%2!
    goto :eof

::清理屏幕：
:begin
    echo\&pause&cls&echo.
    echo                         变量var的值为:        %var%
    echo.
    goto :eof

＝＝＝

http://article.lre.cn/article/10001572.htm

　从一个批处理程序中调用另一个批处理程序，而不会引起第一个批处理的中止。

　　语法：CALL[drive:][path]filename[batch-parameters]

　　参数：[drive:][path]filename，指定要调用的批处理程序的名字及其存放处。文件名必须用.BAT作扩展名。

　　batch-parameters　指定批处理程序所需的命令行信息。

　　CALL　注解

　　使用批处理参数：批处理参数可包含传递给批处理程序的任何信息，包括开关项、文件名、可替换参数%1至%9，以及环境变量，如%baud%。

　　使用管道和重定向符：在CALL命令中，不要用管道（"|"）和重定向符号（"<<"，"<"，">"，和">>"）。

　　递归调用：可以创建一个批处理程序调用它本身，但必须有一条exit命令。否则，父、子批处理程序将无限循环下去。

　　＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝

　　CALL　例子

　　从另一批处理程序运行 CHECKNEW.BAT，在父批处理程序中可包含命令：call checknew

　　假设父批处理程序接收两个可替换参数，并希望将它们传给CHECKNEW.BAT。可在父批理程序中使用命令：call checknew %1%2

 

=================

@echo off
set str=123456789
echo 第一个字符为：%str:~0,1%
echo 头两个字符为：%str:~0,2%
echo 头5个字符为：%str:~0,5%
echo 去掉最后一个字符后的字符串为：%str:~0,-1%
echo 去掉最后3个字符后的字符串为：%str:~0,-3%
echo 第4个字符为：%str:~3,1%
echo 第4个及其之后的3个字符为：%str:~3,4%
echo 最后一个字符为：%str:~-1%
echo 最后一个字符为：%str:~-1,1%
echo 最后一个字符为：%str:~-1,2%
echo 倒数第4个字符为：%str:~-4,1%
echo 倒数第4个及其之后的字符为：%str:~-4%
echo 倒数第4个及其之后的1个字符为：%str:~-4,2%
echo 倒数第4个及其之后的2个字符为：%str:~-4,3%
pause
为了说明这个问题,我在这里把批处理取字符,做下进一步的解释,希望对新手有所启发
如下:
echo %var:~n,k%
我们在这里对每个参数做个说明:"%var",即我们要从中要截取字符的字符串." ~ "取字

符标志符(我是这么理解的),"n" 我们将其理解为指针,"k"我们将其理解为偏移地址.(注

:指针和偏移地址都是从零开始数的)
我们还是用namejm版主的例子做下说明:

@echo off
set str=123456789

rem 定义一个str字符串为123456789

echo 第一个字符为：%str:~0,1%

rem 指针为0,偏移地址为1,即从第0位开始,取1位

echo 头两个字符为：%str:~0,2%

rem 指针为0,偏移地址为2,即从第0位开始,取2位

echo 头5个字符为：%str:~0,5%

rem    指针为0,偏移地址为5,即从第0位开始,取5位

echo 去掉最后一个字符后的字符串为：%str:~0,-1%

rem 当"k"为负值时,我们可以这样理解:从指针开始处开始取其后面所有字符,然后减去

后面"abs(k)位"..所以这个句字我们可以做如下解释:从第0位开始取其全部字符

为:123456789然后从后面减去abs(k)位,所以最后结果为:12345678

echo 去掉最后3个字符后的字符串为：%str:~0,-3%

rem    该句解释同上↑

echo 最后一个字符为：%str:~-1%

rem    参数"n,"和"k"都可以为缺省,缺省"n,"时可以理解为:从abs(k)位开始取其全部

echo 倒数第4个及其之后的字符为：%str:~-4%

rem    解释同上↑

echo 最后一个字符为：%str:~-1,1%

rem    n为负值时,表示从后面开始截取字符,取k位(此时n应从1开始数)

echo 最后一个字符为：%str:~-1,2%

rem    解释同上↑

echo 倒数第4个字符为：%str:~-4,1%

rem    解释同上↑

echo 倒数第4个及其之后的1个字符为：%str:~-4,2%

rem    解释同上↑

echo 倒数第4个及其之后的2个字符为：%str:~-4,3%

rem 解释同上↑

pause