CMD&DOS入口及符号的作用

主入口：cmd help

附入口：/?

 

|
① 管道符，就是将上一个命令的输出，作为下一个命令的输入."dir /a/b |more"就可以逐屏的显示dir命令所输出的信息。
② 在set/a中的二元运算符，表示按位或。
③ 在帮助文档中表示其前后两个开关、选项或参数是二选一的。

?
① 在findstr/r中表示在此位置匹配一个任意字符。
② 在路径中表示在此位置通配任意一个字符。
③ 紧跟在/后表示获取命令的帮助文档。

\
① 这个"\"符号在有的情况下，代表的是当前路径的根目录.比如当前目录在c:\windows\system32下，那么你"dir \"的话，就相当与"dir c:\"。
② 在findstr/r中表示正则转义字符。

----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

一、单符号

~
① 在for中表示使用增强的变量扩展。
② 在%var:~n,m%中表示使用扩展环境变量指定位置的字符串。
③ 在set/a中表示一元运算符，将操作数按位取反。

!
① 在set /a中一元运算符，表示逻辑非。比如set /a a=!0，这时a就表示逻辑1。

@
① 隐藏命令行本身的回显，常用于批处理中。

$
① 在findstr命令里面表示一行的结束。
② 在prompt命令里面，表示将其后的字符转义（符号化或者效果化）。

%
① 在set /a中的二元运算符，表示算术取余。
② 命令行环境下，在for命令in前，后面接一个字符（可以是字母、数字或者一些特定字符），表示指定一个循环或者遍历指标变量。
③ 批处理中，后接一个数字表示引用本批处理当前执行时的指定的参数。
④ 其它情况下，%将会被脱去（批处理）或保留（命令行）

^
① 取消特定字符的转义作用，比如& | > < ! "等，但不包括%。比如要在屏幕显示一些特殊的字符，比如> >> | ^ &等符号时，就可以在其前面加一个^符号来显示这个^后面的字符了，^^就是显示一个^，^|就是显示一个|字符了;
② 在set/a中的二元运算符，表示按位异或。
③ 在findstr/r的[]中表示不匹配指定的字符集。

&
① 命令连接字符。比如我要在一行文本上同时执行两个命令，就可以用&命令连接这两个命令。
② 在set/a中是按位与。

*
① 代表任意个任意字符，就是我们通常所说的"通配符";比如想在c盘的根目录查找c盘根目录里所有的文本文件(.txt)，那么就可以输入命令"dir c:\*.txt"。
② 在set /a中的二元运算符，表示算术乘法。
③ 在findstr/r中表示将前一个字符多次匹配。

-
① 范围表示符，比如日期的查找，for命令里的tokens操作中就可以用到这个字符。
② 在findstr/r中连接两个字符表示匹配范围。
③ -跟在某些命令的/后表示取反向的开关。
④ 在set /a中：
1.表示一个负数。
2.表示算术减运算。

+
① 主要是在copy命令里面会用到它，表示将很多个文件合并为一个文件，就要用到这个+字符了。
② 在set/a中的二元运算符,表示算术加法。

:
① 标签定位符，表示其后的字符串为以标签，可以作为goto命令的作用对象。比如在批处理文件里面定义了一个":begin"标签，用"goto begin"命令就可以转到":begin"标签后面来执行批处理命令了。
② 在%var:string1=string2%中分隔变量名和被替换字串关系。

|
① 管道符，就是将上一个命令的输出，作为下一个命令的输入."dir /a/b |more"就可以逐屏的显示dir命令所输出的信息。
② 在set/a中的二元运算符，表示按位或。
③ 在帮助文档中表示其前后两个开关、选项或参数是二选一的。

/
① 表示其后的字符（串）是命令的功能开关（选项）。比如"dir /s/b/a-d"表示"dir"命令指定的不同的参数。
② 在set/a中表示除法。

>
① 命令重定向符，将其前面的命令的输出结果重新定向到其后面的设备中去，后面的设备中的内容被覆盖。比如可以用"dir > lxmxn.txt"将"dir"命令的结果输出到"lxmxn.txt"这个文本文件中去。
② 在findstr/r中表示匹配单词的右边界，需要配合转义字符\使用。

<
① 将其后面的文件的内容作为其前面命令的输入。
② 在findstr/r中表示匹配单词的左边界，需要配合转义字符\使用。

=
① 赋值符号，用于变量的赋值。比如"set a=windows"的意思意思是将"windows"这个字符串赋给变量"a"。
② 在set/a中表示算术运算，比如"set /a x=5-6*5"。

