把对后台的操作记录保存到文本文件的类

<%
Class Adminstrator
 Private objFile,SetFileName,SetTextName
 Dim FileName_  '存放操作记录的总文件夹
 Dim ToFile_   '二级目录　２００７
 Dim File_    '三级目录  １２　月
 Dim TextName_  '记录名称
 Dim ToFileOpen_ '是否启用二级目录 True-启用　False-不启用
 Dim FileOpen_  '是否启用三级目录 True-启用　False-不启用
 '****************************************************************
 '属性
 '****************************************************************
 Public Property Get FileName
  FileName=FileName_
 End Property

 Public Property Let FileName(value)
  FileName_=value
 End Property

 Public Property Get ToFile
  ToFile=ToFile_
 End Property

 Public Property Let ToFile(value)
  ToFile_=value
 End Property

 Public Property Get File
  File=File_
 End Property

 Public Property Let File(value)
  File_=value
 End Property

 Public Property Get TextName
  TextName=TextName_
 End Property

 Public Property Let TextName(value)
  TextName_=value
 End Property

 Public Property Get ToFileOpen
  ToFileOpen=ToFileOpen_
 End Property

 Public Property Let ToFileOpen(value)
  ToFileOpen_=value
 End Property

 Public Property Get FileOpen
  FileOpen=FileOpen_
 End Property

 Public Property Let FileOpen(value)
  FileOpen_=value
 End Property

 '****************************************************************
 '函数名：Class_Initialize
 '功能：默认值的设定
 '参数：无
 '返回值：无
 '****************************************************************
 Public Sub Class_Initialize
  FileName_="AdminLogFile"
  ToFile_=Year(Now())
  File_=Month(Now())
  TextName_=Day(Now())
  ToFileOpen_=True
  FileOpen_=True
 End Sub
 
 '****************************************************************
 '函数名：InLog
 '功能：判断目录是否存在，不存在则创建，把操作记录保存到文本文件
 '参数：value-操作记录，user-操作人
 '返回值：无
 '****************************************************************
 Public Sub InLog(value,user)
  Set objFile=Server.CreateObject("Scripting.FileSystemObject")
  
  IF objFile.FolderExists(Server.MapPath(FileName))=False Then
   objFile.CreateFolder(Server.MapPath(FileName))
  End IF

  IF ToFileOpen=True Then
   IF objFile.FolderExists(Server.MapPath(FileName&"/"&ToFile))=False Then
    objFile.CreateFolder(Server.MapPath(FileName&"/"&ToFile))
   End IF
  End IF
  
  IF ToFileOpen=True and FileOpen_=True Then
   IF objFile.FolderExists(Server.MapPath(FileName&"/"&ToFile&"/"&File))=False Then
    objFile.CreateFolder(Server.MapPath(FileName&"/"&ToFile&"/"&File))
   End IF
  End IF

  IF ToFileOpen=True Then
   SetFileName=ToFile
    IF FileOpen =True Then
     SetFileName=SetFileName&"/"&File
    Else
     SetFileName=SetFileName
    IF TextName_=Day(Now()) Then TextName_=Month(Now())&"-"&Day(Now())
    End IF
   SetTextName="/"&TextName
  Else
   SetFileName=""
   IF TextName_=Day(Now()) Then TextName_=Year(Now())&"-"&Month(Now())&"-"&Day(Now())
   SetTextName=TextName   
  End IF

  Set TextFile=objFile.OpenTextFile(Server.MapPath(FileName&"/"&SetFileName&SetTextName&".txt"),8,True)
   TextFile.WriteLine "操作："&value&"|操作人："&user&"|操作时间："&Now()
  TextFile.Close
 End Sub

End Class
%>

调用：

<%

Dim Admin
Set Admin = new Adminstrator
Admin.InLog "操作成功","User"

%>

还有很多功能没想到,希望大家给点意见!