AR发票导入程序
来源:互联网 发布:it服务外包排名 编辑:程序博客网 时间:2024/04/28 18:16
CREATE OR REPLACE PACKAGE APPS.MEW_AR_INVOICE_TRC_PKG IS
/* =============================================================
* Copyright (C) Panasonic Co., Ltd All rights reserved
* =============================================================
* Program Name : mew_ar_invoice_trc_pkg
* Author : zhuhailong
* Created Date : 2012-12-2
* Purpose : 松下新会计准则AR发票导入
* Update History
* Version Date Name Description
* -------- --------------- -------------- --------------------
* V1.0 2012-12-2 朱海龙 Creation
===========================================================*/
G_INNER_EXCEPTION EXCEPTION; --内部异常
G_INSERT_EXCEPTION EXCEPTION; --插入异常
G_ERROR_MSG VARCHAR2(100); --错误信息
--接口主过程
PROCEDURE IMPORT_TRANSACTION_P(P_ORG_CODE VARCHAR2);
--获取org_id,set_of_book_id
PROCEDURE GET_ORG_ID(P_ORG_CODE IN VARCHAR2
,P_ORG_ID OUT NUMBER
,P_SET_OF_BOOKS_ID OUT NUMBER);
--获取cust_trx_type_id
PROCEDURE GET_TRX_TYPE_ID(P_TYPE_CODE IN VARCHAR2
,P_ORG_ID IN NUMBER
,P_TYPE_ID OUT NUMBER);
--获取客户信息
PROCEDURE GET_CUSTOMER_INFO(P_CUSTOMER_CODE IN VARCHAR2
,P_SITE_USE_CODE IN VARCHAR2
,P_SITE_USE_ID IN NUMBER
,P_ORG_ID IN NUMBER
,P_CUST_ACCOUNT_ID OUT NUMBER
,P_CUST_ACCT_SITE_ID OUT NUMBER);
--获取term_id
PROCEDURE GET_TERM_ID(P_TERM_NAME IN VARCHAR2
,P_TERM_ID OUT NUMBER);
--获取salesrep_id
PROCEDURE GET_SALESREP_ID(P_SALESREP IN VARCHAR2
,P_ORG_ID IN NUMBER
,P_SALESREP_ID OUT NUMBER);
--获取memo_id
PROCEDURE GET_MEMO_ID(P_MEMO_NAME IN VARCHAR2
,P_ORG_ID IN VARCHAR2
,P_MEMO_ID OUT NUMBER);
--插入接口表
PROCEDURE INSERT_IFACE_P(P_BATCH_SOURCE_NAME IN VARCHAR2
,P_SET_OF_BOOKS_ID IN NUMBER
,P_TRX_NUMBER IN VARCHAR2
,P_DESCRIPTION IN VARCHAR2
,P_CURRENCY_CODE IN VARCHAR2
,P_AMOUNT IN NUMBER
,P_CUST_TRX_TYPE_ID IN NUMBER
,P_TERM_ID IN NUMBER
,P_ORIG_SYSTEM_BILL_CUSTOMER_ID IN NUMBER
,P_ORIG_SYSTEM_BILL_ADDRESS_ID IN NUMBER
,P_ORIG_SYSTEM_SHIP_CUSTOMER_ID IN NUMBER
,P_ORIG_SYSTEM_SHIP_ADDRESS_ID IN NUMBER
,P_ORIG_SYSTEM_SOLD_CUSTOMER_ID IN NUMBER
,P_CONVERSION_TYPE IN VARCHAR2
,P_CONVERSION_DATE IN DATE
,P_CONVERSION_RATE IN NUMBER
,P_PRIMARY_SALESREP_ID IN NUMBER
,P_ORG_ID IN NUMBER
,P_VAT_CODE IN VARCHAR2
,P_TRX_DATE IN DATE
,P_GL_DATE IN DATE
,P_MEMO_LINE_ID IN NUMBER);
END MEW_AR_INVOICE_TRC_PKG;
/
CREATE OR REPLACE PACKAGE BODY APPS.MEW_AR_INVOICE_TRC_PKG IS
/* =============================================================
* Copyright (C) Panasonic Co., Ltd All rights reserved
* =============================================================
* Program Name : mew_ar_invoice_trc_pkg
* Author : zhuhailong
* Created Date : 2012-12-2
* Purpose : 松下新会计准则AR发票导入
* Update History
* Version Date Name Description
* -------- --------------- -------------- --------------------
* V1.0 2012-12-2 朱海龙 Creation
===========================================================*/
--接口主过程
PROCEDURE IMPORT_TRANSACTION_P(P_ORG_CODE VARCHAR2) IS
--临时表游标
CURSOR C1 IS
SELECT MAIT.INVOICE_ID
,MAIT.ORG_CODE
,MAIT.INVOICE_NUM
,MAIT.BATCH_SOURCE_NAME
,MAIT.TRANCATION_NAME
,MAIT.INVOCIE_DATE
,MAIT.BILL_TO_NUM
,MAIT.SHIP_TO_NUM
,MAIT.TERM
,MAIT.CURRENCY
,MAIT.CONVERSION_TYPE
,MAIT.CONVERSION_DATE
,MAIT.CONVERSION_RATE
,MAIT.SALESREP
,MAIT.AMOUNT
,MAIT.VAT_CODE
,MAIT.GL_DATE
,MAIT.LINE_DESCRIPTION
,MAIT.MEMO_NAME
,MAIT.BILL_SITE_USE_ID
,MAIT.SHIP_SITE_UES_ID
FROM MEW_AR_INVOICE_TRC_TEMP MAIT
WHERE MAIT.ORG_CODE = P_ORG_CODE;
V_ORG_ID NUMBER;
V_SET_OF_BOOKS_ID NUMBER;
V_TYPE_ID NUMBER;
V_BILL_TO_CUST_ID NUMBER;
V_BILL_TO_SITE_ID NUMBER;
V_SHIP_TO_CUST_ID NUMBER;
V_SHIP_TO_SITE_ID NUMBER;
V_TERM_ID NUMBER;
V_SALESREP_ID NUMBER;
V_MEMO_ID NUMBER;
V_SUCESS_FLAG VARCHAR2(1) := 'N';
V_COUNT PLS_INTEGER := 1; --插入计数器
V_SUCESS_NUM NUMBER := 0; --成功记录数
V_FAIL_NUM NUMBER := 0; --失败记录数
BEGIN
DBMS_OUTPUT.PUT_LINE('程序开始!');
DBMS_OUTPUT.PUT_LINE('-----------------------------------------');
FOR INVOICE_REC IN C1
LOOP
BEGIN
--获取org_id,set_of_book_id
MEW_AR_INVOICE_TRC_PKG.GET_ORG_ID(P_ORG_CODE => INVOICE_REC.ORG_CODE
,P_ORG_ID => V_ORG_ID
,P_SET_OF_BOOKS_ID => V_SET_OF_BOOKS_ID);
--获取cust_trx_type_id
MEW_AR_INVOICE_TRC_PKG.GET_TRX_TYPE_ID(P_TYPE_CODE => INVOICE_REC.TRANCATION_NAME
,P_ORG_ID => V_ORG_ID
,P_TYPE_ID => V_TYPE_ID);
--获取收单方信息
MEW_AR_INVOICE_TRC_PKG.GET_CUSTOMER_INFO(P_CUSTOMER_CODE => INVOICE_REC.BILL_TO_NUM
,P_SITE_USE_CODE => 'BILL_TO'
,P_ORG_ID => V_ORG_ID
,P_SITE_USE_ID => INVOICE_REC.BILL_SITE_USE_ID
,P_CUST_ACCOUNT_ID => V_BILL_TO_CUST_ID
,P_CUST_ACCT_SITE_ID => V_BILL_TO_SITE_ID);
--获取收货方信息
MEW_AR_INVOICE_TRC_PKG.GET_CUSTOMER_INFO(P_CUSTOMER_CODE => INVOICE_REC.SHIP_TO_NUM
,P_SITE_USE_CODE => 'SHIP_TO'
,P_ORG_ID => V_ORG_ID
,P_SITE_USE_ID => INVOICE_REC.SHIP_SITE_UES_ID
,P_CUST_ACCOUNT_ID => V_SHIP_TO_CUST_ID
,P_CUST_ACCT_SITE_ID => V_SHIP_TO_SITE_ID);
--获取term_id
MEW_AR_INVOICE_TRC_PKG.GET_TERM_ID(P_TERM_NAME => INVOICE_REC.TERM
,P_TERM_ID => V_TERM_ID);
--获取salesrep_id
MEW_AR_INVOICE_TRC_PKG.GET_SALESREP_ID(P_SALESREP => INVOICE_REC.SALESREP
,P_ORG_ID => V_ORG_ID
,P_SALESREP_ID => V_SALESREP_ID);
--获取memo_id
MEW_AR_INVOICE_TRC_PKG.GET_MEMO_ID(P_MEMO_NAME => INVOICE_REC.MEMO_NAME
,P_ORG_ID => V_ORG_ID
,P_MEMO_ID => V_MEMO_ID);
--插入接口表
MEW_AR_INVOICE_TRC_PKG.INSERT_IFACE_P(P_BATCH_SOURCE_NAME => INVOICE_REC.BATCH_SOURCE_NAME
,P_SET_OF_BOOKS_ID => V_SET_OF_BOOKS_ID
,P_TRX_NUMBER => INVOICE_REC.INVOICE_NUM
,P_DESCRIPTION => INVOICE_REC.LINE_DESCRIPTION
,P_CURRENCY_CODE => INVOICE_REC.CURRENCY
,P_AMOUNT => INVOICE_REC.AMOUNT
,P_CUST_TRX_TYPE_ID => V_TYPE_ID
,P_TERM_ID => V_TERM_ID
,P_ORIG_SYSTEM_BILL_CUSTOMER_ID => V_BILL_TO_CUST_ID
,P_ORIG_SYSTEM_BILL_ADDRESS_ID => V_BILL_TO_SITE_ID
,P_ORIG_SYSTEM_SHIP_CUSTOMER_ID => V_SHIP_TO_CUST_ID
,P_ORIG_SYSTEM_SHIP_ADDRESS_ID => V_SHIP_TO_SITE_ID
,P_ORIG_SYSTEM_SOLD_CUSTOMER_ID => V_BILL_TO_CUST_ID
,P_CONVERSION_TYPE => INVOICE_REC.CONVERSION_TYPE
,P_CONVERSION_DATE => INVOICE_REC.CONVERSION_DATE
,P_CONVERSION_RATE => INVOICE_REC.CONVERSION_RATE
,P_PRIMARY_SALESREP_ID => V_SALESREP_ID
,P_ORG_ID => V_ORG_ID
,P_VAT_CODE => INVOICE_REC.VAT_CODE
,P_TRX_DATE => INVOICE_REC.INVOCIE_DATE
,P_GL_DATE => INVOICE_REC.GL_DATE
,P_MEMO_LINE_ID => V_MEMO_ID);
--回写成功信息
V_SUCESS_FLAG := 'Y';
UPDATE MEW_AR_INVOICE_TRC_TEMP MAIT
SET MAIT.PROCESS_FLAG = V_SUCESS_FLAG
,MAIT.ERROR_MSG = ''
WHERE MAIT.INVOICE_ID = INVOICE_REC.INVOICE_ID;
--dbms_output.put_line(v_count || '导入成功!');
V_COUNT := V_COUNT + 1;
EXCEPTION
WHEN G_INSERT_EXCEPTION THEN
--回写失败信息
V_SUCESS_FLAG := 'N';
UPDATE MEW_AR_INVOICE_TRC_TEMP MAIT
SET MAIT.PROCESS_FLAG = V_SUCESS_FLAG
,MAIT.ERROR_MSG = G_ERROR_MSG
WHERE MAIT.INVOICE_ID = INVOICE_REC.INVOICE_ID;
V_COUNT := V_COUNT + 1;
END;
IF V_SUCESS_FLAG = 'Y'
THEN
V_SUCESS_NUM := V_SUCESS_NUM + 1;
ELSIF V_SUCESS_FLAG = 'N'
THEN
V_FAIL_NUM := V_FAIL_NUM + 1;
ELSE
NULL;
END IF;
END LOOP;
--commit;
DBMS_OUTPUT.PUT_LINE('-----------------------------------------');
DBMS_OUTPUT.PUT_LINE('成功导入' || V_SUCESS_NUM || '条!');
DBMS_OUTPUT.PUT_LINE('失败' || V_FAIL_NUM || '条!');
DBMS_OUTPUT.PUT_LINE('程序结束!');
END IMPORT_TRANSACTION_P;
--获取org_id,set_of_book_id
PROCEDURE GET_ORG_ID(P_ORG_CODE IN VARCHAR2
,P_ORG_ID OUT NUMBER
,P_SET_OF_BOOKS_ID OUT NUMBER) IS
BEGIN
IF P_ORG_CODE IS NOT NULL
THEN
SELECT HOU.ORGANIZATION_ID
,HOU.SET_OF_BOOKS_ID
INTO P_ORG_ID
,P_SET_OF_BOOKS_ID
FROM HR_OPERATING_UNITS HOU
WHERE HOU.NAME = TRIM(P_ORG_CODE);
END IF;
EXCEPTION
WHEN NO_DATA_FOUND THEN
G_ERROR_MSG := 'get_org_id发生no_data_found异常!';
RAISE G_INSERT_EXCEPTION;
WHEN TOO_MANY_ROWS THEN
G_ERROR_MSG := 'get_org_id发生too_many_rows异常!';
RAISE G_INSERT_EXCEPTION;
END;
--获取cust_trx_type_id
PROCEDURE GET_TRX_TYPE_ID(P_TYPE_CODE IN VARCHAR2
,P_ORG_ID IN NUMBER
,P_TYPE_ID OUT NUMBER) IS
BEGIN
IF P_TYPE_CODE IS NOT NULL AND
P_ORG_ID IS NOT NULL
THEN
SELECT RCTT.CUST_TRX_TYPE_ID
INTO P_TYPE_ID
FROM RA_CUST_TRX_TYPES_ALL RCTT
WHERE RCTT.ORG_ID = P_ORG_ID
AND RCTT.NAME = TRIM(P_TYPE_CODE);
END IF;
EXCEPTION
WHEN NO_DATA_FOUND THEN
G_ERROR_MSG := 'get_trx_type_id发生no_data_found异常!';
RAISE G_INSERT_EXCEPTION;
WHEN TOO_MANY_ROWS THEN
G_ERROR_MSG := 'get_trx_type_id发生too_many_rows异常!';
RAISE G_INSERT_EXCEPTION;
END GET_TRX_TYPE_ID;
--获取客户信息
PROCEDURE GET_CUSTOMER_INFO(P_CUSTOMER_CODE IN VARCHAR2
,P_SITE_USE_CODE IN VARCHAR2
,P_SITE_USE_ID IN NUMBER
,P_ORG_ID IN NUMBER
,P_CUST_ACCOUNT_ID OUT NUMBER
,P_CUST_ACCT_SITE_ID OUT NUMBER) IS
BEGIN
IF P_CUSTOMER_CODE IS NOT NULL AND
P_SITE_USE_CODE IS NOT NULL AND
--p_site_use_id is not null and
P_ORG_ID IS NOT NULL
THEN
SELECT HZCA.CUST_ACCOUNT_ID
,HZCS.CUST_ACCT_SITE_ID
INTO P_CUST_ACCOUNT_ID
,P_CUST_ACCT_SITE_ID
FROM HZ_PARTIES PARTY
,HZ_CUST_ACCOUNTS HZCA
,HZ_CUST_ACCT_SITES_ALL HZCS
,HZ_CUST_SITE_USES_ALL HZCSU
WHERE 1 = 1
AND PARTY.PARTY_ID = HZCA.PARTY_ID
AND HZCS.CUST_ACCOUNT_ID = HZCA.CUST_ACCOUNT_ID
AND HZCSU.CUST_ACCT_SITE_ID = HZCS.CUST_ACCT_SITE_ID
AND PARTY.PARTY_NUMBER = TRIM(P_CUSTOMER_CODE)
AND HZCSU.ORG_ID = P_ORG_ID
AND HZCSU.SITE_USE_ID = NVL(P_SITE_USE_ID
,HZCSU.SITE_USE_ID)
AND HZCSU.SITE_USE_CODE = TRIM(P_SITE_USE_CODE)
--and hzcsu.primary_flag = 'Y'
--and hzcsu.primary_flag = decode(p_site_use_code,'SHIP_TO','Y',hzcsu.primary_flag)
AND HZCSU.STATUS = 'A'
AND HZCA.STATUS = 'A';
END IF;
EXCEPTION
WHEN NO_DATA_FOUND THEN
G_ERROR_MSG := P_SITE_USE_CODE ||
'get_customer_info 发生no_data_found异常!';
RAISE G_INSERT_EXCEPTION;
WHEN TOO_MANY_ROWS THEN
G_ERROR_MSG := P_SITE_USE_CODE ||
'get_customer_info发生too_many_rows异常!';
RAISE G_INSERT_EXCEPTION;
END GET_CUSTOMER_INFO;
--获取term_id
PROCEDURE GET_TERM_ID(P_TERM_NAME IN VARCHAR2
,P_TERM_ID OUT NUMBER) IS
BEGIN
IF P_TERM_NAME IS NOT NULL
THEN
SELECT RT.TERM_ID
INTO P_TERM_ID
FROM RA_TERMS RT
WHERE RT.NAME = TRIM(P_TERM_NAME);
END IF;
EXCEPTION
WHEN NO_DATA_FOUND THEN
G_ERROR_MSG := 'get_term_id发生no_data_found异常!';
RAISE G_INSERT_EXCEPTION;
WHEN TOO_MANY_ROWS THEN
G_ERROR_MSG := 'get_term_id发生too_many_rows异常!';
RAISE G_INSERT_EXCEPTION;
END GET_TERM_ID;
--获取salesrep_id
PROCEDURE GET_SALESREP_ID(P_SALESREP IN VARCHAR2
,P_ORG_ID IN NUMBER
,P_SALESREP_ID OUT NUMBER) IS
BEGIN
IF P_SALESREP IS NOT NULL AND
P_ORG_ID IS NOT NULL
THEN
SELECT JRS.SALESREP_ID
INTO P_SALESREP_ID
FROM JTF_RS_SALESREPS JRS
WHERE JRS.NAME = TRIM(P_SALESREP)
--and jrs.status = 'A'
AND JRS.ORG_ID = P_ORG_ID
AND ROWNUM = 1;
END IF;
EXCEPTION
WHEN NO_DATA_FOUND THEN
G_ERROR_MSG := 'get_salesrep_id发生no_data_found异常!';
RAISE G_INSERT_EXCEPTION;
WHEN TOO_MANY_ROWS THEN
G_ERROR_MSG := 'get_salesrep_id发生too_many_rows异常!';
RAISE G_INSERT_EXCEPTION;
END GET_SALESREP_ID;
--获取memo_id
PROCEDURE GET_MEMO_ID(P_MEMO_NAME IN VARCHAR2
,P_ORG_ID IN VARCHAR2
,P_MEMO_ID OUT NUMBER) IS
BEGIN
IF P_MEMO_NAME IS NOT NULL
THEN
SELECT ML.MEMO_LINE_ID
INTO P_MEMO_ID
FROM AR_MEMO_LINES_ALL_TL ML
WHERE ML.ORG_ID = P_ORG_ID
AND ML.NAME = P_MEMO_NAME
AND ML.LANGUAGE = 'ZHS';
END IF;
EXCEPTION
WHEN NO_DATA_FOUND THEN
G_ERROR_MSG := 'get_memo_id发生no_data_found异常!';
RAISE G_INSERT_EXCEPTION;
WHEN TOO_MANY_ROWS THEN
G_ERROR_MSG := 'get_memo_id发生too_many_rows异常!';
RAISE G_INSERT_EXCEPTION;
END GET_MEMO_ID;
--插入接口表
PROCEDURE INSERT_IFACE_P(P_BATCH_SOURCE_NAME IN VARCHAR2
,P_SET_OF_BOOKS_ID IN NUMBER
,P_TRX_NUMBER IN VARCHAR2
,P_DESCRIPTION IN VARCHAR2
,P_CURRENCY_CODE IN VARCHAR2
,P_AMOUNT IN NUMBER
,P_CUST_TRX_TYPE_ID IN NUMBER
,P_TERM_ID IN NUMBER
,P_ORIG_SYSTEM_BILL_CUSTOMER_ID IN NUMBER
,P_ORIG_SYSTEM_BILL_ADDRESS_ID IN NUMBER
,P_ORIG_SYSTEM_SHIP_CUSTOMER_ID IN NUMBER
,P_ORIG_SYSTEM_SHIP_ADDRESS_ID IN NUMBER
,P_ORIG_SYSTEM_SOLD_CUSTOMER_ID IN NUMBER
,P_CONVERSION_TYPE IN VARCHAR2
,P_CONVERSION_DATE IN DATE
,P_CONVERSION_RATE IN NUMBER
,P_PRIMARY_SALESREP_ID IN NUMBER
,P_ORG_ID IN NUMBER
,P_VAT_CODE IN VARCHAR2
,P_TRX_DATE IN DATE
,P_GL_DATE IN DATE
,P_MEMO_LINE_ID IN NUMBER) IS
V_LINES_REC RA_INTERFACE_LINES_ALL%ROWTYPE;
V_SALESCREDITS_REC RA_INTERFACE_SALESCREDITS_ALL%ROWTYPE;
V_INTERFACE_LINE_ID NUMBER;
BEGIN
SELECT RA_CUSTOMER_TRX_LINES_S.NEXTVAL
INTO V_INTERFACE_LINE_ID
FROM DUAL;
V_LINES_REC.TRX_NUMBER := SUBSTRB(TRIM(P_TRX_NUMBER)
,0
,20); --防止发票编号过长
V_LINES_REC.INTERFACE_LINE_ID := V_INTERFACE_LINE_ID;
V_LINES_REC.INTERFACE_LINE_CONTEXT := 'MEW AR IMPORT';
V_LINES_REC.INTERFACE_LINE_ATTRIBUTE1 := V_INTERFACE_LINE_ID;
V_LINES_REC.BATCH_SOURCE_NAME := TRIM(P_BATCH_SOURCE_NAME);
V_LINES_REC.SET_OF_BOOKS_ID := P_SET_OF_BOOKS_ID;
V_LINES_REC.LINE_TYPE := 'LINE';
V_LINES_REC.DESCRIPTION := TRIM(P_DESCRIPTION);
V_LINES_REC.CURRENCY_CODE := TRIM(P_CURRENCY_CODE);
V_LINES_REC.AMOUNT := P_AMOUNT;
V_LINES_REC.CUST_TRX_TYPE_ID := P_CUST_TRX_TYPE_ID;
V_LINES_REC.TERM_ID := P_TERM_ID;
V_LINES_REC.ORIG_SYSTEM_BILL_CUSTOMER_ID := P_ORIG_SYSTEM_BILL_CUSTOMER_ID;
V_LINES_REC.ORIG_SYSTEM_BILL_ADDRESS_ID := P_ORIG_SYSTEM_BILL_ADDRESS_ID;
V_LINES_REC.ORIG_SYSTEM_SHIP_CUSTOMER_ID := P_ORIG_SYSTEM_SHIP_CUSTOMER_ID;
V_LINES_REC.ORIG_SYSTEM_SHIP_ADDRESS_ID := P_ORIG_SYSTEM_SHIP_ADDRESS_ID;
V_LINES_REC.ORIG_SYSTEM_SOLD_CUSTOMER_ID := P_ORIG_SYSTEM_SOLD_CUSTOMER_ID;
V_LINES_REC.CONVERSION_TYPE := TRIM(P_CONVERSION_TYPE);
V_LINES_REC.CONVERSION_DATE := P_CONVERSION_DATE;
V_LINES_REC.CONVERSION_RATE := P_CONVERSION_RATE;
V_LINES_REC.PRIMARY_SALESREP_ID := P_PRIMARY_SALESREP_ID;
V_LINES_REC.ORG_ID := P_ORG_ID;
V_LINES_REC.TAX_CODE := TRIM(P_VAT_CODE);
V_LINES_REC.TRX_DATE := P_TRX_DATE;
V_LINES_REC.GL_DATE := P_GL_DATE;
V_LINES_REC.MEMO_LINE_ID := P_MEMO_LINE_ID;
V_SALESCREDITS_REC.INTERFACE_LINE_CONTEXT := 'MEW AR IMPORT';
V_SALESCREDITS_REC.INTERFACE_LINE_ATTRIBUTE1 := V_INTERFACE_LINE_ID;
V_SALESCREDITS_REC.SALES_CREDIT_TYPE_ID := 1;
V_SALESCREDITS_REC.SALESREP_ID := P_PRIMARY_SALESREP_ID;
V_SALESCREDITS_REC.SALES_CREDIT_PERCENT_SPLIT := 100;
INSERT INTO RA_INTERFACE_LINES_ALL VALUES V_LINES_REC;
INSERT INTO RA_INTERFACE_SALESCREDITS_ALL VALUES V_SALESCREDITS_REC;
--dbms_output.put_line('1');
END INSERT_IFACE_P;
END MEW_AR_INVOICE_TRC_PKG;
/
- AR发票导入程序
- AP发票导入程序(WEB ADI)
- AR自动开票主程序导入发票的时候,出现错误提示''不能获取汇款地址''
- AR 调整应收发票脚本
- AR 收款导入及收款核销程序
- AP发票导入(发票头行)
- AR发票与客户的关联关系
- 使用API创建AR 定金发票
- 发票套打程序
- Oracle EBS 应付发票 接口导入 API
- Oracle EBS AP发票接口导入
- 发票
- 发票
- 发票
- 发票
- 发票套打程序 源程序发布
- SD发票 可以修改程序RV60AFZZ增强
- R12 AR INVOICE 接口表导入
- java多线程 sleep()和wait()的区别
- MYSQL数据库的导出与导入
- 修改ASM磁盘的启动权限
- Android分享到新浪微博
- 集成运放芯片资料大全
- AR发票导入程序
- 高速光耦型号大全
- 局部内部类引用外部类中的局部变量必须是final属性的!
- 帕金森定律(Parkinson's Law)亦称“官场病”或“组织麻痹病”
- ubuntu支持exfat分区
- Android Junit单元测试
- FormsAuthentication实现登录
- 正则表达式
- 开源遇到挫折