\
① 这个"\"符号在有的情况下，代表的是当前路径的根目录.比如当前目录在c:\windows\system32下，那么你"dir \"的话，就相当与"dir c:\"。
② 在findstr/r中表示正则转义字符。

,
① 在set /a中表示连续表达式的分割符。
② 在某些命令中分割元素。

.
① 在路径的\后紧跟或者单独出现时：
一个.表示当前目录。
两个.表示上一级目录。
② 在路径中的文件名中出现时：
最后的一个.表示主文件名与扩展文件名的分隔。

?
① 在findstr/r中表示在此位置匹配一个任意字符。
② 在路径中表示在此位置通配任意一个字符。
③ 紧跟在/后表示获取命令的帮助文档。

______________________________________________________________________________________________

二、多符号(符号不能分隔)

&&
① 连接两个命令，当&&前的命令成功时，才执行&&后的命令。

||
① 连接两个命令，当||前的命令失败时，才执行||后的命令。

>&
① 将一个句柄的输出写入到另一个句柄的输入中。

<&
① 从一个句柄读取输入并将其写入到另一个句柄输出中。

%%
① 两个连续的%表示在预处理中脱为一个%。
② 批处理中，在for语句的in子句之前，连续两个%紧跟一个字符（可以是字母、数字和一些特定字符），表示指定一个循环或者遍历指标变量。
③ 批处理中，在for语句中，使用与in之前指定的指标变量相同的串，表示引用这个指标变量。

>>
① 命令重定向符，将其前面的命令的输出结果追加到其后面的设备中去。
② 在set /a中的二元运算符，表示逻辑右移。

==
① 在if命令中判断==两边的元素是否相同。

<<
① 在set /a中的二元运算符，表示逻辑左移。

+=
① 在set /a中的二元运算符。例如set /a a+=b表示将a加上b的结果赋值给a。

-=
① 在set /a中的二元运算符。例如set /a a-=b表示将a减去b的结果赋值给a。

*=
① 在set /a中的二元运算符。例如set /a a*=b表示将a乘以b的结果赋值给a。

/=
① 在set /a中的二元运算符。例如set /a a/=b表示将a除以b的结果赋值给a。

%=
① 在set /a中的二元运算符。例如set /a a%=b表示将a除以b的余数赋值给a。
【注：命令行可以直接用 set /a a%=b ，在批处理里面可以用 set /a a%%=b 。】

^=
① 在set /a中的二元运算符。例如set /a a"^="b表示将a与b按位异的结果赋值给a。
【注：这里 "^=" 加引号是为了防止^被转义，下同。】

&=
① 在set /a中的二元运算符。例如set /a a"&="b表示将a与b按位与的结果赋值给a。

|=
① 在set /a中的二元运算符。例如set /a a"|="b表示将a与b按位或的结果赋值给a。

<<=
① 在set /a中的二元运算符。例如set /a a"<<="b表示将a按位左移b位的结果赋值给a。

>>=
① 在set /a中的二元运算符。例如set /a a">>="b表示将a按位右移b位的结果赋值给a。

\<
① 在findstr的一般表达式中表示字的开始处。

\>
① 在findstr的一般表达式中表示字的结束处。

______________________________________________________________________________________________

三、双符号对(两个符号之间须指定字符串)

! !
① 当启用变量延迟时，使用!!将变量名扩起来表示对变量值的引用。

' '
① 在for/f中表示将它们包含的内容当作命令行执行并分析其输出。
② 在for/f "usebackq"中表示将它们包含的字符串当作字符串分析。

( )
① 命令包含或者是具有优先权的界定符，比如for命令要用到这个()，我们还可以在if，echo等命令中见到它的身影。
② 在set /a中表示表达式分组。

" "
① 界定符，在表示带有空格的路径时常要用""来将路径括起来，在一些命令里面也需要" "符号。
② 在for/f中将表示它们包含的内容当作字符串分析。
③ 在for/f "usebackq"表示它们包含的内容当作文件路径并分析其文件的内容。
④ 在其它情况下表示其中的内容是一个完整的字符串，其中的>、>>、<、&、|、空格等不再转义。

` `
① 在for/f中表示它们所包含的内容当作命令行执行并分析它的输出。

% %
① 使用两个单独的%包含一个字符串表示引用以此串为名的环境变量。比如一个%time%可以扩展到当前的系统时间。[ ]① 在帮助文档表示其中的开关、选项或参数是可选的。
② 在findstr /r中表示按其中指定的字符集匹配。

______________________________________________________________________________________________

四、实例讲解CMD&DOS符号的用法

1、@
　　一般在它之后紧跟一条命令或一条语句，则此命令或语句本身在执行的时候不会显示在屏幕上。请把下面的代码保存为test.cmd文件，然后运行，比较一下两条echo语句在屏幕上的输出差异：

