使用SQL-DMO备份数据库并进行校验
来源:互联网 发布:长春手机数据恢复公司 编辑:程序博客网 时间:2024/05/16 23:46
本文谈论如何用SQL-DMO创建数据库备份和校验的ASP应用。
============================================================
概述
SQL分布式管理对象(SQL Distributed Management objects, SQL-DMO)为开发者提供了使用程序和脚本语言执行普通任务的方法,从而扩展了SQL Server功能。本文谈论如何用SQL-DMO创建数据库备份和校验的ASP应用。
前提
你需要有SQL Server数据库备份的相关知识。另外还要在global.asa文件中加入SQL-DMO库的引用。以下是SQL Server 2000的引用:
<!--METADATA TYPE="TypeLib" NAME="Microsoft SQLDMO Object Library" UUID="{10010001-E260-11CF-AE68-00AA004A34D5}" VERSION="8.0"-->
本文示例代码适用于SQL 7.0, MSDE, 和 SQL Server 2000。
喜与忧
使用SQL-DMO对象让人且喜且忧。它提供了非常丰富的功能,以至于不知该如何使用。本文只讨论示例涉及的对象属性和方法。你可以在SQL Server在线教学上找到许多相关信息。本文末尾可以下载本文示例源代码。
SQLDMO.SQLServer
代码看上去挺眼熟。它用于连接SQL Server数据库:
<%
Dim srv
Set srv = Server.CreateObject("SQLDMO.SQLServer")
srv.LoginTimeout = 15
srv.Connect "servername", "username", "password"
%>
这里通过代入用户名和口令来连接SQL Server数据库。如果要使用NT的身份认证,就将它的LoginSecure属性设为真(TRUE),忽略代入的用户名和口令,而使用NT的注册信息。
SQLDMO.Database
列出服务器中的数据库。在本文示例中,对列出的数据库进行备份。下面的代码将服务器中的数据库列于下拉菜单:
<%
Dim srv
Dim objDB
Set srv = Server.CreateObject("SQLDMO.SQLServer")
srv.LoginTimeout = 15
srv.Connect "servername", "username", "password"
Set objDB = Server.CreateObject("SQLDMO.Database")
%>
<SELECT name="fdatabase">
<%
For Each objDB In srv.Databases
If objDB.SystemObject = False Then
%>
<OPTION><%=objDB.Name%></OPTION>
<%
End If
Next
%>
</SELECT>
SQLDMO.BackupDevice
列出服务器上安装的备份装置。我建议使用备份装置来备份数据库。因为这样可以使用SQL-DMO的校验功能来校验备份情况。下面的代码列出服务器上的备份装置:
<%
Dim srv
Dim objDevice
Set srv = Server.CreateObject("SQLDMO.SQLServer")
srv.LoginTimeout = 15
srv.Connect "servername", "username", "password"
Set objDevice = Server.CreateObject("SQLDMO.BackupDevice")
For Each objDevice In srv.BackupDevices
Response.Write objDevice.Name + "<BR>"
Next
%>
SQLDMO.Backup
这就是我们要用到的备份核心对象。它有许多属性,让我们作到与企业版SQL管理器一样水平的备份。先讨论一下本文示例用到的属性。
BackupSetName - 备份文件名。
Database - 要备份的数据库。
Action - 全部或增量备份。还有其他选项,不过示例中只用到这二个。
BackupSetDescription - 备份说明。
Files - 文件备份选项。标明备份文件的路径和名字,如:C:/pubs.bak。使用文件备份时,下面的备份装置名要设置为空。
Devices - 服务器上的备份装置。如果使用备份装置,上面的文件备份选项要设置为空。
TruncateLog - 备份日志选项。其选项有:
NoLog - 不备份交易日志。
NoTruncate - 备份交易日志。日志里提供时间标记。
Truncate - 备份交易日志,但不保留交易纪录。
Initialize - 如设置为真(True),该备份装置将取代其他备份媒介而成为首选。
以下是示例中的backup.asp文件:
<%@ Language=VBScript %>
<HTML>
<BODY>
<!--contains all the login information -->
<!--#include file=login.asp -->
<%
Dim objBackup
'创建备份对象
set objBackup = Server.CreateObject("SQLDMO.Backup")
'设置属性
objBackup.BackupSetName = Request("fname")
objBackup.Database = Request("fdatabase")
objBackup.Action = Request("fAction")
objBackup.BackupSetDescription = Request("fdescription")
objBackup.Files = Request("fbackupfile")
objBackup.Devices = Request("fdevice")
objBackup.TruncateLog = Request("flog")
objBackup.Initialize = Request("finit")
'备份数据库
objBackup.SQLBackup srv
'断开与服务器的连接
srv.disconnect
'释放
set srv = nothing
set objBackup = Nothing
%>
<P>
The backup was started, use the <A HREF="devices.asp">verify</A>
option to see if it completed successfully.
<A HREF="default.asp">Click here</A> to return.
</P>
</BODY>
</HTML>
备份校验
如果用VB或C++编程,可以用事件触发来校验备份过程,但在ASP中不行。我们用SQLDMO.BackupDevice对象的ReadBackupHeader方法来确认备份是否成功。
下面是verify.asp文件代码,它列出备份装置名字并提供最近备份的有关信息。
<%@ Language=VBScript %>
<HTML>
<BODY>
<!--Login information -->
<!--#include file=login.asp-->
<P>
<%
Dim objDevice
Dim objResults
Dim iCount
Dim xCount
'创建备份装置对象
Set objDevice = Server.CreateObject("SQLDMO.BackupDevice")
'循环直到找到匹配的装置
For Each objDevice In srv.BackupDevices
If objDevice.Name = Request("fname") Then
'找到匹配装置,开始读取结果
Set objResults = objDevice.ReadBackupHeader
For iCount = 1 To objResults.Rows
For xCount = 1 To objResults.Columns%>
<B><%=objResults.ColumnName(xcount)%></B>:
<%=objResults.GetColumnString(icount,xcount)%><br>
<%Next %>
<HR>
<%Next %>
<%End If%>
<%Next%>
<%
srv.Disconnect
set srv = nothing
set objDevice = nothing
set objResults = nothing
%>
</BODY>
</HTML>
ReadBackupHeader方法返回QueryResults对象。用其Rows属性可以得到备份的纪录数。然后对每行纪录作列信息搜索。
其他功能
SQL-DMO还提供远程备份和恢复功能。本文没有涉及数据库恢复,但SQL-DMO有很强的恢复功能。
本文附件:
http://www.chinaok.net/down/200204250401420.zip
- 使用SQL-DMO备份数据库并进行校验
- 使用SQL-DMO备份数据库并进行校验
- 使用SQL-DMO备份并进行校验
- Asp.Net中利用SQL-DMO实现数据库自动备份并添加自定义日志记录
- 使用T-SQL进行数据库备份并检查该备份文件是否存在且作出相应处理
- VB.NET DMO SQL SERVER备份恢复
- VB.NET DMO SQL SERVER备份恢复
- 在VFP里操作和管理SQL SERVER(介绍SQL-DMO)转帖 SQL SERVER2000数据库备份和恢复存储过程
- 使用SQL语句对Access数据库进行备份
- 使用SQL-DMO实现定制SQL Scripts
- 使用SQL-DMO实现定制SQL Scripts
- 使用SQL-DMO来操控SQL服务器
- 使用SQL-DMO实现定制SQL Scripts
- SQL DMO
- 使用MYSQL进行数据库备份
- 使用bcp进行备份数据库
- 使用SQL-DMO实现定制SQLScripts
- 数据库备份的校验
- 用XMLHTTP实现伪Web服务
- TListView在XP中的补丁程序
- 如何在程序中实现XP模式
- ASP.NET的用户控件
- 在.NET框架的Web服务上使用Base64编码
- 使用SQL-DMO备份数据库并进行校验
- 获取其他线程的光标句柄[DELPHI]
- 用Visual C++建立SOAP客户端应用
- 用OO思路处理Cookies
- 用正则表达式作校验
- 创建存储过程的XML注释文件
- XML SOAP应用简介
- 存储数据键和项目对的类(Dictionary对象)
- Delphi 7前瞻:将Delphi作为ASP.NET的脚本语言(上)