DCOM当中保证异步作业不因远端COM客户断开而中止的解决方案(Delphi)

问题起源：最近开发了一个DCOM服务器，内部有个队列任务。客户端可以连接调用以添加任务到队列。现在有个问题是当客户端调用完断开连接后，DCOM服务器的队列任务还没执行完毕DCOM就退出了。请问有什么办法可以让队列执行完才退出呢？

简单的解决方案演示：演示是通过增加一个方法Method1，被用户调用后，记下自己当前的ThreadID(GetCurrentThradId获得)，然后调用_Addref增加引用计数。
启动一个线程，在线程当中只做一个事，等待15秒，线程置为FreeOnTerminate，并且OnTerminated事件置过程放在COM对象当中，事件发生时（线程是主线程），调用_Release释放引用计数。此时COM的处理线程会在等待消息，所以不会去释放对象，但是此时可以PostThreadMessage(ThreadID,0,0)唤醒线程，线程就会检查计数，(而此时计数正好为0)并释放对象。

1. unit Unit4;
3. {$WARN SYMBOL_PLATFORM OFF}
5. interface
7. uses
8.   Windows, Messages, SysUtils, Classes, ComServ, ComObj, VCLCom, DataBkr,
9.   DBClient, Project2_TLB, StdVcl;
11. type
12.   Tcc = class(TRemoteDataModule, Icc)
13.   private
14.     { Private declarations }
15.     ThrdID: DWORD;
16.     procedure OnThradTerminated(Sender: TObject);
17.   protected
18.     class procedure UpdateRegistry(Register: Boolean; const ClassID, ProgID: string); override;
19.     procedure Method1; safecall;
20.   public
21.     { Public declarations }
22.   end;
24.   //一个定时器线程
25.   TMyThread = Class(TThread)
26.     protected
27.       procedure Execute;override;
28.   End;
29. implementation
31. {$R *.DFM}
33. procedure TMyThread.Execute;
34. var
35.   I: Integer;
36. begin
37.   I := 15000;//15秒
38.   while I>0 do begin
39.     Sleep(15);
40.     Dec(I,15);
41.   end;
43. end;
44. class procedure Tcc.UpdateRegistry(Register: Boolean; const ClassID, ProgID: string);
45. begin
46.   if Register then
47.   begin
48.     inherited UpdateRegistry(Register, ClassID, ProgID);
49.     EnableSocketTransport(ClassID);
50.     EnableWebTransport(ClassID);
51.   end else
52.   begin
53.     DisableSocketTransport(ClassID);
54.     DisableWebTransport(ClassID);
55.     inherited UpdateRegistry(Register, ClassID, ProgID);
56.   end;
57. end;
59. procedure Tcc.Method1;
60. var
61.   Thd: TMyThread;
62. begin
63.   //添加引用计数
64.   _AddRef;
65.   //取得当前线程的ID，以方便释放时唤醒
66.   ThrdID := GetCurrentThreadId;
67.   //创建一个线程用于15秒后释放计数，以模拟线程异步操作
68.   Thd := TMyThread.Create(True);
69.   //置线程线程事件过程,以执行释放计数的过程代码
70.   Thd.OnTerminate := OnThradTerminated;
71.   //线程自动销毁
72.   Thd.FreeOnTerminate := True;
73.   //唤醒线程
74.   Thd.Resume;
75. end;
77. procedure Tcc.OnThradTerminated(Sender: TObject);
78. begin
79.   //线程结束,表示异步任务完成，释放计数
80.   _Release;
81.   //唤醒COM线程
82.   PostThreadMessage(ThrdID,0,0,0);
83. end;
85. initialization
86.   TComponentFactory.Create(ComServer, Tcc,
87.     Class_cc, ciMultiInstance, tmApartment);
88. end.