TStringList的方法与属性

//TStringList 常用方法与属性:
var
  strList: TStringList;
  i: Integer;
begin
  strList := TStringList.Create;
  strList.Add('Strings1');           {添加}
  strList.Add('Strings2');
  strList.Exchange(0,1);             {置换}
  strList.Insert(0,'Strings3');      {插入}
  i := strList.IndexOf('Strings1');  {第一次出现的位置}
  strList.Sort;                      {排序}
  strList.Sorted := True;   {指定排序}
  strList.Count;                     {总数}
  strList.Text;                      {文本集合}
  strList.Delete(0);                 {删除, 0是第一个数据}
  strList.LoadFromFile('c:/tmp.txt');   {打开}
  strList.SaveToFile('c:/tmp.txt');  {保存}
  strList.Clear;                     {清空}
  strList.Free;                      {释放}
end;

//--------------------------------------------------------------------------------

//读入字符串
var
  strList: TStringList;
begin
  strList := TStringList.Create;
  strList.CommaText := 'aaa,bbb,ccc,ddd';
//相当于: strList.Text := 'aaa' + #13#10 + 'bbb' + #13#10' + 'ccc' + '#13#10' + 'ddd';

  ShowMessage(IntToStr(strList.Count)); //4
  ShowMessage(strList[0]); //aaa

  strList.Free;
end;

//--------------------------------------------------------------------------------

//置换分隔符
var
  strList: TStringList;
begin
  strList := TStringList.Create;
  strList.Delimiter := '|';
  strList.DelimitedText := 'aaa|bbb|ccc|ddd';

  ShowMessage(IntToStr(strList.Count));  //4
  ShowMessage(strList[0]);  //aaa

  strList.Free;
end;

//--------------------------------------------------------------------------------

//类似的哈希表操作法
var
  strList: TStringList;
begin
  strList := TStringList.Create;

  strList.Add('aaa=111');
  strList.Add('bbb=222');
  strList.Add('ccc=333');
  strList.Add('ddd=444');

  ShowMessage(strList.Names[1]);  //bbb
  ShowMessage(strList.ValueFromIndex[1]);  //222
  ShowMessage(strList.Values['bbb']);  //222

//ValueFromIndex 可以赋值:
  strList.ValueFromIndex[1] := '2';
  ShowMessage(strList[1]); //bbb=2

//可以通过 Values 赋值:
  strList.Values['bbb'] := '22';
  ShowMessage(strList[1]); //bbb=22

  strList.Free;
end;
//避免重复值
var
  strList: TStringList;
begin
  strList := TStringList.Create;

  strList.Add('aaa');

  strList.Sorted := True; //需要先指定排序
  strList.Duplicates := dupIgnore; //如有重复值则放弃

  strList.Add('aaa');

  ShowMessage(strList.Text); //aaa

//Duplicates 有3个可选值:
//dupIgnore: 放弃;
//dupAccept: 结束;
//dupError: 提示错误.

  strList.Free;
end;

//--------------------------------------------------------------------------------

//排序与倒排序
{排序函数}
function DescCompareStrings(strList: TStringList; Index1, Index2: Integer): Integer;
begin
  Result := -AnsiCompareText(strList[Index1], strList[Index2]);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  strList: TStringList;
begin
  strList := TStringList.Create;

  strList.Add('bbb');
  strList.Add('ccc');
  strList.Add('aaa');

//未排序
  ShowMessage(strList.Text);  //bbb ccc aaa

//排序
  strList.Sort;
  ShowMessage(strList.Text);  //aaa bbb ccc

//倒排序
  strList.CustomSort(DescCompareStrings); //调用排序函数
  ShowMessage(strList.Text);  //ccc bbb aaa

//假如:
  strList.Sorted := True;
  strList.Add('999');
  strList.Add('000');
  strList.Add('zzz');
  ShowMessage(strList.Text);  //000 999 aaa bbb ccc zzz
end;

    很多时候，可以用TSTringList来处理文本文档。在delphi中可以用Memo控件处理文本文档，用的就是TSTringList类，在处理文本文档时也可以直接声明TSTringList类对象，然后用LoadFromFile方法将文本文件中的内容取出来，相当于放进一个字符串数组，文本的每一行相当于是一个字符串，接下来可以利用一些字符串操作函数来对文本进行操作。最后用SaveToFile函数保存到文本文件中去。在这些操作中用的多的还有Pos函数，Trim函数等等。