bat批处理 for命令

格式: FOR [参数] %%变量名 IN  (相关文件或命令)   DO 执行的命令   
作用: 对一个或一组文件, 字符串或命令结果中的每一个对象执行特定命令, 达到我们想要的结果。   
注意: 在批处理文件中使用 FOR 命令时, 指定变量请使用 %%variable, 而不要用 %variable. 变量名称是区分大小写的, 所以 %%i 不同于 %%I.   
关于: FOR命令可以带参数或不带参数, 带参数时支持以下参数 /d /r /l  /f   
下面分别解释一下.

  

无参数时  
FOR %%variable IN (set) DO command [command-parameters]   
%%variable   指定一个单一字母可替换的参数.   
(set)    指定一个或一组文件, 可以使用通配符.   
command     指定对每个文件执行的命令。   
command-parameters   为特定命令指定参数或命令行开关。   

示例:

for %%i in (t*.*) do echo %%i-- 显示当前目录下与t*.*相匹配的文件(只显示文件名, 不显示路径)   

for %%i in (d:\mydocuments\*.doc) do @echo %%i-- 显示d:\mydocuments\目录下与*.doc相匹配的文件   

  

参数 /D
格式: FOR /D %%variable IN (set) DO command [command-parameters]   
这个参数主要用于目录搜索, 不会搜索文件, /D 参数只能显示当前目录下的目录名字.(特别说明: 只会搜索指定目录下的目录, 不会搜索再下一级的目录).   
示例:   
for /d %%i in (c:\*) do echo %%i-- 显示c盘根目录下的所有目录   
for /d %%i in (???) do echo %%i-- 显示当前目录下名字只有1-3个字母的目录   
  

参数 /R 
格式: FOR /R [[drive:]path] %%variable IN (set) DO command [command-parameters]   
此命令会搜索指定路径及所有子目录中与set相符合的所有文件, 注意是指定路径及所有子目录.   
  
1, set中的文件名如果含有通配符(?或*),  则列举/R参数指定的目录及其下面的所用子目录中与set相符合的所有文件, 无相符文件的目录则不列举.   
2, 如果set中为具体文件名, 不含通配符, 则枚举该目录树(即列举该目录及其下面的所有子目录, 并在后面加上具体的文件名), 而不管set中的指定文件是否存在。   
例: for /r c:\ %%i in (*.exe) do echo %%i -- 把C盘根目录和每个目录的子目录下面全部的EXE文件都列出来了.  
  
示例:   
for /r c:\ %%i in (boot.ini) do echo %%i-- 枚举了c盘所有目录   
for /r d:\backup %%i in (1) do echo %%i-- 枚举d:\backup目录   
for /r c:\ %%i in (boot.ini) do if exist %%i echo %%i-- 很好的搜索命令，列举boot.ini存在的目录   
  

参数 /L
格式: FOR /L %%variable IN (start,step,end) DO command [command-parameters]   
该集表示以增量形式从开始到结束的一个数字序列, 可以使用负的 Step   
  
示例：   
for /l %%i in (1,1,5) do @echo %%i-- 输出1, 2, 3, 4, 5   
for /l %%i in (1,2,10) do @echo %%i-- 输出1, 3, 5, 7, 9   
for /l %%i in (100,-20,1) do @echo %%i-- 输出100, 80, 60, 40, 20   
for /l %%i in (1,1,5) do start cmd-- 打开5个cmd窗口   
for /l %%i in (1,1,5) do md %%i-- 建立从1~5共5个文件夹   
for /l %%i in (1,1,5) do rd /q %%i-- 删除从1~5共5个文件夹

参数 /F

格式:
FOR /F ["options"] %%i IN (file) DO command
FOR /F ["options"] %%i IN ("string") DO command
FOR /F ["options"] %%i IN ('command') DO command
这个可能是最常用的, 也是最强的命令, 主要用来处理文件和一些命令的输出结果.

file 代表一个或多个文件
string 代表字符串
command 代表命令
["options"] 可选

对于FOR /F %%i IN (file) DO command
file为文件名, 按照官方的说法是, for会依次将file中的文件打开, 并且在进行到下一个文件之前将每个文件读取到内存, 按照每一行分成一个的元素, 忽略空白的行, 看个例子.
假如文件a.txt中有如下内容：

