PL-SQL 存储函数和存储过程



PL-SQL 存储函数和存储过程

ORACLE 提供可以把PL/SQL 程序存储在数据库中，并可以在任何地方来运行它。这样就叫存储过程或函数。
过程和函数统称为PL/SQL子程序，他们是被命名的PL/SQL块，均存储在数据库中，并通过输入、输出参数或输入/输出参数与其调用者交换信息。
过程和函数的唯一区别是函数总向调用者返回数据，而过程则不返回数据。

①创建函数
1. 建立内嵌函数
语法如下：
CREATE[OR REPLACE] FUNCTION function_name
    [ (argment [ { IN| IN OUT }] Type,
    argment [ { IN| OUT| IN OUT} ] Type ]
    [ AUTHID DEFINER| CURRENT_USER ]
    RETURN return_type
{ IS| AS}
    <类型.变量的说明>
BEGIN
    FUNCTION_body
EXCEPTION
    其它语句
END;
说明:
1) OR REPLACE 为可选. 有了它, 可以或者创建一个新函数或者替换相同名字的函数, 而不会出现冲突
2) 函数名后面是一个可选的参数列表, 其中包含IN, OUT 或IN OUT 标记. 参数之间用逗号隔开.
    IN 参数标记表示传递给函数的值在该函数执行中不改变;
    OUT 标记表示一个值在函数中进行计算并通过该参数传递给调用语句;
    IN OUT 标记表示传递给函数的值可以变化并传递给调用语句. 若省略标记, 则参数隐含为IN。
3) 因为函数需要返回一个值, 所以RETURN 包含返回结果的数据类型.

2. 内嵌函数的调用
函数声明时所定义的参数称为形式参数，应用程序调用时为函数传递的参数称为实际参数。应用程序在调用函数时，
可以使用以下三种方法向函数传递参数：
第一种参数传递格式称为位置表示法，格式为：

第二种参数传递格式称为名称表示法，格式为：
argument => parameter [,…]
其中：argument 为形式参数，它必须与函数定义时所声明的形式参数名称相同。Parameter 为实际参数。
在这种格式中，形势参数与实际参数成对出现，相互间关系唯一确定，所以参数的顺序可以任意排列。

第三种参数传递格式称为混合表示法：
即在调用一个函数时，同时使用位置表示法和名称表示法为函数传递参数。采用这种参数传递方法时，
使用位置表示法所传递的参数必须放在名称表示法所传递的参数前面。也就是说，无论函数具有多少个参数，
只要其中有一个参数使用名称表示法，其后所有的参数都必须使用名称表示法。

无论采用哪一种参数传递方法，实际参数和形式参数之间的数据传递只有两种方法：传址法和传值法。
所谓传址法是指在调用函数时，将实际参数的地址指针传递给形式参数，使形式参数和实际参数指向内存中的同一区域，从而实现参数数据的传递。
这种方法又称作参照法，即形式参数参照实际参数数据。输入参数均采用传址法传递数据。
传值法是指将实际参数的数据拷贝到形式参数，而不是传递实际参数的地址。默认时，输出参数和输入/输出参数均采用传值法。
在函数调用时，ORACLE将实际参数数据拷贝到输入/输出参数，而当函数正常运行退出时，又将输出形式参数和输入/输出形式参数数据拷贝到实际参数变量中。

3. 参数默认值
在CREATE OR REPLACE FUNCTION 语句中声明函数参数时可以使用DEFAULT关键字为输入参数指定默认值。
具有默认值的函数创建后，在函数调用时，如果没有为具有默认值的参数提供实际参数值，函数将使用该参数的默认值。
但当调用者为默认参数提供实际参数时，函数将使用实际参数值。
在创建函数时，只能为输入参数设置默认值，而不能为输入/输出参数设置默认值。

②创建过程
1.建立存储过程
在ORACLE SERVER上建立存储过程,可以被多个应用程序调用,可以向存储过程传递参数,也可以向存储过程传回参数.
创建过程语法:
CREATE[OR REPLACE] PROCEDURE Procedure_name
    [ (argment [ { IN| IN OUT }] Type,
    argment [ { IN| OUT| IN OUT} ] Type ]
    [ AUTHID DEFINER| CURRENT_USER ]
{ IS| AS}
    <类型.变量的说明>
BEGIN
    <执行部分>
EXCEPTION
    <可选的异常错误处理程序>
END;

2. 调用存储过程
ORACLE 使用EXECUTE语句来实现对存储过程的调用：
EXEC[UTE]  Procedure_name( parameter1, parameter2…);

3.AUTHID
在创建存储过程时, 可使用AUTHID CURRENT_USER 或AUTHID DEFINER 选项,以表明在执行该过程时Oracle 使用的权限.
1) 如果使用AUTHID CURRENT_USER 选项创建一个过程, 则Oracle 用调用该过程的用户权限执行该过程.
为了成功执行该过程,调用者必须具有访问该存储过程体中引用的所有数据库对象所必须的权限

2) 如果用默认的AUTHID DEFINER 选项创建过程, 则Oracle 使用过程所有者的特权执行该过程.为了成功执行该过程,
过程的所有者必须具有访问该存储过程体中引用的所有数据库对象所必须的权限. 想要简化应用程序用户的特权管理,
在创建存储过程时, 一般选择AUTHID DEFINER 选项–--这样就不必授权给需要调用的此过程的所有用户了.