复制内容到剪贴板:
echo a
@pause
@echo b
@pause
　　执行结果如下：
C:\Documents and Settings\JM\桌面>echo a
a
请按任意键继续...
b
请按任意键继续...

2、%、%%
　　百分号用在不同的场合，有不同的含义：
　　① 当百分号成对出现，并且其间包含非特殊字符时，一般做变量引用处理，比如：%var%、%str%。把以下代码保存为批处理文件，运行后观察屏幕显示结果：

复制内容到剪贴板:
@echo off
set str=abc
echo 变量 str 的值是： %str%
pause
　　在屏幕上将显示这样的结果：
变量 str 的值是： abc
按任意键继续...
　　另外，百分号作为变量引用还有一种特殊形式，那就是对形式参数的引用，此时，单个百分号后面紧跟0～9这10个数字，如%0、%1，请看演示代码：

复制内容到剪贴板:
@echo off
if defined str goto next
set str=
set /p str=请把文件拉到本窗口后回车：
call "%~0" %str%
pause
exit

:next
cls
echo 本批处理文件完整路径为："%~0"
echo 拖到本窗口的文件完整路径为："%~1"
goto :eof

　　② 出现在 set /a 语句中时，表示两数相除取余数，也就是所谓的模运算，它在命令行窗口和批处理文件中的写法略有差异：在命令行窗口中，只需要单个的%，在批处理文件中，需要连续两个百分号，写成%%。
　　例如：在命令行窗口中，运行 set /a num=4%2 ，则结果将显示0，因为4除以2的余数为0；如果保存为批处理文件，则此语句将略有改变：

复制内容到剪贴板:
@echo off
set /a num=4%%2
echo 4除以2的余数为 %num%
pause

　　③ 转义符号：如果要显示%本身时，需要在前面用%来转义。例如：

复制内容到剪贴板:
@echo off
echo 一个百分号：%%
echo 两个百分号：%%%%
echo 三个百分号：%%%%%%
pause

3、:、::
　　① 以:打头的单个的:表示该行是一个标签，它之后的内容是一个标签段，如:test，则表示:test之下的内容是标签段，而test是这个标签段的名，可以用 goto test 、goto :test 跳转到该标签段或用 call :test 调用该子过程；而连续两个冒号打头表示该行内容为注释内容，实际上，:: 是个无效的标签名，:加上空格同样可以起到注释的作用，此时，::的功能和注释命令rem相同；但是，rem 注释语句中的某些命令符号如重定向符号和管道符号还是会执行，而如果用::来注释的时候，与::同处一行的所有命令或符号直接被命令解释器忽略掉，无形中提高了注释的兼容性和整个程序的执行效率，并且在众多的命令语句中更显得醒目，所以，注释语句推荐使用::的格式。

　　② 在 set 语句中：和~同时使用时，: 起到截取字符串的功能。假设 set str=abcde，那么，set var=%str:~0,1% 表示截取字符串abcde的第一个字符；和=同时使用时，起到替换字符串的功能。假设：set str=abc:de，那么，set var=%str:a=1% 则表示把字符串abc:de中的a替换为1，set var=%str::=2% 则表示把字符串abc:de中的:替换为2；

4、~
　　① 用在 set 语句中，和:同时使用时，起到截取字符串的功能，请参考上一条的解释；

　　② 用在 set /a 语句中时，它是一元运算符号，表示将操作数字按位取反，例如，set /a num=~1的执行结果是-2，set /a num=~0的结果是-1

　　③ 用在for语句中，表示增强for的功能，能够提取到更多的信息。例如：在批处理文件的for语句中：%%~i表示去掉第一对外侧引号，%%~zi表示获取文件的大小(以字节为单位)，%%~ni表示获取文件名，%%~xi表示获取扩展名(带点号)……它们可以组合使用，如%%~nxi表示获取文件名和后缀名。

5、>、>>
　　一般而言，>表示用新内容覆盖原文件内容，>>表示向原文件追加内容，此时，它们以重定向符号的身份出现；如果用在 set /a 语句中，则>表示分组，>>表示逻辑移位；

6、|
　　一般而言，它以管道符号的身份出现，表示把在它之前的命令或语句的执行结果作为在它之后的命令或语句的处理对象，简而言之，就是把它之前的输出作为它之后的输入，例如：echo abcd|findstr "b"，表示把echo abcd的执行结果，作为findstr "b" 的执行对象，也就是在字符串abcd中查找b字符；如果test.txt中有abcd字符串，则该语句与 findstr "b" test.txt 具有同样的效果；

