MapX中access表图形化为mapinfo表的两种途径
来源:互联网 发布:巴以问题的由来知乎 编辑:程序博客网 时间:2024/04/29 06:16
1.bindlayerXY方式绑定。
指定bindlayer.filespec就可以创建永久表,不指定则为临时表。
Private Sub Command4_Click()
'只能创建一个字段,GeoName,来源于City字段。当City字段不能唯一是,state字段用于限定。
'不能创建索引
Dim BindlayerObject As New MapXlib.BindLayer
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim ds As MapXlib.Dataset
Set db = DBEngine.WorkSpaces(0).Opendatabase("C:Program FilesmapinfoMapX 4.0DataMapstats.mdb")
Set rs = db.OpenRecordset("US_Cust")
BindlayerObject.LayerName = "新图层名"
BindlayerObject.Filespec = App.Path + "mytab.tab" '若不指定,则为临时表
BindlayerObject.RefColumn1 = "X"
BindlayerObject.RefColumn2 = "Y"
BindlayerObject.LayerType = miBindLayerTypeXY
Set ds = Map1.Datasets.Add(miDataSetDAO, rs, "数据集名", "City", "State", BindlayerObject)
End Sub
2.layerInfo新建表
layers.add lyrinfo创建好一个有完备字段的空表
ds.rowvalues,
lyr.addfeature ftr,rvs填入图元和属性
Private Sub Command1_Click()
'可以创建多个字段
'MapX5中可以创建索引,MapX4中不可以
Dim rs As DAO.Recordset
Dim db As DAO.Database
Dim flds As New MapXLib.Fields
Dim lyrNew As MapXLib.Layer
Dim ptNew As New MapXLib.Point
Dim ftrNew As MapXLib.Feature
Dim ff As MapXLib.FeatureFactory
Dim li As New MapXLib.LayerInfo
Dim rvs As New MapXLib.Rowvalues
Dim ds As MapXLib.Dataset
Set db = DBEngine.OpenDatabase("C:Program FilesmapinfoMapX 4.0datamapstats.mdb")
Set rs = db.OpenRecordset("US_Cust")
Set ff = Map1.FeatureFactory
flds.AddStringField "Company", 50 ,true 'MapX5中可以创建索引,
'flds.AddStringField "Company", 50 'MapX4中不可以创建索引,
flds.AddStringField "City", 50
flds.AddStringField "State", 2
flds.AddNumericField "Order_Amt", 12, 2
li.Type = miLayerInfoTypeNewTable
li.AddParameter "FileSpec", App.Path & "custtab.tab"
li.AddParameter "Name", "mycustomers"
li.AddParameter "Fields", flds
Map1.Layers.Add li, 1
'到此为止,已经用access表建好mapinfo表,也设置好了字段,但是没有图元在上面,也没有记录。
'下面从access表中x,y创建点图元,同时把其属性数据也添加进去
'--------------------------------------------------------------------
Set lyrNew = Map1.Layers(1)
Set ds = Map1.Datasets.Add(miDataSetLayer, lyrNew)
Set rvs = ds.Rowvalues(0)
rs.MoveFirst
Do While Not rs.EOF
rvs.Item("Company").value = rs.Fields("Company") 'rvs.Item("Company")可写为rvs("Company")
rvs.Item("City").value = rs.Fields("City")
rvs.Item("State").value = rs.Fields("State")
rvs.Item("Order_Amt").value = rs.Fields("Order_Amt")
ptNew.Set rs.Fields("X"), rs.Fields("Y")
Set ftrNew = ff.CreateSymbol(ptNew)
Set ftrNew = lyrNew.AddFeature(ftrNew, rvs) ' 图元+属性,即feature+Rowvalues
'Set ftrNew = lyrNew.AddFeature(ftrNew)
'ftrNew.Update True, rvs
rs.MoveNext
Loop
Set rs = Nothing
Set db = Nothing
End Sub
==================MapX专家论坛(www.51gis.com)===================
- MapX中access表图形化为mapinfo表的两种途径
- MapX中access表图形化为mapinfo表的两种途径
- MapX中access表图形化为mapinfo表的两种途径
- 3S基础知识:MapX中access表图形化为mapinfo表的两种途径
- Mapinfo Mapx Mobile
- 3S基础知识:MapInfo MapX中如何保存专题地图
- mapinfo 的WOR文件转换成mapx的GST文件
- java产生随机数的两种途径
- android 创建快捷方式的两种途径
- Struts2访问ServletAPI的两种途径
- 获得临时文件的两种途径
- VC++通过MapX调用MapInfo
- Linux下远程图形化管理的几种途径
- Linux操作系统远程图形化管理的几种途径
- 【strike Fish】构筑Render的两种途径的思考
- 我是如何学习用C#和MapInfo,MapX制作GIS系统软件的
- Asp.net生成htm静态文件的两种途径
- Asp.net生成htm静态文件的两种途径
- 利用PHP代码实现网页自动判断转向
- 获取webbrowser控件 网页的源码(收藏)
- 如何用PHP脚本和PEAR类创建ZIP档案文件
- 手机短信收发
- 在线管理PHP网站文件
- MapX中access表图形化为mapinfo表的两种途径
- 如何快速导出数据库为EXCEL文档(另一种方法)
- 窗体控件大小随窗体大小变化而变化
- 关于天文数字十进制与十六进制间的转换
- 将查询结果导出到Excel的另一个方法
- 如何获得对窗体移动事件的处理的一个方法
- 利用EXCEL 实现字符串的计算
- 利用API 实现字符串表达式的计算
- Outlook Add-in(COM加载项)技术指南(一)