④删除存储过程和存储函数
1．删除过程
可以使用DROP PROCEDURE命令对不需要的过程进行删除，语法如下：
DROP PROCEDURE [user.]Procudure_name;
2．删除函数
可以使用DROP FUNCTION 命令对不需要的函数进行删除，语法如下：
DROP FUNCTION [user.]Function_name;

⑤例子
[存储函数：有返回值，创建完成后，通过select function() from dual;执行]
[存储过程：由于没有返回值，创建完成后，不能使用select语句，只能使用pl/sql块执行]

[格式]
--函数的声明(有参数的写在小括号里)
create or replace function func_name(v_param varchar2)
 --返回值类型
 return varchar2
is
 --PL/SQL块变量、记录类型、游标的声明(类似于前面的declare的部分)
begin
 --函数体(可以实现增删改查等操作，返回值需要return)
       return 'helloworld'|| v_logo;
end;

1 函数的 helloworld: 返回一个 "helloworld" 的字符串

create or replace function hello_func
return varchar2
is
begin
       return 'helloworld';
end;

执行函数

begin
    dbms_output.put_line(hello_func());
end;

或者： select hello_func() from dual;

2 返回一个"helloworld: atguigu"的字符串，其中atguigu 由执行函数时输入。

--函数的声明(有参数的写在小括号里)
create or replace function hello_func(v_logo varchar2)
--返回值类型
return varchar2
is
--PL/SQL块变量的声明
begin
--函数体
       return 'helloworld'|| v_logo;
end;

3 创建一个存储函数，返回当前的系统时间
create or replace function func1
return date
is
--定义变量
v_date date;
begin
 --函数体
 --v_date := sysdate;
       select sysdate into v_date from dual;
       dbms_output.put_line('我是函数哦');
      
       return v_date;
end;

执行法1：
select func1 from dual;
执行法2：
declare
  v_date date;
begin
  v_date := func1;
  dbms_output.put_line(v_date);
end;
4. 定义带参数的函数: 两个数相加

create or replace function add_func(a number, b number)
return number
is
begin
       return (a + b);
end;

执行函数

begin
    dbms_output.put_line(add_func(12, 13));
end;
或者
    select add_func(12,13) from dual;

5. 定义一个函数: 获取给定部门的工资总和, 要求:部门号定义为参数, 工资总额定义为返回值.

create or replace function sum_sal(dept_id number)
       return number
       is
      
       cursor sal_cursor is select salary from employees where department_id = dept_id;
       v_sum_sal number(8) := 0;  
begin
       for c in sal_cursor loop
           v_sum_sal := v_sum_sal + c.salary;
       end loop;      

       --dbms_output.put_line('sum salary: ' || v_sum_sal);
       return v_sum_sal;
end;

执行函数

begin
    dbms_output.put_line(sum_sal(80));
end;

6. 关于 OUT 型的参数: 因为函数只能有一个返回值, PL/SQL 程序可以通过 OUT 型的参数实现有多个返回值

要求: 定义一个函数: 获取给定部门的工资总和 和 该部门的员工总数(定义为 OUT 类型的参数).
要求: 部门号定义为参数, 工资总额定义为返回值.

create or replace function sum_sal(dept_id number, total_count out number)
       return number
       is
      
       cursor sal_cursor is select salary from employees where department_id = dept_id;
       v_sum_sal number(8) := 0;  
begin
       total_count := 0;

       for c in sal_cursor loop
           v_sum_sal := v_sum_sal + c.salary;
           total_count := total_count + 1;
       end loop;      

       --dbms_output.put_line('sum salary: ' || v_sum_sal);
       return v_sum_sal;
end;  

执行函数:

delare
  v_total number(3) := 0;

begin
    dbms_output.put_line(sum_sal(80, v_total));
    dbms_output.put_line(v_total);
end;

7*. 定义一个存储过程: 获取给定部门的工资总和(通过 out 参数), 要求:部门号和工资总额定义为参数

create or replace procedure sum_sal_procedure(dept_id number, v_sum_sal out number)
       is
      
       cursor sal_cursor is select salary from employees where department_id = dept_id;
begin
       v_sum_sal := 0;
      
       for c in sal_cursor loop
           --dbms_output.put_line(c.salary);
           v_sum_sal := v_sum_sal + c.salary;
       end loop;      

       dbms_output.put_line('sum salary: ' || v_sum_sal);
end;
[执行]
declare
     v_sum_sal number(10) := 0;
begin
     sum_sal_procedure(80,v_sum_sal);
end;

8*. 自定义一个存储过程完成以下操作:
对给定部门(作为输入参数)的员工进行加薪操作, 若其到公司的时间在 (? , 95) 期间,    为其加薪 %5
                                                               [95 , 98)             %3      
                                                               [98, ?)               %1
得到以下返回结果: 为此次加薪公司每月需要额外付出多少成本(定义一个 OUT 型的输出参数).

create or replace procedure add_sal_procedure(dept_id number, temp out number)

is

       cursor sal_cursor is select employee_id id, hire_date hd, salary sal from employees where department_id = dept_id;
       a number(4, 2) := 0;
begin
       temp := 0;      

       for c in sal_cursor loop
           a := 0;   
      
           if c.hd < to_date('1995-1-1', 'yyyy-mm-dd') then
              a := 0.05;
           elsif c.hd < to_date('1998-1-1', 'yyyy-mm-dd') then
              a := 0.03;
           else
              a := 0.01;
           end if;
          
           temp := temp + c.sal * a;
           update employees set salary = salary * (1 + a) where employee_id = c.id;
       end loop;      
end;