LTORG

    RISC CPU是众多CPU中的一种. RISC是精简指令集的CPU. 也就是说, 它的指令系统一般都十分简洁.本文将要介绍的是RISCCPU中目前十分普遍的ARMCPU。目前很多的RISC CPU均是使用的32BIT长度的指令. 也就是每个指令长度为32BIT（注意：包括操作码和操作数一共32位）. (也有很多RISC CPU提供16BIT长度的指令系统,用于缩短代码长度)
       所有的代码均长度为32BIT意味着CPUDESIGNER可以比较省力设计CPU. 而CPU DECODE代码的速度也可以相对快很多.
       INTEL系列的CPU指令长度是不固定的. 从1BYTE~15BYTE.均是允许范围之内的. 这样的话, 我们就可以看到一条JMP XXXXXXXX的指令会被编译成5个字节长度. 一条指令便解决了一条附带有32BIT操作数的操作. 但是RISC无法这样处理. 在ARM的CPU中, 所有指令均是32BIT. 这样,32BIT的操作数就无法直接处理了.

    我们举例说明.
    在INTEL 386以上的CPU上, 我们可以直接加载1个32BIT VALUE到EAX.
    MOV EAX,12345678H
    在对应的ARM CPU上,编译器提供的是对等的操作,也是MOV指令
    MOV R0,=0x12345678
    但是我们可以发现, 这样的指令是无法通过编译的. 因为MOV指令只能有8BIT的操作数，32bit的mov指令，只留了8bit的操作数，这就决定了MOV指令的操作数大小有一定的限制，那我们如何处理呢?
    OK. 现在是编译器帮忙的时候了.
    我们提供给编译器一条指令
    LDR R0,=0X12345678
    编译器就必须识别=0X12345678是否可以被精简到8BIT. 显然不行! 编译器接下来的方案就是要把32BIT的常量, 放置到内存的某个地址, 让寻址指令来处理。现在编译器将尝试将0X12345678放置到CODE SECTOIN的尾部.然后通过一条 LDR R0,(某地址)的指令来解决.这就是一般的解决之道.
    但是我们必须再度想一下,LDR指令能寻址多远呢? LDR伪指令最多处理4K的偏移!!! 也是因为CPU指令集的问题.我们的CODE SECTION如果很大,导致0X12345678放置的地方超过了LDR伪指令寻址能力,将再度出现错误!OK, 了解了这点, 我们就应该能够预防这里问题的出现. 我们需要的是让编译器尽可能近地处理这个常量. 查看一下编译器手册, 请使用LTORG吧。. LTORG将立刻在当前计数器上放置所有的那些已经出现,并且需要解决的常量.这样,我们在那些FUNC的尾部加上LTORG指令,就可以处理调那些加载常量导致的麻烦.
    例:
    STMFD SP!,{r0-rx};PUSH STACK
    ...FUNC BODY...
    LDMFD SP!,{r0-rx};POP STACK
    MOV PC,LR ;RETURN
    LTORG ;RESOLVE LITERAL POOL

汇编器所做的工作：
    如果LDR Rd, =const能够被转换成MOV 或者 MVN指令,则汇编器将转换成它成为相应的指令；
    如果不能被转换，则汇编器会将value存放在在一个叫做literal pool(一段嵌在代码中用以存储constant values的内存空间)，并且产生一个LDR指令操作，它是Program-relativeaddress的,并且是从literal pool来读这个constant value的。
    例如：
    LDR R1,=23   ;MOV R1, #23
    LDR Rn, [pc, #offset to litealpool]   ;从内存单元pc+offset处装载数据到Rn。

2.offset与pc之间的偏移量还有一定的规定：
    在arm状态为<4KB,并且是双向的。
    在thumb状态为<1KB,并且只能向前(Forward)。 
3.设置literal pools
    以LTORG伪指令来标识。LTORG伪指令通常放在无条件跳转指令之后，或者子程序返回指令之后，这样处理器就不会错误的将文字池中的数据当作指令来执行了。
4.例程：
    AREA   Loadcon, CODE, READONLY
        ENTRY;标识第一条指令执行的地方

    start
        BL func1    ; Branch to first subroutine
        BL func2    ; Branch to second subroutine
    stop      
        MOV r0, #0x18
        LDR r1,=0x20026;         
        SWI 0x123456    ;ARM semihosting SWI

    func1
        LDR r0, =42    ; 可以转换成MOV格式=> MOVR0, #42
        LDR r1, =0x55555555    ;不能转换，因为超过了MOV操作数的范围，故用literal pool => LDR R1,[PC,#offset to Literal Pool 1]
        LDR r2,=0xFFFFFFFF    ;可以转换成MVN =>MVN R2, #0  
        MOV pc, lr        ;返回到调用该函数的下一条，一般情况下将LTORG的声明放在此语句之后。
        LTORG    ;LiteralPool 1 contains;此处是存放LDR中constant values的一个embedded memory incode section!
                    ;针对此示例存放的内容为：literal Ox55555555
    func2
        LDR r3, =0x55555555    ;=> 不能够被转换，故使用literal pool，由于0x55555555已经存在literalpool1，故可以使用literal pool1中的literal data，转换成此种形式=> LDR R3, [PC, #offset to Literal Pool 1]
        ;LDR r4, =0x66666666    ;If this is uncommented itfails, because Literal Pool2 is out of reach因为0x66666666未出现，所以这个需要存放在此代码后面的literal pool2中,由于在后面分配了一块4200大小的内存块，这样与literal pool2之间的offset>4KB.若不注释掉此句话，则编译器会提示出现错误。
        MOV pc, lr    ;返回到调用该函数的下一条，
    LargeTable
        SPACE 4200    ;Starting at the current location, clears a4200 byte area of memory to zero
         END    ;Literal Pool 2 isempty，由于没有显示声明literal pool2，故这是literal pool2的默认声明位置（程序的结束位置）

关于LTORG:
    LTORG用于声明一个文字池，在使用LDR伪指令的时候，要在适当的地址加入LTORG声明文字池，这样就会把要加载的数据保存在文字池内，再用ARM的加载指令读出数据。（若没有使用LTORG声明文字池，则汇编器会在程序末尾自动声明）。
    伪指令格式为：
        LTORG
    伪指令应用举例如下：
        ;..............
        LDR R0, =0X12345678
        ADD R1, R1, R0
        MOV PC, LR
        LTORG   ;声明文字池，此地址存储0x12345678