VB.Net自己写的一个控件：ComboBox下拉列表中显示多列数据(可以绑定数据表)

最近在用VB.Net开发一个小程序时候，用到一个显示多列的ComboBox，而且从数据库中取出来的数据表要绑定到一个ComboBox中。找来找去，找不到。上Baidu Google很多人说:在VB.Net中的ComboBox只能绑定一列数据。以前的VBA和VB的ComBox可以显示多列数据的。上.Net的怎么不可以能。自己考虑到可以用一个ComboBox和一个ListView结合做一个能够显示多列内容的ComboBox下拉框，可以将一个数据表绑定到ComboBox中的用户控件。

自己就开始做，反复测试，改代码。

 

用户控件名：CmbBoxListView
控件里面有一个ComboBox和一个ListView。名称分别为：CmbBox和Lv。

 

控件的属性：
LvWidth     设置CmbBox中的List的宽度。
LvHeight    设置CmbBox中的List的高度。
IsShowColumnHeader  是否显示列标题。
IsShowRowHeader  是否显示行标题。
Text   获取或设置CmbBoxListView中的当前文本(重写基类Text)。

SelectedIndex 选中项的索引

 

控件的方法：（一个绑定数据表的方法，重载四次。）
BindDataTB(ByVal DataTB As DataTable, ByVal TBKeyWordName As String)
将DataTable的数据绑定到ListView中，作为CmbBox的List数据。并指定绑定的字段的名称。

BindDataTB(ByVal DataTB As DataTable, ByVal TBKeyWordPosition As Integer)
将DataTable的数据绑定到ListView中，作为CmbBox的List数据。并指定绑定的字段的位置。

BindDataTB(ByVal DataTB As DataTable, ByVal NewColumnsNameStr As String, ByVal KeyWordName As String)
将DataTable的数据绑定到ListView中，作为CmbBox的List数据。并指定新的列表标题和绑定的标题的名称。新的列表标题，用 , 或 ; 分隔开的字符串。

BindDataTB(ByVal DataTB As DataTable, ByVal NewColumnsNameStr As String, ByVal KeyWordPosition As Integer)
将DataTable的数据绑定到ListView中，作为CmbBox的List数据。并指定新的列表标题和绑定的标题的位置。新的列表标题，用 , 或 ; 分隔开的字符串。

 

 

使用起来很方便：
Me.CmbBoxListView1.LvWidth = 200
Me.CmbBoxListView1.LvHeight = 100
Me.CmbBoxListView1.IsShowColumnHeader = True
Me.CmbBoxListView1.IsShowRowHeader = False
Me.CmbBoxListView1.BindDataTB(Me.ADataSet.Dt, "你的;我的;他的;美的;好的", 1)
Me.TextBox1.Text = Me.CmbBoxListView1.Text

其中DataSet.Dt是一个DataSe的一个表Dt，表有5个字段名，绑定第一列为有效数据也就是控件CmbBoxListView中的当前文本Text属性。

 

------补充开始------

控件的下载地址：
http://download.csdn.net/source/954311

 

增加的一个事件，事件的使用和说明见：

http://blog.csdn.net/linjimu/archive/2009/01/09/3739537.aspx

 

------补充结束------

 

绑定效果：

 

整个控件的代码（已经添加了事件了）：

