K 线为王

K 线为王：
--------------------------------------------------------------------------------
1. 惯性定律
    a. 跳高线和跳水线。  升势或跌势极强
    b. 攀援线和滑行线。  升势或跌势较强
    c. 并列线        升势或跌势较缓                    
    d. 包容线和孕妊线     升势或跌势较缓
    e. 弃子线        高开或低开后。 注意换手率

2. 物极必反
    a. 压迫线和奉承线    ， 反叛力弱
    b. 覆盖线和切入线    ， 反叛力强
    c. 下拖线与上拉线    ， 反叛力很强
    d. 反叛线与归顺线    ， 反叛力极强
    e. 伪阳线与伪阴线    ， 反叛
简单说， 同向升降幅度大为惯性强，反向升降幅大反叛强
--------------------------------------------------------------------------------
1. 低进模式和高出模式是一对矛盾。 都是行情翻转模式，只是一个在低位，一个在高位
   这是一个拐点的把握。

低位，出现信号都是买进，高位，出现信号是卖出。

震荡型模式。股价变化比较平缓
连续的并阳线，连续的并阴线，弓形线，剑形线，大阳线，大阴线是买入，卖出信号。 （低位吸筹或高位出货）,
突破时也是这种信号。 突破还有底部红三兵升， 顶部黑三兵降的说法

低位反弹模式。（可能出在中途或底部）
低位反弹说的是下跌过程中由于下跌过快，下跌失去动力，多方则抓紧反击。出现回调，但下档不够坚实，下跌并未停止
在操作上必需大胆逢低介入，以快进快出，博取差价为主。
发生条件： 低档急跌之后。
信号： 急跌三大阴，三空阴线，急跌后下跳十字星， 遇弓形线，剑形线。
尽头阴线（未超前剑形线阴影）。独阳线（大跌探底阳线），独阴线（大阴后跟阳）。
阴孕阳， 阴孕阴，阴孕十字星，阴孕剑形线，阴孕弓形线。 阳包阴， 阴包阳（最后包容阴线）, 都是止跌信号。
还有切入线，上拉线，连拉剑形线（双针探底）, 阴夹阳（两中大阴线夹一个中大阳线）, 二次阻击型阳线（极有可能成w 型底），
都是跌势变缓转暖信号。

