DFM文件与标准文本文件转换

 　　在Delphi可视化设计环境中，允许程序员在代码编辑器中以文本的方式浏览和修改DFM文件内容。当用File/Open命令直接打开DFM文件或者选择窗体设计窗口的弹出式菜单上的View   as  Text命令时，就会在编辑器中出现文本形式的信息。在一些资料中将这种文本形式称之为窗体设计脚本。Delphi提供的这种脚本编辑功能是对Delphi可视化设计的一大补充。当然这个脚本编辑能力是有限制的，比方说不能在脚本任意地添加和删除部件，因为代码和DFM脚本是紧密相连的，任意添加和修改会导致不一致性。但在动态生成的DFM文件中，就不存在这一限制。  
 　　实际上，DFM文件内容是二进制数据，它的脚本是经过Delphi开发环境自动转化的，而且Delphi  VCL中的Classes库单元提供了在二进制流中的文件DFM和它的脚本之相互转化的过程。它们是ObjectBinaryToText和ObjectTextToBinary、ObjectResourceToText和ObjectTextToResource。  
  　　ObjectBinaryToText过程将二进制流中存储的部件转化为基于文本的表现形式，这样就可以用文本处理函数进行处理，还可以用文本编辑器进行查找和替代操作，最后可以将文本再转化成二进制流中的部件。  
 　　ObjectTextToBinary过程执行的功能与ObjectBinaryToText相反，将TXT文件转换为二进制流中的部件，而且只要TXT文件内容的书写符合DFM脚本语法，ObjectTextToBinary可将任何程序生成的TXT文件转换为部件，这一功能也为DFM文件的动态生成和编辑奠定了基础。  
  　　DFM文件与DFM脚本语言之间相互转换的任务由ObjectResourceToText和ObjectTextToResource两个过程完成。下面以我所拥有的Delphi编程资料作详细说明：  
  　　ObjectResourseToText过程比较简单，如下：

 

   function   ComponentToString(Component:   TComponent):   string;
  var
      BinStream:   TMemoryStream;
      StrStream:   TStringStream;
      s:   string;
  begin
      BinStream   :=   TMemoryStream.Create;
      try
          StrStream   :=   TStringStream.Create(s);
          try
              BinStream.WriteComponent(Component);
              BinStream.Seek(0,   soFromBeginning);
              ObjectBinaryToText(BinStream,   StrStream);
              StrStream.Seek(0,   soFromBeginning);
              Result   :=   StrStream.DataString;
          finally
              StrStream.Free;
          end;
      finally
          BinStream.Free
      end;
  end;   {   ComponentToString   }

  function   StringToComponent(Value:   string;   Instance:   TComponent):   TComponent;
  var
      StrStream:   TStringStream;
      BinStream:   TMemoryStream;
  begin
      StrStream   :=   TStringStream.Create(Value);
      try
          BinStream   :=   TMemoryStream.Create;
          try
              ObjectTextToBinary(StrStream,   BinStream);
              BinStream.Seek(0,   soFromBeginning);
              Result   :=   BinStream.ReadComponent(Instance);
          finally
              BinStream.Free;
          end;
      finally
          StrStream.Free;
      end;
  end;   {   StringToComponent   }