记录2--u-boot 1.1.6 start.S

来源：互联网发布：java绝对路径编辑：程序博客网时间：2024/04/30 10:42

.globl _start
_start: b reset
ldr pc, _undefined_instruction
ldr pc, _software_interrupt
ldr pc, _prefetch_abort
ldr pc, _data_abort
ldr pc, _not_used
ldr pc, _irq
ldr pc, _fiq
_undefined_instruction: .word undefined_instruction
_software_interrupt: .word software_interrupt
_prefetch_abort: .word prefetch_abort
_data_abort: .word data_abort
_not_used: .word not_used
_irq: .word irq
_fiq: .word fiq
.balignl 16,0xdeadbeef

说明：

（1）_start是整个u-boot程序的入口点，即链接后，该处是整个程序的第一条指令。程序的入口点是由链接脚本所指定，比如对于smdk2410的板子(下面都以smdk241为例)，脚本文件位于board/smdk2140/u-boot.lds。在该脚本文件中：ENTRY(_start)即指定程序的入口地址。

（2）globl _start 定义一个外部可以引用的变量，比如说，在其它源代码文档中。就可以直指引用_start这个变量。而在C语言中如intentry=_start; 那此处entry值将是多少呢？因为_start相当于一个变量，entry的值就是_start处存储的值。即breset机器码值。关于globl定义的变量得注意的地方。后面还有记录这段代码处理中断向量表。
（3）关于 balignal 16,0xdeadbeef的网上资料：
.align伪操作用于表示对齐方式：通过添加填充字节使当前位置满足一定的对齐方式。
.balign的作用同.align。
.align {alignment} {,fill} {,max}
其中：alignment用于指定对齐方式，可能的取值为2的次幂，缺省为4。fill是填充内容。
缺省用0填充。max是填充字节数最大值，如果填充字节数超过max,就不进行对齐.
例如： .align 4, 指定对齐方式为字对齐
deadbeef一般用来表示没用的或是已经被释放掉的内存

_TEXT_BASE:
.word TEXT_BASE
.globl _armboot_start
_armboot_start:
.word _start

.globl _bss_start
_bss_start:
.word __bss_start
.globl _bss_end
_bss_end:
.word _end

备注这几个由.word伪操作符定义变量的作用及其取值
_TEXT_BASE:
.word TEXT_BASE
_TEXT_BASE:此处定义一汇编语言标签，更好的理解就是：告诉编译器。
  为_TEXT_BASE分配存储空间。
  该空间的名字就叫_TEXT_BASE,该空间中存储的值就是由.word后面确定的TEXT_BASEC(即0x33F80000)。
  相当于C语言中 long _TEXT_BASE=TEXT_BASE;TEXT_BASE定义在board/smdk2410/config.mk文件中。该值的作用是告诉链接器，本程序运行的基地址为TEXT_BASE。U-boot编译后。
  烧在FLASH的第一个块中。
  CPU复位上电后，电脑寄存器为0x0000。怎么会跑到TEXT_BASE处执行呢？
事实上，CPU上电后。
  从地址0x0000处执行。
  而U-BOOT的最起始代码。
  即本文件中从_start开始的代码是与地址不相关的。
  这段代码放在任何空间执行的结果都是一样（当然不是绝对，假设u-boot代码段是100K。
  则放在TEXT_BASE-80K处。
  搬运时就会把u-boot代码后面20K部分覆盖为最前面的20K）。
.globl _armboot_start
_armboot_start:
.word _start
定义外部可以引用的变量_armboot_start,此处为标签为_armboot_start的内存赋值，取的值为_srart内存中的值，即相当于C long_armboot_start=&_start;_armboot_start值是多少？是TEXT_BASE,即0x33F80000！等价的那条Ｃ语句，取的是_start变量地址。
  而不是_start本身。在Ｃ语言中。
  定义一变量 intx=100;就是告诉编译器。给我一个int大小的存储空间。
  该空间存储的值就是100，这个空间在哪呢？即空间地址是多少呢？我们可以通过&x知道。