高位回调模式。(可能出在顶部或中途）
同理，高位回调是上升过程中由于升速过快，上升动力不足。空方及获利盘涌出，打压股价。 但是股价还会在盘整或回调后继续走高。
操作上要做到逢高卖出，落袋为安。 低吸高抛，赚取差价。避开损失
发生条件： 高档急升之后。

信号： 急升三大阳， 三空阳线(股价放量收阴或回补最后一个缺口时再出货, 要重势不要轻易了解）
    遇弓形线（出师未捷身先死）， 吊颈线（快跑）, 尽头阳线（未超前弓形线影），独阴线（冲顶回落），独阳线(退潮）,
    跳空滑行线（双雁南飞）
    阳孕阳，阳孕阴，阳孕十字星，阳孕剑型线，阳孕弓形线。阴包阳，阴包阴，最后包容阳线
    高档覆盖线，下拖线，二次阻击型阴线。 都是升势遇阻回调信号(可能成M 型顶）。


2. 高进模式和低出模式。他们是一对矛盾， 都是在同一个方向上进行操作。
对于低出， 有快速下滑模式和震荡盘下模式，
高进， 也有快速上攻模式和震荡盘上模式

高进模式-快攻型：盘整后大阳突破，跳高一字线不补缺，二次高开阳线, 跳空攀援线，渐大三连阳，
    上升途中跳高十字星，跳高剑形线，跳高弓形线, 小压迫线，伪阴线, 升势凌厉。
    上升中途上拉线，归顺线，阳包阴。阳孕阴。 遇抵抗，也是软弱无力，空方束手被擒。

    注意区分高档急升情景， 防止跟进时遇到回调。

高进模式-震荡盘上， 尽量不参与该模式，但应该知道。
上升中途切入线，阳孕阳，并阳线，滑行线（遇到两根滑行的阴线，如两只翩翩南归的燕子，说明空头已有一定实力）
上升三连击（一根阴线，吞吃了三根小阳线）
上升三法。（三根小阴线，被一根中大阳线吞吃）
上升跳空三法（阴线补缺）
超越覆盖线或压迫线。（再创新高）
受阻红三兵
思考红三兵。
阴夹阳（腹背受敌，注意观察）
阳包阳
伪阳线， 说明遇到了敌情， 要谨慎前行。

低出-快速下滑模式：
下档盘整后大阴跌破，跳水一字线不补缺，二次跳空阴线，跳空滑行线，渐大三连阴。跳水十字星，跳水剑形线，跳水弓形线,小奉承线，伪阳线。
下降途中下拖线，反叛线，阴包阳。 持币观望或追卖，  注意，下跌过头也可能反弹，但要确认才可操作，最好观望。

低出-震荡盘下模式
下跌中途覆盖线（收阳不济）
下跌中途并阳线（虽抵抗，不强）
下跌中途阴孕阴（虽放缓，未改变）
下跌中途并阴线（虽放缓，未改变）
下跌中途攀援线（虽抵抗，但未超过或超一点前期阴线开盘价，不强）
下降三连击（三阴对一阳较量，最后的较量)
下降三法（一阴对三阳较量，风卷残云）
下降跳空三法（补缺也没用）
超越切入线或奉承线（再创新低）
受阻黑三兵
思考黑三兵
阳夹阴
阴包阴
伪阴线（虽然价格升了点，但浮萍难驻，毕竟随风去）1操作： 抛盘而去。（最好不要遇到该情况，提前操作）

注意区分低出和反弹模式。

难就难在， 低出与反弹，高进与回调的把握上。 

通达信主图指标k线标注，本人整理，注意，K线不是万能，还要参考量能。抛砖引玉。

{单根K线}
长下影:=    {影线超过了总实体2/3 为长影线}
(MIN(CLOSE,OPEN)-LOW)/(HIGH-LOW)>0.667;
DRAWTEXT(长下影,h+0.1,'长下影 '),COLORWHITE; {-下档支撑强或空方试探进攻}

长上影:=
(HIGH-MAX(CLOSE,OPEN))/(HIGH-LOW)>0.667;
DRAWTEXT(长上影,h+0.1,'长上影'),COLORWHITE; {-上档阻力大或多方试探进攻}


光头阳线:=
HIGH=CLOSE AND HIGH<>LOW;
DRAWTEXT(光头阳线,h+0.2,'光头阳线 '),COLORRED;{-今日尾盘多方气盛 可能延续到明天}

大阳烛:=
CLOSE/OPEN>1.05 AND HIGH/LOW < CLOSE/OPEN+0.018;
DRAWTEXT(大阳烛,h+0.1,'大阳烛 '),COLORRED; {-上升行情中意味行情剧烈向上攀升 下跌行情中意味行情剧烈向上反弹}

大阴烛:=
OPEN/CLOSE > 1.05 AND HIGH/LOW < OPEN/CLOSE+0.018;
DRAWTEXT(大阴烛,H+0.1,'大阴烛 '),COLORWHITE; {-今日空方有绝对优势}

赤脚阴线:=
LOW=CLOSE AND HIGH<>LOW;
DRAWTEXT(赤脚阴线,H+0.2,'赤脚阴线 '),COLORWHITE;{-尾盘空方胜 注意延续次日}

垂死十字:=  {墓碑}
CLOSE=OPEN AND CLOSE=LOW AND CLOSE<>HIGH;
DRAWTEXT(垂死十字,L-0.1,'垂死十字 -在顶部时重要 表强力多头开始疲软'),COLORWHITE;

长十字:= {高点比低点超过了3% 为长十字}
CLOSE=OPEN AND  HIGH<>CLOSE AND LOW<>CLOSE AND HIGH/LOW > 1.03;
DRAWTEXT(长十字,L-0.1,'长十字 '),COLORWHITE; {-多空激争 前途未明}

十字星:=
CLOSE=OPEN AND HIGH<>CLOSE AND LOW<>CLOSE AND HIGH <>CLOSE;
DRAWTEXT(十字星,h+0.15,'十字星 '),COLORWHITE; {-警告信号 原趋势停顿或反转 依上下影线长度判后市}

射击之星:= {等同于倒转锤头}
CLOSE<>OPEN AND MIN(OPEN,CLOSE)=LOW AND HIGH-LOW > 3*(MAX(OPEN,CLOSE)-LOW) AND CLOSE > MA(CLOSE,5);
{DRAWTEXT(射击之星,l+0.2,' 射击之星 '),COLORWHITE;-如伴大量 上遇阻力 有短期见顶可能 转疲}

倒转锤头:=
MIN(OPEN,CLOSE)=LOW AND HIGH-LOW > 3*(MAX(OPEN,CLOSE)-LOW) AND CLOSE < MA(CLOSE,5);
DRAWTEXT(倒转锤头,L-0.15,'倒转槌头 '),COLORWHITE; {-高位抛压 低位多空争执}

锤头:= {总体长大于3倍实体长为锤头线，处于5日均线之上为吊颈线，高位要注意，看跌，低位看涨}
HIGH = MAX(OPEN,CLOSE) AND HIGH-LOW > 3*(HIGH-MIN(OPEN,CLOSE)) AND CLOSE < MA(CLOSE,5);
DRAWTEXT(锤头,L-0.15,'槌头 '),COLORWHITE;{-下影线有多头意义 在下降趋势之后看涨 注意反弹卖压}

吊颈线:=
HIGH = MAX(OPEN,CLOSE) AND HIGH-LOW > 3*(HIGH-MIN(OPEN,CLOSE)) AND CLOSE > MA(CLOSE,5);
DRAWTEXT(吊颈线,h+0.15,'吊颈线 '),COLORWHITE; {-高档看跌}

跳空缺口:=
HIGH<REF(LOW,1) OR LOW>REF(HIGH,1);
DRAWTEXT(跳空缺口,L-0.35,'跳空缺口 '),COLORWHITE; {-当日未补 有与跳空同向进行欲望强烈 三日为回补观察期}

断头铡刀:=
(O>C AND OPEN>MA(C,5) AND OPEN>MA(C,10) AND O>MA(C,20) AND CLOSE<MA(C,5) AND CLOSE<MA(C,10) AND CLOSE<MA(C,20));
DRAWTEXT(断头铡刀,L-0.15,'断头铡刀'),COLORWHITE;{-一根大阴线切断了三根均线 如果改变了其后均线的排列为空头排列 后势看空}

出水芙蓉:=
(O<C AND OPEN<MA(C,5) AND OPEN<MA(C,10) AND O<MA(C,20) AND CLOSE>MA(C,5) AND CLOSE>MA(C,10) AND CLOSE>MA(C,20));
DRAWTEXT(出水芙蓉,H+0.15,'出水芙蓉'),COLORRED;{-一根大阳线切断了三根均线 如果改变了其后均线的排列为多头排列 后势看多}

{!!2根K线}
分离:=
OPEN=REF(OPEN,1) AND (CLOSE-OPEN)*(REF(CLOSE,1)-REF(OPEN,1))<0;
DRAWTEXT(分离,L-0.15,'分离 '),COLORWHITE; {-两日开盘相同 一阴一阳 变盘前彻底整理}

友好反攻:=
(REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN AND ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002) OR
(REF(CLOSE,1)>REF(OPEN,1) AND CLOSE<OPEN AND ABS(CLOSE-REF(CLOSE,1))/CLOSE<0.002);
DRAWTEXT(友好反攻,L-0.2,'友好反攻 '),COLORWHITE; {-阴(阳)线结合极线 多方跳低(高)后反弹 有企稳迹象}


平顶:=
ABS(HIGH-REF(HIGH,1))/HIGH<0.001;
DRAWTEXT(平顶,L-0.2,'平顶 '),COLORWHITE;{-该高点有一定阻力}

平底:=
ABS(LOW-REF(LOW,1))/LOW<0.001 AND ABS(REF(LOW,1)-REF(LOW,2))/REF(LOW,1)<=0.001;
DRAWTEXT(平底,L-0.2,'平底 '),COLORWHITE;{-该低点有一定支撑}

最后吞噬1:=
REF(C,1)-REF(O,1)<0 AND C-O<0 AND C<REF(C,1)  AND O>REF(O,1);
DRAWTEXT(最后吞噬1,L-0.25,'黑吞黑'),COLORWHITE;

阴线吞噬:=
(REF(C,1)-REF(O,1)>0 AND C-O<0 AND C<REF(O,1) AND O>REF(C,1));
DRAWTEXT(阴线吞噬,L-0.25,'黑吞红 '),COLORWHITE;{-黑包红 向空反转}

多头阳线吞噬:=
(REF(C,1)-REF(O,1)<0 AND C-O>0 AND C>REF(O,1) AND O<REF(C,1));
DRAWTEXT(多头阳线吞噬,L-0.25,'红吞黑'),COLORWHITE; {多头阳线吞噬 -红包黑 反转趋势 配合量}


穿头破脚:= {是吞噬线，且吞噬的是中阳，中阴 3%}
(REF(CLOSE,1)/REF(OPEN,1)>1.03 AND CLOSE/OPEN<0.96 AND CLOSE<REF(OPEN,1) AND OPEN>REF(CLOSE,1)) OR
(REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.04 AND CLOSE>REF(OPEN,1) AND OPEN<REF(CLOSE,1));
DRAWTEXT(穿头破脚 ,L-0.5,'穿头破脚 '),COLORYELLOW; {-若第一根K为阴(阳) 表强劲上涨(下跌)力量}


双飞乌鸦:= {今天的阴线大于2个点}
REF(CLOSE,1)<REF(OPEN,1) AND CLOSE<OPEN AND CLOSE/OPEN<0.98;
DRAWTEXT(双飞乌鸦,L-0.2,'双飞乌鸦 '),COLORWHITE; {-多头力竭 行情走软}

多头孕育线:=
(REF(C,1)-REF(O,1)<0 AND C-O>0 AND C<REF(O,1) AND O>REF(C,1));
DRAWTEXT(多头孕育线,L-0.2,'多头孕育线 '),COLORWHITE;{-阴育阳 多头反转可能}

空头孕育线:=
(REF(C,1)-REF(O,1)>0 AND (ABS(REF(C,1)-REF(O,1)))/(ABS(REF(C,2)-REF(O,2)))>2.4 AND C-O<0 AND C>REF(O,1) AND REF(C,1)-O>2);
DRAWTEXT(空头孕育线,L-0.2,'空头孕线 '),COLORWHITE; {--阳育阴 看空}

空头孕育线2:=(REF(C,1)-REF(O,1)<0 AND C-O<0 AND C>REF(C,1) AND O<REF(O,1) AND O-C <6);
DRAWTEXT(空头孕育线2,L-0.2,'空头孕线 '),COLORWHITE; {-阴育阴 看空}

身怀六甲:= {要求第一根K线幅度为大K线, >4%}
ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1) > 0.04 AND ABS(CLOSE-OPEN)/CLOSE<0.005 AND MAX(CLOSE,OPEN) < MAX(REF(CLOSE,1),REF(OPEN,1)) AND MIN(CLOSE,OPEN) > MIN(REF(CLOSE,1),REF(OPEN,1));
DRAWTEXT(身怀六甲,L-0.25,'身怀六甲 '),COLORWHITE; {-阴(阳)怀阳(阴)怪异的走势显示该股行情可能转向 若量由大转缩更明}

十字胎:=
ABS(REF(CLOSE,1)-REF(OPEN,1))/REF(CLOSE,1) > 0.04 AND CLOSE=OPEN AND CLOSE < MAX(REF(CLOSE,1),REF(OPEN,1)) AND CLOSE > MIN(REF(CLOSE,1),REF(OPEN,1));
DRAWTEXT(十字胎,h+0.2,'十字胎 '),COLORWHITE; {-似身怀六甲 转向可能性更大 量缩观望为宜}

颈上线:={昨日收大实体阴线，今日收假阳线，收盘等于昨日最低点下}
REF(O,1)/REF(C,1) > 1.05 AND REF(H,1)/REF(L,1) < REF(O,1)/REF(C,1)+0.018 AND C>O AND O<REF(L,1) AND C=REF(L,1);
DRAWTEXT(颈上线,L-0.2,'颈上线 '),COLORWHITE; {奉承线，-下降趋势 若第二天大量 维持原趋势可能大增}

戮入线:= {昨日实体大阴，今日实体大阳，但是未能触及昨日一半幅度，为失败张升}
REF(O,1)/REF(C,1) > 1.05 AND REF(H,1)/REF(L,1) < REF(O,1)/REF(C,1)+0.018 AND CLOSE/OPEN>1.05 AND HIGH/LOW < CLOSE/OPEN+0.018 AND O<REF(L,1) AND C<REF(C,1)+(REF(O,1)-REF(C,1))*0.5 AND C>REF(C,1);
DRAWTEXT(戮入线,L-0.2,'戮入失败线 '),COLORWHITE; {-代表下跌市场中的失败涨升 下降趋势持续}

贯穿线:= {也叫切入线，昨日收阴，今日收阳，低开后收盘于阴线中部以上, 虽未能吞噬但力道也很强}
REF(CLOSE,1)-REF(OPEN,1)<0 AND CLOSE-OPEN>0 AND OPEN-REF(CLOSE,1)<0 AND CLOSE<REF(OPEN,1) AND CLOSE>REF(CLOSE,1) AND CLOSE>(REF(CLOSE,1)+REF(OPEN,1))/2;
DRAWTEXT(贯穿线,L-0.2,'切入线 '),COLORWHITE; {-多头力道的反扑或是空单回补力道 长黑之后开低收在前天1/2之上 多头反转信号}


曙光:= {要求切入线2根K 线幅度均较大，为中K线 >3%}
REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.03 AND OPEN<REF(CLOSE,1) AND CLOSE>REF(CLOSE,1);
DRAWTEXT(曙光,H+0.2,'曙光 '),COLORRED; {-与乌云盖顶相反 行情将演化为V型反转或止跌横盘趋势}

{3根K线}
三白兵:= {收3红，涨3天}
REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND CLOSE>OPEN AND REF(CLOSE,1)>REF(CLOSE,2) AND CLOSE>REF(CLOSE,1);
DRAWTEXT(三白兵,H+0.3,'三白兵 '),COLORRED;{-多方气盛 在底部见底反弹可能}

三只乌鸦:= {收3黑，跌3天}
REF(CLOSE,2)<REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND CLOSE<OPEN AND REF(CLOSE,1)<REF(CLOSE,2) AND CLOSE<REF(CLOSE,1);
DRAWTEXT(三只乌鸦,L-0.3,'三只乌鸦 '),COLORWHITE;{-强烈转空趋势 三黑K价越深量越大越易下跌}


body_r12:=(ABS(REF(C,1)-REF(O,1)))/(ABS(REF(C,2)-REF(O,2)));
乌云罩顶:={昨日收阳，实体是是前天2.5倍，今日收阴，且开盘点高，收盘已低于昨日一半价}
REF(C,1)-REF(O,1)>0 AND body_r12 >2.5 AND C-O<0 AND C>REF(O,1) AND C<(REF(CLOSE,1)+REF(OPEN,1))/2 AND O>REF(C,1);
DRAWTEXT(乌云罩顶,L-0.3,'乌云罩顶 '),COLORWHITE; {-上涨遇重大阻力 空头聚力}

乌云罩顶2:={昨日收阳，实体是前天1.5倍，但今天被切}
REF(C,1)-REF(O,1)>0 AND body_r12>1.5 AND body_r12 <2.5
AND C-O<0 AND C>REF(O,1) AND C<REF(C,1) AND O>REF(C,1);
DRAWTEXT(乌云罩顶2,L-0.35,'乌云罩顶2 '),COLORWHITE;{-上涨遇重大阻力 空头聚力 三日内见九死一生或跌落一红K低点 反转走空}

包容线:={前天收阳，昨天收阴，今天收阳，两阳夹一阴}
REF(C,2)-REF(O,2)>0  AND REF(C,1)-REF(O,1)<0 AND C-O>0 AND REF(C,1)-REF(O,2)>0 AND REF(C,1)<REF(C,2) AND REF(O,1)>REF(C,2) AND O<REF(C,1) AND C>REF(O,1);
DRAWTEXT(包容线,L-0.3,'包容线 ');{翻空？}

二阳夹一阴:= {前日收阳，实体超过2个点，昨日收阴，是个孕线，且实体小于2%，今日收阳，是吞噬线，收盘点位与前天很接近}
REF(CLOSE,2)>REF(OPEN,2) AND (REF(CLOSE,2)-REF(OPEN,2))/REF(OPEN,2)>=2/100  AND REF(OPEN,1)>=REF(CLOSE,1) AND (REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<=2/100 AND REF(OPEN,1)<=REF(CLOSE,2) AND REF(CLOSE,1)>=REF(OPEN,2) AND C>=OPEN AND (CLOSE-OPEN)/OPEN>=2/100 AND CLOSE>=REF(OPEN,1) AND OPEN<=REF(CLOSE,1) AND (MAX(CLOSE,REF(C,2))-MIN(CLOSE,REF(CLOSE,2)))/MIN(CLOSE,REF(CLOSE,2))<=1/100;
DRAWTEXT(二阳夹一阴,L-0.3,'二阳夹一阴  '),COLORYELLOW; {-必须从后续的走势来研判}

body_r23:=(ABS(REF(C,2)-REF(O,2)))/(ABS(REF(C,3)-REF(O,3)));
body_r01:=(ABS(c-o))/(ABS(REF(C,1)-REF(O,1)));
body_r02:=(ABS(c-o))/(ABS(REF(C,2)-REF(O,2)));
body_2:=ABS(REF(C,2)-REF(O,2));
body_1:=ABS(REF(C,1)-REF(O,1));
neg_2:= REF(C,2)-REF(O,2)<0 ; {前日阴线}
neg_1:= REF(C,1)-REF(O,1)<0 ;
neg_0:= c-o<0 ;
pos_2:= REF(C,2)-REF(O,2)>0 ;
pos_1:= REF(C,1)-REF(O,1)>0 ;
pos_0:= c-o>0 ;
low_1o:= REF(O,1) <REF(C,2); {昨日低开}
high_1o:= REF(O,1) >REF(C,2);
low_o:= o < ref(c,1); {今日低开}
high_o:= o > ref(c,1); {今日高开}
up_1c:= REF(c,1) > REF(c,2); {昨日收盘升}
up_1o:= REF(o,1) > REF(o,2); {昨日开盘升}
up_o:= o>REF(o,1) ; {今日开盘升}
down_1c:= REF(c,1) < REF(c,2);
down_o:= o<REF(o,1) ; {今日开盘降}

{前天收阴，且实体比大前天大2.7倍，比昨天实体大，昨天收阴，今天收阳，今天实体比左天实体大2.5倍, }
{昨天开盘价低开，今日开盘高于昨日开盘，收盘小于前日开盘大于前日收盘，即今天中阳吃入前天大阴线一部分}
{或者昨日收盘价为跌，今日开盘大于昨日收盘， 今日收盘高于前日收盘小于前日开盘， 是弃子线的一种}
晨星:=
(neg_2 AND body_r23 >2.7 AND body_2>body_1 AND body_r01>2.5 AND neg_1 AND pos_0 AND low_1o AND up_o AND C<REF(O,2)  AND C>REF(C,2)) OR
(neg_2 AND body_r23 >2.7 AND body_2>body_1 AND body_r01>2.5 AND neg_1 AND pos_0 AND down_1c AND high_o AND C>REF(C,2) AND C<REF(O,2))  ;
DRAWTEXT(晨星,L-0.3,'晨星 '),COLORWHITE; {-反多信号}

晨星2:= {幅度不同}
(neg_2 AND body_r23>2.3 AND body_2>body_1 AND body_r01>2 AND body_r02<2 AND neg_1 AND pos_0 AND low_1o AND up_o AND C<REF(O,2)  AND C>REF(C,2)) OR
(neg_2 AND body_r23>2.3 AND body_2>body_1 AND body_r01>2 AND body_r02 AND neg_1 AND pos_0 AND down_1c AND high_o AND C>REF(C,2) AND  C<REF(O,2));
DRAWTEXT(晨星2,L-0.35,'晨星2 '),COLORWHITE;{-反多信号}

黎明之星:= {前天大阴线5%，今天大阳线5%已经侵入前天领地，昨天实体小}
REF(OPEN,1)<>REF(CLOSE,1) AND REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND low_1o AND ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03 AND CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);
DRAWTEXT(黎明之星,L-0.3,'黎明之星 '),COLORWHITE;{-多方势盛 变盘信号}

晨星十字:= {前天大阴体5%，昨日低开十字，今日大阳体侵入阴体内}
REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND low_1o AND REF(OPEN,1)=REF(CLOSE,1)AND CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);
DRAWTEXT(晨星十字,L-0.3,'晨星十字 '),COLORWHITE;{-同晨星 从看空平衡到看涨 转强 左右跳空曰弃婴}

夜星:=
(pos_2 AND body_r23>2.4 AND ABS(C-O)>3 AND body_2>body_1 AND pos_1 AND neg_0 AND high_1o AND down_o AND C<REF(C,2) AND C>REF(O,2)) OR
(pos_2 AND body_r23>2.4 AND ABS(C-O)>3 AND body_2>body_1 AND neg_1 AND neg_0 AND up_1c AND low_o  AND C<REF(C,2) AND C>REF(O,2));
DRAWTEXT(夜星,L-0.3,'夜星 '),COLORWHITE;{-从看多平衡到看空 转弱 转空}

黄昏之星:={昨日<2%阴体，高开，前日>3%阳体，今日3%阴体，已跌入前日收盘价内}
REF(OPEN,1)<>REF(CLOSE,1) AND REF(CLOSE,2)/REF(OPEN,2) > 1.03 AND high_1o AND ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.02 AND CLOSE/OPEN<0.97 AND CLOSE<REF(CLOSE,2);
DRAWTEXT(黄昏之星,L-0.3,'黄昏之星 '),COLORWHITE;{-空方势盛 反转信号 跳空成弃婴}

夜星十字:={昨日高开十字，前日5%大阳烛，今日5%大阴烛}
REF(CLOSE,2)/REF(OPEN,2) > 1.05 AND high_1o AND REF(OPEN,1)=REF(CLOSE,1)AND CLOSE/OPEN<0.95 AND CLOSE<REF(CLOSE,2);
DRAWTEXT(夜星十字,L-0.3,'黄昏十字 '),COLORWHITE;{-同夜星 从看多平衡到看空 转弱 左右跳空曰弃婴}



neg_3:= REF(C,3)-REF(O,3)<0 ; {前3日阴线}
上升三部曲:={前4天阴线实体3%,后续3天阴，但高低都包含在大阴之内，今日大阳体3%，收盘高于4天前收盘}
REF(CLOSE,4)/REF(OPEN,4)>1.03 AND neg_3 AND neg_2 AND neg_1 AND REF(LOW,4)<REF(LOW,3) AND REF(LOW,4)<REF(LOW,2) AND REF(LOW,4)<REF(LOW,1) AND REF(HIGH,4)>REF(HIGH,3) AND REF(HIGH,4)>REF(HIGH,2) AND REF(HIGH,4)>REF(HIGH,1) AND CLOSE/OPEN>1.03 AND CLOSE>REF(CLOSE,4);
DRAWTEXT(上升三部曲,L-0.3,'上升三部曲 '),COLORWHITE;{-空方卖压被吸纳 趋势易顺势走涨}

下跌三部曲:=
REF(CLOSE,4)/REF(OPEN,4)<0.97 AND REF(CLOSE,3)>REF(OPEN,3) AND REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND REF(LOW,4)<REF(LOW,3) AND REF(LOW,4)<REF(LOW,2) AND REF(LOW,4)<REF(LOW,1) AND REF(HIGH,4)>REF(HIGH,3) AND REF(HIGH,4)>REF(HIGH,2) AND REF(HIGH,4)>REF(HIGH,1) AND CLOSE/OPEN<0.97 AND CLOSE<REF(CLOSE,4);
DRAWTEXT(下跌三部曲,L-0.3,'下跌三部曲 '),COLORWHITE;{-多方弱势不堪一击 趋势易顺势走跌}

双人殉情:={今日长红吞噬昨日高低点，昨日长阴开盘收盘吞噬前日开盘收盘。前日开盘收盘大雨大前日开盘收盘}
neg_1 AND pos_0 AND C>REF(H,1) AND O<REF(L,1) AND REF(O,1)>REF(MAX(O,C),2) AND REF(C,1)>REF(MIN(O,C),2) AND REF(MAX(O,C),2)>REF(MAX(O,C),3);
DRAWTEXT(双人殉情,L-0.4,'双人殉情'),COLORWHITE; {-在上升趋势中最后之空头吞噬 也就是所谓的不见长红不回头}

三胎鸦:={收3阴线，并且几乎都是不带毛的}
(REF(HIGH,2) -REF(O,2))/REF(HIGH,2)<=0.0003 AND (C-LOW)/O<=0.0003 AND neg_2 AND low_1o AND low_o AND neg_1 AND REF(HIGH,1)-REF(O,1)>0 AND REF(LOW,1)-REF(C,1)<0 AND HIGH-O>0 AND REF(C,2)-REF(LOW,2)>0 AND neg_0;
DRAWTEXT(三胎鸦,L-0.3,'三胎鸦 '),COLORWHITE;{-多头走势被扭转 黑K价愈深量愈大 跳空愈大 反转信号愈强}

pos_3:= REF(C,3)-REF(O,3)>0 ; {前3日阳线}
连续型态之执垫:= {前4天阳线实体>2%,后收3阴线，为孕线，今日收阳线，开盘价高，收盘价比3天前高}
REF(CLOSE,4)/REF(OPEN,4)>1.02 AND neg_3 AND neg_2 AND neg_1 AND REF(CLOSE,4)<=REF(CLOSE,3) AND REF(HIGH,2)<REF(HIGH,3) AND REF(LOW,2)>=REF(OPEN,4) AND REF(HIGH,1)<REF(CLOSE,4) AND REF(LOW,1)>REF(OPEN,4) AND CLOSE/OPEN>1.01 AND up_o AND CLOSE>=REF(HIGH,3);
DRAWTEXT(连续型态之执垫,L-0.3,'连续型态之执垫 '),COLORWHITE;{-比上升三法更具多头意义}

{简言之:昨日孕阳，今日继续上攻}
内困三日翻红:={前日黑，昨日红，今日红，昨日高开，收盘不及前日开盘，今日开盘高于前日开盘，收盘大于昨日收盘}
pos_0 AND (neg_2 AND pos_1 AND REF(C,1)<REF(O,2) AND high_1o AND O>REF(O,2) AND C>REF(C,1));
DRAWTEXT(内困三日翻红,L-0.3,'内困三日翻红'),COLORWHITE;{-一二母子 二量缩 三量增翻红}