用VB将WORD文档(或其他的二进制数据)生成xml文件并互相转换
来源:互联网 发布:windows xp 耳机录音 编辑:程序博客网 时间:2024/05/17 02:15
用vb将word文档(或其他的二进制数据)生成xml文件并互相转换
1. 建立一个新的vb工程
2. 引用 Microsoft XML,版本 2.0 或以上
3. 在窗体form1上建立按钮 cmdCreateXML 和 cmdGetBinary
代码:
Option Explicit
Dim oDoc As DOMDocument
Dim DOCINPATH As String
Dim XMLOUTPATH As String
Dim DOCOUTPATH As String
Private Sub cmdCreateXML_Click()
Dim oEle As IXMLDOMElement
Dim oRoot As IXMLDOMElement
Dim oNode As IXMLDOMNode
DOCINPATH = App.Path & "/DocInput.doc"
XMLOUTPATH = App.Path & "/XmlOuput.xml"
Call ReleaseObjects
Set oDoc = New DOMDocument
oDoc.resolveExternals = True
' Create processing instruction and document root
Set oNode = oDoc.createProcessingInstruction("xml", "version='1.0'")
Set oNode = oDoc.insertBefore(oNode, oDoc.childNodes.Item(0))
' Create document root
Set oRoot = oDoc.createElement("Root")
Set oDoc.documentElement = oRoot
oRoot.setAttribute "xmlns:dt", "urn:schemas-microsoft-com:datatypes"
' Add a few simple nodes with different datatypes
Set oNode = oDoc.createElement("Document")
oNode.Text = "Demo"
oRoot.appendChild oNode
Set oNode = oDoc.createElement("CreateDate")
oRoot.appendChild oNode
Set oEle = oNode
' Use DataType so MSXML will validate the data type
oEle.dataType = "date"
oEle.nodeTypedValue = Now
Set oNode = oDoc.createElement("bgColor")
oRoot.appendChild oNode
Set oEle = oNode
' Use DataType so MSXML will validate the data type
oEle.dataType = "bin.hex"
oEle.Text = &HFFCCCC
Set oNode = oDoc.createElement("Data")
oRoot.appendChild oNode
Set oEle = oNode
' Use DataType so MSXML will validate the data type
oEle.dataType = "bin.base64"
' Read in the data
oEle.nodeTypedValue = ReadBinData(DOCINPATH)
' Save xml file
oDoc.save XMLOUTPATH
MsgBox XMLOUTPATH & " is created for you."
End Sub
Function ReadBinData(ByVal strFileName As String) As Variant
Dim lLen As Long
Dim iFile As Integer
Dim arrBytes() As Byte
Dim lCount As Long
Dim strOut As String
'Read from disk
iFile = FreeFile()
Open strFileName For Binary Access Read As iFile
lLen = FileLen(strFileName)
ReDim arrBytes(lLen - 1)
Get iFile, , arrBytes
Close iFile
ReadBinData = arrBytes
End Function
Private Sub WriteBinData(ByVal strFileName As String)
Dim iFile As Integer
Dim arrBuffer() As Byte
Dim oNode As IXMLDOMNode
If Not (oDoc Is Nothing) Then
' Get the data
Set oNode = oDoc.documentElement.selectSingleNode("/Root/Data")
' Make sure you use a byte array instead of variant
arrBuffer = oNode.nodeTypedValue
' Write to disk
iFile = FreeFile()
Open strFileName For Binary Access Write As iFile
Put iFile, , arrBuffer
Close iFile
End If
End Sub
Private Sub cmdGetBinary_Click()
DOCOUTPATH = App.Path & "/DocOutput.doc"
Set oDoc = New DOMDocument
If oDoc.Load(XMLOUTPATH) = True Then
' Save the Doc as another file
WriteBinData DOCOUTPATH
MsgBox DOCOUTPATH & " is created for you."
Else
MsgBox oDoc.parseError.reason
End If
End Sub
Private Sub Form_Unload(Cancel As Integer)
ReleaseObjects
End Sub
Private Sub ReleaseObjects()
Set oDoc = Nothing
End Sub
4. 建立word文档DocInput.doc.
5. 保存文档在工程目录下
6. 运行程序点击cmdCreateXML 按钮.一个 XML 文件XmlOuput.xml 就建立了.
点击 cmdGetBinary 按钮就可以生成word文档 DocOutput.doc.
按照上面的方法,同样可以将任意的二进制数据存为xml,然后再重新生成二进制数据
可以用于web传输等等可以使用xmlhttp的地方
- 用VB将WORD文档(或其他的二进制数据)生成xml文件并互相转换
- 用VB将WORD文档(或其他的二进制数据)生成xml文件并互相转换
- 用VB将WORD文档(或其他的二进制数据)生成xml文件并互相转换
- 用VB将WORD文档(或其他的二进制数据)生成xml文件并互相转换
- 用VB将WORD文档(或其他的二进制数据)生成xml文件并互相转换
- [C#]用C#动态生成Word文档并将数据填入Word表格中
- [C#]用C#动态生成Word文档并将数据填入Word表格中(续)
- 用C#动态生成Word文档并将数据填入Word表格中
- [C#]用C#动态生成Word文档并将数据填入Word表格中
- 用C#动态生成Word文档并将数据填入Word表格中
- 用C#动态生成Word文档并将数据填入Word表格中
- 在vs2005.net中,用C#如何将xml文件转换成二进制数据存入数据库字段,并从数据库提取该字段转换成xml文件?
- 用C#实现动态生成Word文档,在Word文档中插入表格,并将读出的数据填入到表格中
- c# word文档与二进制数据的相互转换
- c# word文档与二进制数据的相互转换
- 将上传文件以二进制形式存入数据库中,并下载数据库中的二进制数据生成对应的文件
- 将二进制数据嵌入 XML 文档的三种方法
- 将二进制数据嵌入 XML 文档的三种方法
- 《深入Spring2》第五章“AOP及在Spring中的应用”的电子版出来了
- 开源可视化 Python 性能调优工具 VPT 发布
- 程序员的灯下黑:能认识自己吗?
- 项目管理手记(七)--DRP系统的文化输出与营销
- 《给初学者的Windows Vista的补遗手册》之053
- 用VB将WORD文档(或其他的二进制数据)生成xml文件并互相转换
- 管理者的两难:公平和效率的博弈
- 中小企业信息化:坐公车还是买车
- 《给初学者的Windows Vista的补遗手册》之052
- CSDN Windows专区9X版版主测试题目
- 在Spring2中使用引介
- 游戏人工智能演示(1)追逐
- ITIL提升中国电信运维管理系统建设
- 远程注册表访问