2. Public Class CmbBoxListView
3.     Inherits UserControl
5.     Public Delegate Sub ChangedTextEvent(ByVal sender As Object, ByVal e As EventArgs)
6.     Public Event SelectTextChanged As ChangedTextEvent
8.     Const CtrlHeight As Integer = 20
9.     Dim NewWidth, NewHeight, DesignCmbWidth As Integer
10.     Dim _TBKeyWordIndex As Integer
11.     Dim _IsShowColumnHeader As Boolean = True
12.     Dim _IsShowRowHeader As Boolean = True
13.     Dim _CmbBoxDorpDown As Boolean = False
15.     ''' <summary>
16.     ''' 设置CmbBox中的List的宽度。
17.     ''' </summary>
18.     ''' <value></value>
19.     ''' <returns></returns>
20.     ''' <remarks></remarks>
21.     Public Property LvWidth() As Integer
22.         Get
23.             Return Me.Lv.Width
24.         End Get
25.         Set(ByVal Value As Integer)
26.             Me.Lv.Width = Value
27.         End Set
28.     End Property
30.     ''' <summary>
31.     ''' 设置CmbBox中的List的高度。
32.     ''' </summary>
33.     ''' <value></value>
34.     ''' <returns></returns>
35.     ''' <remarks></remarks>
36.     Public Property LvHeight() As Integer
37.         Get
38.             Return Me.Lv.Height
39.         End Get
40.         Set(ByVal Value As Integer)
41.             Me.Lv.Height = Value
42.             NewHeight = CtrlHeight + Value
43.         End Set
44.     End Property
46.     ''' <summary>
47.     ''' 是否显示列标题。
48.     ''' </summary>
49.     ''' <value></value>
50.     ''' <returns></returns>
51.     ''' <remarks></remarks>
52.     Public Property IsShowColumnHeader() As Boolean
53.         Get
54.             Return _IsShowColumnHeader
55.         End Get
56.         Set(ByVal Value As Boolean)
57.             _IsShowColumnHeader = Value
58.         End Set
59.     End Property
61.     ''' <summary>
62.     ''' 是否显示行标题。
63.     ''' </summary>
64.     ''' <value></value>
65.     ''' <returns></returns>
66.     ''' <remarks></remarks>
67.     Public Property IsShowRowHeader() As Boolean
68.         Get
69.             Return _IsShowRowHeader
70.         End Get
71.         Set(ByVal Value As Boolean)
72.             _IsShowRowHeader = Value
73.         End Set
74.     End Property
76.     ''' <summary>
77.     ''' 获取或设置CmbBoxListView中的当前文本(重写基类Text)。
78.     ''' </summary>
79.     ''' <value></value>
80.     ''' <returns></returns>
81.     ''' <remarks></remarks>
82.     Public Overrides Property Text() As String
83.         Get
84.             Return (Me.CmbBox.Text)
85.         End Get
86.         Set(ByVal Value As String)
87.             Me.CmbBox.Text = Value
88.         End Set
89.     End Property
91.     Public ReadOnly Property SelectedIndex() As Integer
92.         Get
93.             Return Lv.SelectedIndices.Item(0)
94.         End Get
95.     End Property
97.     Private Sub CmbBoxListView_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
98.         Me.Lv.Location = New Point(Me.CmbBox.Location.X, Me.CmbBox.Location.Y + Me.CmbBox.Height)
99.         Lv.GridLines = True
100.         Lv.FullRowSelect = True
101.         Lv.View = View.Details
102.         Lv.Scrollable = True
103.         Lv.MultiSelect = False
104.         Me.Lv.Clear()
105.         NewHeight = CtrlHeight + Me.Lv.Height
106.     End Sub
108.     Private Sub CmbBoxListView_SizeChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.SizeChanged
109.         If Me.Width < 40 Then
110.             Me.Width = 40
111.         End If
112.         If _CmbBoxDorpDown = False Then
113.             Me.Height = CtrlHeight
114.             DesignCmbWidth = Me.Width
115.             Me.CmbBox.Width = DesignCmbWidth
116.         End If
117.     End Sub
119.     Private Sub CmbBoxListView_LostFocus(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.LostFocus
120.         Me.HidenLV()
121.     End Sub
123.     Private Sub CmbBox_DropDown(ByVal sender As Object, ByVal e As System.EventArgs) Handles CmbBox.DropDown
124.         Me.Lv.Visible = Not Me.Lv.Visible
125.         If Me.Lv.Visible = True Then
126.             _CmbBoxDorpDown = True
127.             If Me.CmbBox.Width > Me.Lv.Width Then
128.                 Me.Lv.Width = Me.CmbBox.Width
129.             End If
130.             NewWidth = IIf(Me.Lv.Width > Me.CmbBox.Width, Me.Lv.Width, Me.CmbBox.Width)
131.             Me.Width = NewWidth
132.             Me.Height = NewHeight
133.             Me.BringToFront()
134.             Me.Lv.Select()
135.         Else
136.             _CmbBoxDorpDown = False
137.             Me.Width = DesignCmbWidth
138.             Me.Height = CtrlHeight
139.         End If
140.     End Sub
142.     Private Sub Lv_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles Lv.Click
143.         Me.CmbBox.Text = Me.Lv.SelectedItems(0).SubItems(_TBKeyWordIndex + 1).Text
144.         RaiseEvent SelectTextChanged(Me, e)
145.         Me.HidenLV()
146.     End Sub
148.     Private Sub Lv_LostFocus(ByVal sender As Object, ByVal e As System.EventArgs) Handles Lv.LostFocus
149.         Me.HidenLV()
150.     End Sub
152.     ''' <summary>
153.     ''' 将DataTable的数据绑定到ListView中，作为CmbBox的List数据。并指定绑定的字段的名称。
154.     ''' </summary>
155.     ''' <param name="DataTB">绑定的数据表</param>
156.     ''' <param name="TBKeyWordName">指定绑定的字段的名称。</param>
157.     ''' <remarks></remarks>
158.     Public Sub BindDataTB(ByVal DataTB As DataTable, ByVal TBKeyWordName As String)
159.         AddColumnsHeader(DataTB)
160.         FindKeyWordPosition(DataTB, TBKeyWordName)
161.         FillDataTB2Lv(DataTB)
162.     End Sub
164.     ''' <summary>
165.     ''' 将DataTable的数据绑定到ListView中，作为CmbBox的List数据。并指定绑定的字段的位置。
166.     ''' </summary>
167.     ''' <param name="DataTB">绑定的数据表</param>
168.     ''' <param name="TBKeyWordPosition">指定绑定的字段名的位置。</param>
169.     ''' <remarks></remarks>
170.     Public Sub BindDataTB(ByVal DataTB As DataTable, ByVal TBKeyWordPosition As Integer)
171.         AddColumnsHeader(DataTB)
172.         _TBKeyWordIndex = TBKeyWordPosition - 1
173.         FillDataTB2Lv(DataTB)
174.     End Sub
176.     ''' <summary>
177.     ''' 将DataTable的数据绑定到ListView中，作为CmbBox的List数据。并指定新的列表标题和绑定的标题的名称。
178.     ''' </summary>
179.     ''' <param name="DataTB">绑定的数据表</param>
180.     ''' <param name="NewColumnsNameStr">新的列表标题，用 , 或 ; 分隔开的字符串。</param>
181.     ''' <param name="KeyWordName">指定绑定的标题的名称。</param>
182.     ''' <remarks></remarks>
183.     Public Sub BindDataTB(ByVal DataTB As DataTable, ByVal NewColumnsNameStr As String, ByVal KeyWordName As String)
184.         AddColumnsHeader(NewColumnsNameStr)
185.         FindKeyWordPosition(NewColumnsNameStr, KeyWordName)
186.         FillDataTB2Lv(DataTB)
187.     End Sub
189.     ''' <summary>
190.     '''  将DataTable的数据绑定到ListView中，作为CmbBox的List数据。并指定新的列表标题和绑定的标题的位置。
191.     ''' </summary>
192.     ''' <param name="DataTB">绑定的数据表</param>
193.     ''' <param name="NewColumnsNameStr">新的列表标题，用 , 或 ; 分隔开的字符串。</param>
194.     ''' <param name="KeyWordPosition">指定绑定的标题的位置。</param>
195.     ''' <remarks></remarks>
196.     Public Sub BindDataTB(ByVal DataTB As DataTable, ByVal NewColumnsNameStr As String, ByVal KeyWordPosition As Integer)
197.         AddColumnsHeader(NewColumnsNameStr)
198.         _TBKeyWordIndex = KeyWordPosition - 1
199.         FillDataTB2Lv(DataTB)
200.     End Sub
202.     Private Sub FillDataTB2Lv(ByVal _DataTB As DataTable)
203.         Dim i, j As Integer
204.         If _DataTB.Rows.Count > 0 Then
205.             Lv.Items.Clear()
206.             For i = 0 To _DataTB.Rows.Count - 1
207.                 Dim li As New ListViewItem
208.                 li.SubItems.Clear()
209.                 li.Text = i
210.                 For j = 0 To _DataTB.Columns.Count - 1
211.                     li.SubItems.Add(_DataTB.Rows(i)(j).ToString)
212.                 Next
213.                 Lv.Items.Add(li)
214.             Next
215.         End If
216.         UpdateLvColRowSetting()
217.     End Sub
219.     Private Sub AddColumnsHeader(ByVal _DataTB As DataTable)
220.         Dim i As Integer
221.         If _DataTB.Rows.Count > 0 Then
222.             Lv.Columns.Clear()
223.             Lv.Columns.Add("序")
224.             Lv.Columns(0).Width = 30
225.             For i = 0 To _DataTB.Columns.Count - 1
226.                 Lv.Columns.Add(_DataTB.Columns(i).Caption)
227.             Next
228.         End If
229.     End Sub
231.     Private Sub AddColumnsHeader(ByVal ColumnsNameStr As String)
232.         Dim i As Integer
233.         If ColumnsNameStr > "" Then
234.             Dim CName() As String
235.             Lv.Columns.Clear()
236.             Lv.Columns.Add("序")
237.             Lv.Columns(0).Width = 30
238.             If ColumnsNameStr.Contains(",") Then
239.                 CName = Split(ColumnsNameStr, ",")
240.                 For i = 0 To UBound(CName)
241.                     Lv.Columns.Add(CName(i))
242.                 Next
243.             End If
244.             If ColumnsNameStr.Contains(";") Then
245.                 CName = Split(ColumnsNameStr, ";")
246.                 For i = 0 To UBound(CName)
247.                     Lv.Columns.Add(CName(i))
248.                 Next
249.             End If
250.         End If
251.     End Sub
253.     Private Sub FindKeyWordPosition(ByVal _DataTB As DataTable, ByVal KeyWord As String)
254.         Dim i As Integer
255.         Dim TitleStr As ArrayList
256.         If _DataTB.Rows.Count > 0 Then
257.             TitleStr = New ArrayList
258.             For i = 0 To _DataTB.Columns.Count - 1
259.                 TitleStr.Add(_DataTB.Columns(i).Caption)
260.             Next
261.             _TBKeyWordIndex = TitleStr.IndexOf(KeyWord)
262.             TitleStr = Nothing
263.         End If
264.     End Sub
266.     Private Sub FindKeyWordPosition(ByVal NewColumnsNameStr As String, ByVal KeyWord As String)
267.         Dim i As Integer
268.         Dim TitleStr As ArrayList
269.         If NewColumnsNameStr > "" Then
270.             Dim CName() As String
271.             TitleStr = New ArrayList
272.             If NewColumnsNameStr.Contains(",") Then
273.                 CName = Split(NewColumnsNameStr, ",")
274.                 For i = 0 To UBound(CName)
275.                     TitleStr.Add(CName(i))
276.                 Next
277.                 _TBKeyWordIndex = TitleStr.IndexOf(KeyWord)
278.             End If
279.             If NewColumnsNameStr.Contains(";") Then
280.                 CName = Split(NewColumnsNameStr, ",")
281.                 For i = 0 To UBound(CName)
282.                     TitleStr.Add(CName(i))
283.                 Next
284.                 _TBKeyWordIndex = TitleStr.IndexOf(KeyWord)
285.             End If
286.             TitleStr = Nothing
287.         End If
288.     End Sub
290.     Private Sub UpdateLvColRowSetting()
291.         If IsShowColumnHeader Then
292.             Lv.HeaderStyle = ColumnHeaderStyle.Nonclickable
293.         Else
294.             Lv.HeaderStyle = ColumnHeaderStyle.None
295.         End If
296.         If Lv.Columns.Count > 0 Then
297.             For i As Integer = 0 To (Lv.Columns.Count - 1)
298.                 Lv.Columns(i).AutoResize(ColumnHeaderAutoResizeStyle.HeaderSize)
299.             Next
300.         End If
301.         If IsShowRowHeader Then
302.             If Lv.Columns.Count > 0 Then Lv.Columns(0).Width = 30
303.         Else
304.             If Lv.Columns.Count > 0 Then Lv.Columns(0).Width = 0
305.         End If
306.     End Sub
308.     Private Sub HidenLV()
309.         Me.Lv.Visible = False
310.         Me.Width = DesignCmbWidth
311.         Me.Height = CtrlHeight
312.     End Sub
314. End Class