7、^
　　一般而言，^以转义字符的身份出现。因为在cmd环境中，有些字符具备特殊功能，如>、>>表示重定向，|表示管道，&、&&、||表示语句连接……它们都有特定的功能，如果需要把它们作为字符输出的话，echo >、echo | ……之类的写法就会出错——cmd解释器会把它们作为具有特殊功能的字符对待，而不会作为普通字符处理，这个时候，就需要对这些特殊字符做转义处理：在每个特殊字符前加上转义字符^，因此，要输出这些特殊字符，就需要用 echo ^>、echo ^|、echo ^|^|、echo ^^……之类的格式来处理；

8、&
　　一般而言，&表示两条命令或语句同时执行的意思。如 echo a&echo b，将在屏幕上同时显示a和b字符。当几条语句含义近似或作用相同且没有先后的顺序之别时，启用&符号连接这些语句将会增加程序的可读性；

9、&&、||
　　这是一对含义截然相反的命令符，&&表示如果它之前的语句成功执行，将执行它之后的语句，而||则表示如果它之前的语句执行失败，将执行它之后的语句；在某些场合，它们能替代 if……else…… 语句；例如：

复制内容到剪贴板:
@echo off
md test&&echo 成功创建文件夹test||echo 创建文件夹test失败
pause
　　效果等同于如下代码：
复制内容到剪贴板:
@echo off
md test
if "%errorlevel%"=="0" (echo 成功创建文件夹test) else echo 创建文件夹test失败
pause

10、()
　　小括号对经常出现在for语句和if语句中，还有一些特定场合；在for和if语句中属于语句格式的要求，例如：
　　① for %%i in (语句1) do (语句2)：在这条语句中，语句1必须用括号对包围，而语句2的括号对则可视情况予以抛弃或保留：如果语句2是单条语句或用&、&&、||等连接符号连接的多条语句，括号对可以抛弃，如果语句2是有逻辑先后关系的多条语句集合，则必须保留括号对，并且，多条语句必须断行书写；例如：

复制内容到剪贴板:
@echo off
for %%i in (a b c) do echo %%i&echo --------
pause
　　也可以改写为：
复制内容到剪贴板:
@echo off
for %%i in (a b c) do (
echo %%i
&echo --------
)
pause

　　② if 条件 (语句1) else (语句2)：如果没有else部分，则语句1的括号对可有可无；如果有else部分，则语句1中的括号对必须保留，此时，语句2中的括号对保留与否，和上一点类似。例如：

复制内容到剪贴板:
@echo off
if exist test.txt echo 当前目录下有test.txt
pause

复制内容到剪贴板:
@echo off
if exist test.txt (echo 当前目录下有test.txt) else echo 当前目录下没有test.txt
pause

复制内容到剪贴板:
@echo off
if exist test.txt (echo 当前目录下有test.txt) else (
echo 当前目录下没有test.txt
pause
cls
echo 即将创建test.txt文件
cd.>test.txt&&echo 成功创建test.txt
)
pause

　　③ 特定场合下使用括号对，不但可以使代码逻辑清晰，增强可读性，还可能会减少代码量。比如用echo语句构造多行文本内容的时候：

复制内容到剪贴板:
@echo off
(
echo 第一行
echo 第二行
echo 第三行
)>test.txt
start test.txt
　　如果不使用括号对的话，则需要使用如下代码：

复制内容到剪贴板:
@echo off
echo 第一行>test.txt
echo 第二行>>test.txt
echo 第三行>>test.txt
start test.txt

11、+、-、*、/
　　在 set /a 语句中，这些符号的含义分别为：加、减、乘、除。例如：set /a num=1+2-3*4/5。需要注意的是，这些运算符号遵循数学运算中的优先级顺序：先乘除后加减，有括号的先算括号，并且，直接忽略小数点，因此，刚才那个算式的结果是1而不是0或0.6。
　　另外，有可能会在代码中看到这样的写法：set /a num+=1、set /a num-=1、set /a num*=1 和 set /a num/=1，这些表示累加、累减、累乘、累除，步长都是1，展开后的完整写法为：set /a num=num+1、set /a num=num-1、set /a num=num*1 和 set /a num=num/1(set /a 语句中，变量引用可以忽略百分号对或感叹号对，set /a num=%num%+1 与 set /a num=num+1 等同)

12、equ、neq、lss、leq、gtr、geq
　　这几个命令符是if 语句中常用到的数值比较符号，取自英文的关键字母，具体的含义为：
命令符号           含义                    英文解释
   EQU              等于                      equal
   NEQ             不等于                 not equal
   LSS               少于                    less than
   LEQ          少于或等于        less than or equal
   GTR              大于                   greater than
   GEQ         大于或等于      greater than or equal