a1 a2 a3 
b1 b2 b3 
c1 c2 c3

你想显示a.txt中的内容, 会用什么命令呢? 当然是type, type a.txt
for也可以完成同样的命令:
for /f %%i in (a.txt) do echo %%i
还是先从括号执行, 因为含有参数/f, 所以for会先打开a.txt, 然后读出a.txt里面的所有内容, 把它作为一个集合, 并且以每一行作为一个元素, 所以会产生这样的集合.

{"a1 a2 a3", //第一个元素
"b1 b2 b3 ", //第二个元素
"c1 c2 c3"}   //第三个元素

集合中只有3个元素, 同样用%%i依次代替每个元素, 然后执行do后面的命令. 依次, 直到每个元素都代替完为止.
为了加强理解/f的作用，请执行一下两个命令，对比即可明白：
for /f %%i in (a.txt) do echo %%i //这个会显示a.txt里面的内容, 因为/f的作用, 会读出a.txt中的内容.
for %%i in (a.txt) do echo %%i //而这个只会显示a.txt这个名字, 并不会读取其中的内容.
通过上面的学习, 我们发现for /f会默认以每一行来作为一个元素, 但是如果我们还想把每一行再分解更小的内容, 该怎么办呢?不用担心, for命令还为我们提供了更详细的参数, 使我们将每一行分为更小的元素成为可能.
它们就是: delims和tokens
delims 用来告诉for每一行应该拿什么作为分隔符, 默认的分隔符是空格和tab键
比如, 还是上面的文件, 我们执行下面的命令:
for /f "delims= " %%i in (a.txt) do echo %%i
显示的结果是：

a1 
b1
c1

为什么是这样的呢. 因为这里有了delims这个参数, =后面有一个空格意思是再将每个元素以空格分割, 默认是只取分割之后的第一个元素.
但是这样还是有局限的, 如果我们想要每一行的第二列元素, 那又如何呢?
这时候, tokens跳出来说, 我能做到.
它的作用就是当你通过delims将每一行分为更小的元素时, 由它来控制要取哪一个或哪几个.
还是上面的例子，执行如下命令：
for /f "tokens=2 delims= " %%i in (a.txt) do echo %%i
执行结果：

a2 
b2
c2

如果要显示第三列, 那就换成tokens=3.
同时tokens支持通配符*, 以及限定范围.
如果要显示第二列和第三列, 则换成tokens=2,3或tokens=2-3, 如果还有更多的则为: tokens=2-10之类的.
此时的命令为:
for /f "tokens=2,3 delims= " %%i in (a.txt) do echo %%i %%j
怎么多出一个%%j?
这是因为你的tokens后面要取每一行的两列, 用%%i来替换第二列, 用%%j来替换第三列.
并且必须是按照英文字母顺序排列的, %%j不能换成%%k, 因为i后面是j
执行结果为:

a2 a3 
b2 b3 
c2 c3

对以通配符*, 就是把这一行全部或者这一行的剩余部分当作一个元素了.
比如:
for /f "tokens=* delims= " %%i in (a.txt) do echo %%i
执行结果为:

a1 a2 a3 
b1 b2 b3 
c1 c2 c3

其实就跟for /f %%i in (a.txt) do echo %%i的执行结果是一样的.
再如:
for /f "tokens=2,* delims= " %%i in (a.txt) do echo %%i %%j
执行结果为:

a2 a3 
b2 b3 
c2 c3

用%%i代替第二列, 用%%j代替剩余的所有.
最后还有skip和eol, 这俩个简单, skip就是要忽略文件的前多少行, 而eol用来指定当一行以什么符号开始时, 就忽略它.
比如:
for /f "skip=2 tokens=*" %%i in (a.txt) do echo %%i
结果为:

c1 c2 c3

用skip来告诉for跳过前两行.
必须加tokens=*, 否则只会显示"c1"
再如，当a.txt内容变成：

.a1 a2 a3 
.b1 b2 b3 
c1 c2 c3

执行for /f "eol=. tokens=*" %%i in (a.txt) do echo %%i 
结果是:

c1 c2 c3

用eol来告诉for忽略以"."开头的行.
同样也必须加tokens=*, 否则只会显示"c1"