在汇编语言中，理解上有点不一样。上面三行语句。

第一句，告诉编译器。
  向外面输出变量_armboot_start
第二句，_armboot_start变量在此处，到底在哪。
  要到链接时才能确定。
  凡正现在知道有这么一个变量了。
第三句，_armboot_start变量空间放的数据为_start标签的值。这点与Ｃ语言的理解有点不一样了。此处引用的是_start标签对应处的地址。在汇编语言中，标签代表的就是那行所在的地址。
图１是从u-boot编译后生成的u-boot.map截图的。从此文件中知道，_armboot_start这个变量地址为0x33f80044，

.globl_bss_start
_bss_start:
.word __bss_start
此三句。
  特别要备注的是__bss_start这个符号。
  它的值为多少？该值定义在board/smdk2410/u-boot.lds文件中
. = ALIGN(4);
__bss_start = .;
.bss : { *(.bss) }
_end = .;
上面的__bss_start=.; 表示__bss_start值就是当前位置的值。当前位置是多少呢？从下面一句
.bss:{*(.ss)}知道。紧接该位置后面马上就是放bss段数据了。所以。
  当然就是bss段的起始地址。_end就是bss段的结束地址。
参考：http://blog.chinaunix.net/u1/58780/showart_462971.html
bss是这个链接脚本的最后一个段。start.S就是以这个段的起始地址来计算要搬运u-boot大小的代码的。即。
  这个段前面的所有数据都将被搬到TEXT_BASE处。然后跑到start_armboot处，即Ｃ语言的入口代码。__bss_start这个值是多少？Smdk2410我编译后值是0x33f96f20。可以从图２的map文件中查到，bss段从0x33f96f20开始分配的。
再次验证一下0x33f96f20就是__bss_start值。
  我们可以从图１处可以看到有个变量_bss_start该变量就是由下面三条语句所定义，_bss_start处保存的值就是__bss_start：
.globl _bss_start
_bss_start:
.word __bss_start

reset:

mrs r0,cpsr
bic r0,r0,#0x1f
orr r0,r0,#0xd3
msr cpsr,r0

#if defined(CONFIG_S3C2400)
# define pWTCON 0x15300000
# define INTMSK 0x14400008
# define CLKDIVN 0x14800014
#elif defined(CONFIG_S3C2410)
# define pWTCON 0x53000000
# define INTMSK 0x4A000008
# define INTSUBMSK 0x4A00001C
# define CLKDIVN 0x4C000014
#endif
#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
ldr r0, =pWTCON
mov r1, #0x0
str r1, [r0]

mov r1, #0xffffffff
ldr r0, =INTMSK
str r1, [r0]
# if defined(CONFIG_S3C2410)
ldr r1, =0x3ff
ldr r0, =INTSUBMSK
str r1, [r0]
# endif

ldr r0, =CLKDIVN
mov r1, #3
str r1, [r0]
#endif

#ifndef CONFIG_SKIP_LOWLEVEL_INIT
bl cpu_init_crit
#endif

adr r0, _start
ldr r1, _TEXT_BASE
cmp r0, r1
beq stack_setup
ldr r2, _armboot_start
ldr r3, _bss_start
sub r2, r3, r2
add r2, r0, r2

copy_loop:
ldmia r0!, {r3-r10}
stmia r1!, {r3-r10}
cmp r0, r2
ble copy_loop

#endif

stack_setup:
ldr r0, _TEXT_BASE
sub r0, r0, #CFG_MALLOC_LEN
sub r0, r0, #CFG_GBL_DATA_SIZE
#ifdef CONFIG_USE_IRQ
sub r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
sub sp, r0, #12

clear_bss:
ldr r0, _bss_start
ldr r1, _bss_end
mov r2, #0x00000000
clbss_l:str r2, [r0]
add r0, r0, #4
cmp r0, r1
ble clbss_l

ldr pc, _start_armboot
_start_armboot: .word start_armboot

0 0