fms起步

什么是Flash Media Server ？

Flash大家庭里的一员，以前大概叫Flash Communication Server，传说中的FCS就是这个？现在该叫FMS了吧...
不见不知道哦，一见真可怕，mm还有这么cool的东东，自从见了她，让我做些小东东的兴趣全没了，一心想研究这个

这东东能做什么？

flash聊天室啊，在线视频会议啊啊， 网络游戏？

不管怎样先安个试试吧

先到这里下载免费的开发者版本吧
http://www.macromedia.com/software/flashmediaserver/
然后安装，安装时记得用户名和密码不要瞎填自己要记住，不然好象就要重装喽。。
偶装到了c盘，找到目录
C:/Program Files/Macromedia/Flash Media Server 2

先要打开服务器哦

开始===程序===Macromedia===Flash Media Server 2
有两个start****,都要打开，关时候两个都要关，如果你怕麻烦直接找tool文件夹里的批处理文件StartServerService.bat吧，他会帮你搞定地,想关就找StopServerService.bat。~

管理服务器~

打开后就要管理了哦，点开fms2_console.swf，别看他只是个swf，后台管理就靠他了，输入你安装时候的密码和用户，服务器地址写 localhost 就好
看到了吧，熟悉熟悉他吧

applications文件夹

你可以在里边建一个文件夹例如叫 FirstApp，以后所有此项目服务器端的flv文件啊，共享文件啊都要放在这里边

conf文件夹

还有重要的是conf文件夹了，里边是一些服务器端的配置文件，以后可能会用，先不用动。。。。

今天到这吧.。。等待下集~8
=============================================================================================

有一种协议叫rtmp

客户端和服务器端通信是使用协议rtmp的

现在在服务器端applications文件夹（当然偶的客户端和服务器端是一台机器了）里建个test1文件夹，你的地址就为

rtmp:/test1 或者 rtmp://localhost/test1

注意两个地址中的 "/ "符号

打开flash

与服务器通信首先要建个NetConnection()
var nc = new NetConnection();
//连接
nc.connect("rtmp://localhost/test1");

怎么知道连没连上呢？顺利连接服务器后会触发一个onStatus事件

nc.onStatus = function(info) {
//trace(info)
//trace(info.code)
for (i in info) {
trace(i+": "+info);
}
};

完整代码：
var nc = new NetConnection();
nc.onStatus = function(info) {
trace(info.code);
if (info.code == "NetConnection.Connect.Success") {
trace("接通");
}
};
nc.connect("rtmp://localhost/test1");

注意：默认情况下服务器是允许你连接的，但只是默认，如果服务器拒绝你连接的话，上述代码就不好用了。怎么回事？我们看看连接的过程吧

连接过程
每当客户端试图连接服务器，一个NetConnection.connect()，服务器将会调用application.onConnect 来鉴定是不是允许客户端连接，onConnect()方法返回null 或不返回则将进入未决状态,直到onConnect方法中返回true或执行acceptConnection(client)则允许，返回false或 执行rejectConnection(client)则拒绝，如图

服务器文件是以.asc形式存在的，可以在test1文件夹里建一个main.asc
application.onConnect=function(client){
//this.rejectConnection(client);
//this.acceptConnection(client)
//return true
return false
}
这样就拒绝连接了
=============================================================================================

共享的概念就是让每个链接到服务器的swf都能实时的得到共享的数据。
一个人更改了这些数据，其他人都会看得到。例如聊天室里的发言。

共享对象
共享对象，说英文大概你比较熟ha~ SharedObject， 恩flash中有两种sharedObject，local sharedobject （LSO） 和 remote sharedobject (RSO)，也就是本地共享和远程共享,偶们讨论远程的，不过之前你最好先去了解了解本地的，对你有好处...

RSO在服务器端是以文件形式存储的，扩展名是.fso，为什么不是.rso?....我也想问呢- -b

代码
初始化RSO需要先与服务器建立一个连接，续上节 ，我们先与服务器建立一个连接

//初始化远程共享要利用nc通道
var myNC = new NetConnection();
myNC.onStatus = function(info) {
if (info.code == "NetConnection.Connect.Success") {
//成功则利用此nc初始化rso
initRSO(this);
}
};

跟上一节代码一样，只是连接成功后多了一个initRSO()函数，看不懂的回上一节看看

下边是initRSO了，跟连接结构差不多
function initRSO(NC) {
//在服务器上建立myRSO.fso文件，第2个参数指定nc通道，第3个指定文件在服务器上持久保留
my_rso = SharedObject.getRemote("myRSO", NC.uri, true);
my_rso.onSync = function(list) {
//list 是一个对象数组 ，类似这种[{name:"x",code:"success"},{name:"y",code:"success"}]
//初始成功
};
my_rso.connect(NC); //连接
}

