(转AS3)利用BitmapData.draw对位图进行翻转缩放操作

Sprite对象有2个关于缩放的属性scaleX、scaleY，分别是缩放x轴和y轴。

看下面代码：

 

var c:Sprite = new Sprite;
c.x = 200;
addChild(c);

var s:Sprite = new Sprite;
s.graphics.beginFill(0xff0000);
s.graphics.drawRect(0,0,100,100);
s.graphics.endFill();
s.graphics.beginFill(0x00ff00);
s.graphics.drawRect(100,0,100,100);
s.graphics.endFill();
c.addChild(s);

//s.scaleX = -1;

 

下图分别是注释和没注释最后一句代码的运行结果：

 

把注释去掉可以发现，该对象已经水平翻转了一下，不过看过来却好像坐标往左移了200个像素，实际上只是像素变了，坐标并没有变。

不过这里可以发现，当把scaleX会水平翻转，那scaleY会怎么样呢？没错，是垂直翻转了！

 

由此为基础，使用BitmapData.draw，配合Matrix，就可以实现一个位图或者对象的水平翻转和垂直翻转，下面是实现代码：

 

package org.easily.utils
{
    import flash.display.BitmapData;
    import flash.geom.Matrix;

    public class BitmapDataUtils
    {
        //水平翻转一个位图
        public static function flipHorizontal(bmpData:BitmapData, transparent:Boolean = true, fillColor:uint = 0):BitmapData
        {
            var matrix:Matrix = new Matrix();
            matrix.a = -1;
            matrix.tx = bmpData.width;
            var bmpData_:BitmapData = new BitmapData(bmpData.width, bmpData.height, transparent, fillColor);
            bmpData_.draw(bmpData, matrix);
            return bmpData_;
        }
        
        //垂直翻转一个位图
        public static function flipVertical(bmpData:BitmapData, transparent:Boolean = true, fillColor:uint = 0):BitmapData
        {
            var matrix:Matrix = new Matrix();
            matrix.d = -1;
            matrix.ty = bmpData.height;
            var bmpData_:BitmapData = new BitmapData(bmpData.width, bmpData.height, transparent, fillColor);
            bmpData_.draw(bmpData, matrix);
            return bmpData_;
        }
        
        //缩放位图
        public static function scaleBitmapData(bmpData:BitmapData, scaleX:Number, scaleY:Number):BitmapData
        {
            var matrix:Matrix = new Matrix();
            matrix.scale(scaleX, scaleY);
            var bmpData_:BitmapData = new BitmapData(scaleX * bmpData.width, scaleY * bmpData.height, true, 0);
            bmpData_.draw(bmpData, matrix);
            return bmpData_;
        }
    }
}

 

 

最后一个缩放位图的方法适用于等比例缩放一个对象，位图引擎里面应该也有类似的实现。