了解了吧，下边看一个完整的例子

画一个mc起名叫mc，在第一帧上写代码，

//初始化远程共享要利用nc通道
var myNC = new NetConnection();
myNC.onStatus = function(info) {
if (info.code == "NetConnection.Connect.Success") {
//成功则利用此nc初始化rso
initRSO(this);
}
};
myNC.connect("rtmp://localhost/test1");
function initRSO(NC) {
my_rso = SharedObject.getRemote("myRSO", NC.uri, true);
my_rso.onSync = function() {
mc._x=this.data.x
mc._y=this.data.y
};
my_rso.connect(NC);
}
onMouseDown = function () {
my_rso.data.x = _root._xmouse
my_rso.data.y = _root._ymouse
};

然后发布设置中设置只允许网络，发布看看
现在你可以开多个播放器窗口，点其中一个，看看其他的窗口变不变
点此下载(http://www.nshen.net/blog/attachments/200601/11_145320_test3.fla)

连接流程

完。

再写一个，不知道这样能不能做网游~

mync = new NetConnection();
mync.onStatus = function(info) {
if (info.code == "NetConnection.Connect.Success") {
initRSO();
}
if (info.code == "NetConnection.Connect.Closed") {
trace("关闭");
}
};
function initRSO() {
my_RSO = SharedObject.getRemote("myRSO", mync.uri, true);
trace(my_RSO);
my_RSO.onSync = function() {
mc._x = this.data.hero.x;
};
my_RSO.connect(mync);
}
mync.connect("rtmp:/my_app/test1");
//mync.connect("rtmp://localhost:443/my_app/aaa")
mc.onEnterFrame = function() {
my_RSO.data.hero.x = this._x;
if (Key.isDown(Key.LEFT)) {
this._x -= 5;
}
if (Key.isDown(Key.RIGHT)) {
this._x += 5;
}
};
=============================================================================================

视频，一个是录一个是放

用摄像头录视频：
//从麦和设像头显示视频
my_video.attachVideo(Camera.get());
my_video.attachAudio(Microphone.get());
//连接
nc = new NetConnection();
nc.connect("rtmp://localhost/aaaa");
nsOut = new NetStream(nc);
nsOut.attachVideo(Camera.get());
nsOut.attachAudio(Microphone.get());
//发布2.flv
nsOut.publish("2", "record");
publish后边的参数有record，则录成文件2.flv，
不加参数默认为live,即现场流，类似在线直播，不需要录成文件，其他人可以同时播放视频流

把fla发布一下， 录一会儿，把视频关掉，打开你的
X:/Program Files/Macromedia/Flash Media Server 2/applications/aaaa/

是不是多了个streams/_definst_
打开C:/Program Files/Macromedia/Flash Media Server 2/applications/aaaa/streams/_definst_
看见2.flv了吧。

播放
几行代码而已
nc = new NetConnection();
nc.connect("rtmp://localhost/aaaa");
res = new NetStream(nc);
view.attachVideo(res);
view.attachAudio(res);
res.play("2");

OK. 8
=============================================================================================

我们已经看过怎样跟服务器建立连接了，忘了的回头看看
现在我们深入一点点。。看看有些细节问题

info.code：

连接后info.code会告诉你连接的状态，以前看的都是NetConnection.Connect.Success， 还有一些其他值，和这些值是什么意思，自己看看。

值得注意的是。NetConnection.Connect.Rejected，收到这条消息的时候说明服务器端拒绝了你，接着马上你会收到另一条，NetConnection.Connect.Closed，连接就关闭了~~~

mync = new NetConnection();
mync.onStatus = function(info) {
switch (info.code) {
case "NetConnection.Connect.Success" :
trace("连接成功");
break;
case "NetConnection.Connect.Failed" :
//关掉服务器的情况
trace("连接失败，请检查你的网络");
break;
case "NetConnection.Connect.Rejected" :
//注意这里，服务器拒绝你的情况，如果遭到拒绝，将会调用两次mync.onStatus，
//第一次"NetConnection.Connect.Rejected"第2次"NetConnection.Connect.Closed"
trace("遭到服务器拒绝");
trace("服务器返回信息："+info.application.msg);
break;
case "NetConnection.Connect.Closed" :
trace("连接关闭");
break;
}
};
mync.connect("rtmp://localhost/connect", "N神");
//mync.connect("rtmp://localhost/connect","小新")

服务器端拒绝连接？好象见过。。。回头找找。。。。。。。。哦在这里
application.onConnect = function(client) {
this.rejectConnection(client);
}

我不能所有人都拒绝了。。我要把讨厌的人拒绝了。。。
传给服务器一个人名~~
mync.connect("rtmp://localhost/connect", "N神");

服务器看看是不是讨厌的人。。
application.onConnect = function(client, name) {
trace(name);
if (name == "N神") {
//拒绝连接，并返回个错误对象{msg:"服务器不想"+name+"进去，哈哈~"}，包含错误消息
application.rejectConnection(client, {msg:"服务器不想"+name+"进去，哈哈~"});
} else {
application.acceptConnection(client);
//成功不能返回客户端信息
}
};

看最上边的代码。。
case "NetConnection.Connect.Rejected" :
//注意这里，服务器拒绝你的情况，如果遭到拒绝，将会调用两次mync.onStatus，
//第一次"NetConnection.Connect.Rejected"第2次"NetConnection.Connect.Closed"
trace("遭到服务器拒绝");
trace("服务器返回信息："+info.application.msg);
break;

遭到服务器拒绝后会trace出服务器返回的错误消息

=======================================

还有一些代码。是在一本电子书上学到的。。。传上来看看

//test2 ,拒绝多余的回调信息
mync = new NetConnection();
mync.onStatus = function(info) {
if (info.code == "NetConnection.Connect.Success") {
trace("连接成功");
this.handleCloseEvents = true;
}
if (!this.isConnected && this.handleCloseEvents) {
this.handleCloseEvents = false;
if (info.code == "NetConnection.Connect.Rejected") {
trace("遭到服务器拒绝");
} else {
trace("连接关闭");
}
}
};
mync.handleCloseEvents = true;
mync.connect("rtmp://localhost/connect", "N神");
//mync.connect("rtmp://localhost/connect","小新")
//test3 ,连接时显示正在连接，检查是否uri错误
mync = new NetConnection();
mync.onStatus = function(info) {
if (info.code == "NetConnection.Connect.Success") {
trace("连接成功");
this.handleCloseEvents = true;
}
if (!this.isConnected && this.handleCloseEvents) {
this.handleCloseEvents = false;
if (info.code == "NetConnection.Connect.Rejected") {
trace("遭到服务器拒绝");
} else {
trace("连接关闭");
}
}
};
mync.handleCloseEvents = true;
//uri="rtmp://localhost/connect"
uri = "rtmp2://localhost/connect";
//错误的uri
if (mync.connect(uri, "N神")) {
trace("尝试连接服务器中。。");
} else {
trace("没有尝试连接服务器~是uri错误？？？");
}
//mync.connect("rtmp://localhost/connect","小新")

onStatus都有什么，看清楚~~~

// onStatus( ) handler.
NetConnection.prototype.onStatus = function (info) {
trace("this.isConnected: " + this.isConnected);
trace(" info.level: " + info.level);
trace(" info.code: " + info.code);
trace("info.description: " + info.description);
if (info.application) {
for (var prop in info.application) {
trace("info.application." + prop + ": " + info.application[prop]);
}
}
trace("/n");
};
=============================================================================================

简单的东西，就是共享对象的运用，没有用到服务器端，大型聊天室可能不会这么做.

//用户名
myname="游客"
//建立连接
var myNC = new NetConnection();
myNC.connect("rtmp://localhost/smallchat");

//搞到rso
Talk_SO = SharedObject.getRemote("Talk", myNC.uri, false);
Talk_SO.onSync = function() {
//先把聊天文本框清空
remoteText.text = "";
//把聊天列表显示出来，talklist的格式就是[谁谁说:啊啊啊,谁谁谁说:2222]
var t = this.data.talklist;
for (var i = 0; i

//发消息函数
function post() {
//如果不存在talklist就建一个，这里没用server端，是个技巧
if (Talk_SO.data.talklist[0] == undefined) {
Talk_SO.data.talklist = [];
}
//限制数组长度，是个队列。保证里边有5条消息，当然也可以更多，但如果没有限制，flash会垮的
if (Talk_SO.data.talklist.length>=5) {
Talk_SO.data.talklist.shift();
}
//把消息装到so里
Talk_SO.data.talklist.push(myname+"说："+meText.text);
meText.text = "";
}
//文字显示，换行
function writeln(msg) {
remoteText.text += msg+"/n";
remoteText.vPosition =remoteText.maxVPosition
}
//-----------------------------------------------
Btn.onRelease = function() {
post();
};
this.onKeyDown = function() {
if (Key.isDown(Key.ENTER)) {
post();
}
};
Key.addListener(this);
=============================================================================================

这是目前为止最难的了吧~~

客户端呼叫服务器

fla：

//客户端呼叫server端msgfromclient函数,并将返回值trace出来
mync = new NetConnection();
mync.connect("rtmp://localhost/connect");
//返回值
var resObj = new Object();
resObj.onResult = function(val):Void {
trace("val"+val);
};
mync.call("msgfromclient", resObj, "第一个call");

服务器端代码是放在main.asc里的，你可以到你的application下的你的目录下建一个main.asc，写代码

main.asc:

//要把函数定义到Client上！！
application.onConnect = function(client) {
/* 在这里定义也可以，在Client.prototype里定义也可以
client.msgfromclient=function(what){
trace(what+"进来了")

var aa="呼叫成功并返回结果"
return aa
}
*/
application.acceptConnection(client);
};

Client.prototype.msgfromclient=function(what){
trace(what+"进来了")

var aa="呼叫成功并返回结果"
return aa

}

服务器端呼叫客户端

fla：

//server呼叫client端
//要把函数定义到nc上！！
//
mync = new NetConnection();
mync.onStatus = function(info) {
if (info.code == "NetConnection.Connect.Success") {
trace("连接成功");
}
};
mync.connect("rtmp://localhost/connect");
mync.msgfromserver = function(msg) {
trace(msg);
};

main.asc：

application.onConnect = function(client) {
application.acceptConnection(client);
client.call("msgfromserver",null,"服务器叫你啊")
};
服务器端很少要求客户端返回值，如果一定要返回，一本书上是这么写的，没细看
// Define a class that just stores the client ID.
AreYouOkResultHandler = function (clientID) {
this.clientID = clientID;
};
// Handle the result of calling areYouOk( ).
AreYouOkResultHandler.onResult = function (val) {
trace("Client " + this.clientID + " returned " + val);
};

application.pingClient = function (clientObj, clientID) {
// Invoke a message on the client.
clientObj.call("areYouOk", new AreYouOkResultHandler(clientID));
};
=============================================================================================

在FCS的應用上常會需要讓Client與Server間的資料傳遞與method呼叫，以下幾點概念應該可以避免呼叫method沒反應或資料沒傳到你要的地方等狀況發生。

一.Server端method如何被呼叫

Server端上要能讓Client所呼叫觸發的function，需定義在Server端的Client物件上你可以用prototype方式去extend原本Client類別的method，讓Client類別所產生的instance都擁有該method。
例:
Client.prototype.newfun=function(){}

你也可以把這function定義在單一Client instance下，
例:
application.onConnect(newClient)=function(){
.....
newClient.newfun=function(){}
}

二.Client端的method如何被呼叫

在Client端上要讓Server端可以呼叫的function，一定要定義在Netconnection上。
例:
nc=new NetConnection();
.....
nc.myfun=function(){}

三.send或call這兩個method在使用上有何差異?

如何使用

call:這method在Client端上可使用的是netconnection物件，在Server端上可使用的是netconnection 與Client物件
1.在Client端利用netconnection.call來觸發執行Server端上Client 物件的method。
2.在Server端上利用Client物件.call來觸發Client端上netconnection上的method。
3.在Server端上使用netconnection.call時，這時這server的角色就像一個client端一樣，是在觸發另一個Server端上Client 物件的method。

send:在Client端上可使用這method的包含SharedObject與netStream
send這個method很有趣，他讓你由client端去啟動所有同在client端的function，但因為在觸發function時可以帶參數過 去，這個特性是可以讓你利用來做小量資料的廣播的，要廣播給所有人接收到的資料，並不一定就要放在SharedObject內，利用其onSync來做同 步，有時用send也是一個很簡單的做法，如何定義
1.在netStream或SharedObject上定義好method "myfun"
2.利用netStream.send("myfun")或sharedobject.send("myfun"，myvar)可讓所有client上的"myfun"都會被觸發

四.幾種可能的互動型態範例

1.Client端對Server端傳送data或呼叫執行Server端function應用範例:一個簡易聊天室，聊天內容只存在Server 端的變數內，不使用SharedObject存放呼叫Server端的message這method來處理client傳上去的msg這對話內容

Client端:
nc.call("message"， null， msg);

Server端:
application.onAppstart=function(){
application.chat_content="";
}
application.onConnect=function(newClient){
.......
newClient.message=function(msg){
application.chat_content+=msg;
}
}

2.Client端對所有Client廣播data並執行指定Client端function應用範例:以之前在站上回覆過的問題為例，一個clinet要輸入一個網址url_txt，要讓所有的client都會開啟這網址的網頁

Client端:
先定義一個附掛在so上的method
lobby_so.openPage=function(receive_url){
getURL(receive_url);
}
利用send就可讓所有client接收到這網址並開啟
lobby_so.send("openPage"，url_txt);

3.Server傳送data給特定Client

應用範例:當有使用者連線上server，當使用者資料驗證正確時，接受其連線，一方面要client去執行指定的function跳到某頁或讓某 mc出現...，同時又要把server端的資料帶過去說明:server只回應正在與server做互動的那個client，如以上範例，server 只會去觸發請求連線的該client去執行指定的function，其他client不會有反應

Server端:
application.onConnect=function(newClient，pwd){
if(pwd=="ok"){
application.acceptConnection(newClient);
newClient.call("get_message"，null，message);
}else{
application.rejectConnection(newClient，errObj);
}
}

Client端:
........
nc.get_message=function(message){};

4.Server廣播data給所有Client
應用範例:當有人斷線時，由server端廣播所有client，讓所有client都能同步更新client名單
說明:以上範例來說，當clinet無預警的斷線，只有Server上的application.onDisconnect 這handler會被觸發，也就是說你需要在這handler內寫一些程式去廣播通知給所有的client。

如何廣播?有以下兩種做法
1.把資料放在remote SharedObject物件內，只要SO物件內容更動，即自動觸發Client端的so.onSync
將線上人員名單寫在remote SharedObject物件內，當有人斷線，只要把so內該筆資料剔除掉，因為
so內容改變，因此所有Client端的so.onSync 這handler將被觸發，即可達到你要更新資料的目的。

Server端
application.onDisconnect=function(newClient){
userlist_so.setProperty(newClient.name，"");
}
註:相對的當server端無預警的斷線，client端可由nc.onStatus這handler內由判斷info.code來取得資訊

2.當資料不是存在so內時，只是存在server端的一個變數上，可以善加利用application.clients來對
所有client廣播。以下會觸發所有client端上的client_fun，並把server上的sendvar變數帶過去

server端:
application.onDisconnect=function(newClient){
for(var i=0;i

Client端:
nc.client_fun=function(myvar){ }

增加一個廣播的方法

Server 端傳送給有getRemote 同一個ShareObject 的Client 端

Server 端：
application.abc_so = SharedObject.get("abc_so", false);
application.abc_so.send("msgFromSrvr", msg);

Client 端：
abc_so = SharedObject.getRemote("abc_so", abc_nc.uri, false);
abc_so.msgFromSrvr = function(msg) {
showMsg(msg);
};

=============================================================================================

学了就要用。练练吧，做个在线列表

Client：

btn.onRelease = function() {
if (_root.id.text != "") {
_root.init();
}
};
function init() {
IDNUM = _root.id.text;
//这个为登陆名
//IDPASS = "456";
mync = new NetConnection();
mync.onStatus = function(info) {
trace(info.code);
};
mync.connect("rtmp://localhost/phone", IDNUM, IDPASS);
mync.onlineList = function(list) {
//填充List组件
mylist.labels = list;
};
}

server端

application.onAppStart=function(){
trace("------onAppStart----")
this.onlineList=[]
}
application.onConnect=function(newClient,IDNUM,IDPASS){
trace("------user onconnected------")
newClient.IDNUM=IDNUM
//newClient.IDPASS=IDPASS
//处理在线数组(push)
this.onlineList.push(IDNUM)
this.acceptConnection(newClient);
//广播给client
for(var i=0;i

}
application.onDisconnect = function (newClient){

trace("------user disconnected------");
//处理在线数组(splice)
for(var i=0;i<=this.clients.length;i++){
if(this.onlineList[i]==newClient.IDNUM){
this.onlineList.splice(i,1)
}
}
//广播
for(var i=0;i

=============================================================================================

是一个郁闷我一段时间的问题才想到了答案。。。话说曾经在公司做了一个在线播放电影的东西，在php里取文件列表，然后到fms去播放,经常会出错看不了，还要重启服务器才可以，迷糊~`。最近帮朋友做东西又出现乱码，才突然想到什么原因。
为了解决在flash里显示中文我们通常都加一句

出错原因就在这，显示不了外部中文是因为flash内默认用Unicode编码，外部的大多都是gb2312,加上这句

代表强制flash使用系统默认的gb2312，这样flash就显示正确了，但fms服务器端默认也是用unicode的，这样客户端跟服务器端 不同编码自然会出错了，搜了一下server字典好象没有System.useCodepage=true了。。。所以解决办法就是去掉