PB开发笔记(七)[转]

//小写金额转换成大写金额
string CN_NUM[10] = {"零","壹","贰","叁","肆","伍","陆","柒","捌","玖"}//大写0-9
string CN_CARRY[19] = {"分","角","","元","拾","佰","仟","万","拾","佰","仟","亿","拾","佰","仟","万","拾","佰","仟"}
string ls_pos,ls_number,ls_rc
integer li_for,li_len
Boolean lb_zero = FALSE        //是否允许下一位出现零
ls_number = string(number,"0.00")
li_len = Len(ls_number)
FOR li_for = 1 TO li_len
ls_pos = MID(ls_number,li_for,1)
IF ls_pos = "-" THEN
      ls_rc += "负"
      continue
END IF
IF ls_pos ='.' THEN continue
IF ls_pos <> "0" THEN
      ls_rc += CN_NUM[integer(ls_pos) + 1] + CN_CARRY[li_len - li_for + 1]
ELSEIF MOD(li_len - li_for - 3,4) = 0 THEN
      IF Right(ls_rc,2) = CN_NUM[1] THEN ls_rc = Left(ls_rc,Len(ls_rc) - 2)
      ls_rc += CN_CARRY[li_len - li_for + 1] + CN_NUM[integer(ls_pos) + 1]
ELSEIF lb_zero THEN
      ls_rc += CN_NUM[integer(ls_pos) + 1]
END IF
lb_zero = ls_pos <> "0"
NEXT
IF Right(ls_rc,2) = CN_NUM[1] THEN ls_rc = Left(ls_rc,Len(ls_rc) - 2)
RETURN ls_rc

//Pb中定制打印页长
在使用连续纸打印数据窗口的情况下，需要定制打印的页长，以保证打印机走纸正确，不用人工干预，
实现连续打印。在PB中须调用外部函数来自定义纸张长度，比较繁琐。本文介绍一种直接对打印机的
控制方法，简单实现对页长的设定。
一、 预备知识
计算机与打印机的通讯使用ASCII码进行，其中标准ASCII码包括可打印字符及非打印字符（控制码），
打印机使用控制码来定制打印机。大多数打印机指令使用控制码escape作为其指令序列的第一个序列码。
下面介绍本文用到的几个指令码序列：
设置换行量（行距）1/8 英寸
ASCII码 ESC 0
十进制码 27 48
设置以行为单位的页长
ASCII码 ESC C n
十进制码 27 67 n
其中n 为每页行数范围（1-127）
二、 PB中控制码的传送及定制页长的实现
在PB中通过函数Printsend(printjobnumber,string,{zerochar})来实现向打印机发送控制码。
各参数定义如下：
printjobnumber: 由printjob()函数返回的打印作业号；
string:           控制字符串，使用ASCII码；
zerochar:         用来替代string中的数字0；
由于字符串中，0终止字符串，如果string中包含0，则需利用其他字符来表示0，参数zerochar即为此
用途而设，当PB发送控制字符串给打印机时，把替代的字符zerochar转化为0。
下面是具体的完成定制页长打印数据窗口的程序（定制页长为2.75英寸）：
long ll_job
dw_print.reset()
ll_job = printopen()
if ll_job = -1 then
          messagebox(gs_title,"打印机未准备好")
          return
end if
//定制行距1/8英寸
PrintSend(ll_job, CHAR(27)+CHAR(48))
//设定页长22行
PrintSend(ll_job, CHAR(27)+CHAR(67)+CHAR(22))
printdatawindow(ll_job,dw_print)
printclose(ll_job)
22行刚好是窄行连续纸一页的三分之一长,好多票据都是这种纸.win2000下没问题,我的程序跑得很好.

//pb中的一些经验和技巧
1.RGB函数计算公式: 颜色值 ＝ (65536 * Blue) + (256 * Green) + (Red)
2.控件可拖动：send(handle(this),274,61458,0)
3.如何用程序控制下拉子数据窗口的下拉和收起
用modify或者直接用dw_1.object.col1.dddw.showlist = true
4.检索参数有些不需要传入则传%.
5.如何屏蔽鼠标滚轮触发在控件的other事件写
if message.number = 522 then return 1
6.得到数据窗口的语法：
string ls_dwsyntax
ls_dwsyntax=dw_1.describe("datawindow.syntax")
7.得到数据窗口中各列及标题：
long     ll_count,i
string ls_value,ls_colname
ll_colnum = Long(dw_1.object.datawindow.column.count)
for i = 1 to ll_colnum
     //得到标题头的名字
     ls_colname = dw_1.describe('#' + string(i) + ".name") + "_t"
     ls_value = dw_1.describe(ls_colname + ".text")
next
8.在程序中动态设置初始值:
ex:dw_control.object.columnName.initial = 'xxxx'
9.如何在DataWindow的SQL语法中不使用SELECT DISTINCT实现删除重复的行:
起先对你要显示唯一值的列进行排序："city A"，然后增加如下过滤字符串：
" city < > city [-1] or GetRow () = 1"
10.如何改变列的字体颜色，提醒用户此列已做修改:
在列的Color属性中，输入如下表达式
IF (column_name < >column_name.Original, RGB(255, 0, 0), RGB(0, 0, 0))。
在这个条件中，如果此列已改变，则显示红色字体，否则显示黑色字体。这个表达式主要用
column_name < > column_name.Original比较当前列的值和原始列的值是否相同来达到判断的目的。
11.在数据窗口的clicked或doubleclicked事件中写上注释//可解决一些意外的bug!

//数据窗口中实现字段的组合
现在假设客户的省份，城市，地址，邮编分别存放在不同的字段中，它们是Province，City，Address，
PC。我们要得到“邮编+省份+城市+地址”的格式，如：“（214001）江苏省无锡市人民路1号。"，具体实现
如下：
　　1、在需要显示的位置添加一个计算域（Compute Field）
　　2、在它的表达式栏中写上“ '（' + PC + ' ）' + Province + City + Address ”
　　3、单击确定完成。
　　很容易是不是。需要提醒大家的是，计算域只能用来显示，不能对它进行修改，因为它没有TAB属性，
不能得到焦点。

//数据窗口的自动刷新技术
在我们编写诸如像库存，销售等应用系统时，总希望程序能动态的自动刷新库存量或销售量，比如说
每隔1秒刷新一次。要实现这样的功能只要我们利用数据窗口的时间间隔属性（Timer Interval），
当该值为0时数据窗口不进行刷新，如果要使数据窗口以每一秒钟的频率刷新的话，只要将该值设为
1000，即1000毫秒。
我们还可以为应用程序添加闪烁报警的功能。就拿库存量来说吧，最常用的是当某货物的库存量达到
一个最低库存量时程序应能自动判别，并用警告色显示，通常是红色。此时，我们只要在运用了上述的
方法后再在需要闪烁的字段上，比如，库存量，在它的颜色属性中写上相应的语句。下面这段代码实现
“当某一物品的库存量小于20的时候，程序以红色闪烁显示警告”
　　if ( Store_Num < 20, &
　　if mod( Second(Now()), 2) <> 0, & // 每秒一次，偶数显示红色，奇数显示白色，即底色
　　RGB(255, 255, 255), RGB(255, 0, 0) )

//如何在DataWindow中用数据类型为Datetime的列为条件进行查找
1．当要查找的日期条件是一常数时使用如下表达式：
ls_Find = "datetime_col = DateTime ('1/1/1999')"
2．当要查找的日期条件是一个变量时使用如下的表达式：
ls_Find = "datetime_col = DateTime ('" + ls_Date + "')"
3．当要查找的日期条件是一个DateTime数据类型时使用如下表达式：
ls_Find = "datetime_col = DateTime ('" + String (ldt_DateTime) + "')"

//如何在DataWindow的SQL语法中不使用SELECT DISTINCT实现删除重复的行
起先对你要显示唯一值的列进行排序："city A"，然后增加如下过滤字符串：
" city < > city [-1] or GetRow () = 1"

//如何在分组形式的DataWindow中分别显示各组的行号
当我们为Datawindow的每一行显示行号时，可以简单的放一个表达式为GetRow()计算列。
但是对于分组的Datawindow，要分别显示各组的行号，则应使用表达式为
GetRow() - First(GetRow() for Group 1) + 1的计算列。

//如何改变列的字体颜色，提醒用户此列已做修改
在列的Color属性中，输入如下表达式
IF (column_name < >column_name.Original, RGB(255, 0, 0), RGB(0, 0, 0))。
在这个条件中，如果此列已改变，则显示红色字体，否则显示黑色字体。这个表达式主要用
column_name < > column_name.Original比较当前列的值和原始列的值是否相同来达到判断的目的。

//在数据窗口中移走行,但不是去做过滤或删除操作
RowsDiscard()函数可做到这一点,它在数据窗口中执行移除工作,但被移走的行它不可被删除或做任何
修改性的保存。

//如何在多行显示的DataWindow 中的Footer Band中显示当前数据的首行和最后行的行号
我们先看两个计算列的表达式：
IF (GetRow() = First(GetRow() FOR Page), 1, 0) // 1 为当前页的第一行
IF (GetRow() <> 1 AND GetRow() = Last(GetRow() FOR Page), 1, 0) // 1 为当前页的最后一行
由上面可知，在Footer Band中设置如下计算列表达式：
'Rows ' + String(First(GetRow() FOR Page)) + ' to ' + String(Last(GetRow() FOR Page)) + ' are displayed'。
即可达到这项功能。

//窗口居中:
function long shCenterWindow(long hwnd) library "Pbvm60.dll"

//用IE打开指定网页:
function long shRunDefltBrower(string sellrl) library "Pbvm60.dll"

//如何取得数据窗口计算域的值!
em_data.text=dw_1.getdatavalue(compute_1)是不行的，应该如何写呢？
答案:取个名字，然后就象字段取值一样！在name属性里命名为compute_1
em_date.Text = dw_1.Object.compute_1[dw_1.GetRow()]

//PB6.5中grid风格的数据窗口如何自动折行
1、在DataWindow Painter中打开DataWindow;
2、在需设定自动折行的列上双击鼠标, 弹开此列的属性窗口；
3、 选择Position标签, 选中Autosize Height 多选框；
4、 选择Edit标签, 不选中Auto Horz Scroll多选框；
5、 单击OK按钮, 保存所做的修改；
6、 点中Detail Band (即写有Detail的灰色长带), 单击鼠标右键, 选择Properties... 菜单项；
7、 选中Autosize Height多选框；
8、 单击OK按钮, 保存所做的修改；
9、 保存DataWindow。
還在列的Height屬性寫表達式:
if(len(trim( file_name ))/18 > 1,ceiling(len(trim(file_name))/18)*24,18)多少個字符就折行

//【１２个用一条语句写成的有关日期函数】
可以直接赋值给变量，不用写成函数形式的。另函数适用于pb6.5，一个汉字占两个字节，如果用于
pb8.0以上请根据实际情况修改
//1.生肖(年份参数：int ls_year    返回参数：string):
mid(fill('鼠牛虎兔龙蛇马羊猴鸡狗猪',48),(mod(ls_year -1900,12)+13)*2 -1,2)
//2.天干地支(年份参数：int ls_year    返回参数：string):
mid(fill('甲乙丙丁戊己庚辛壬癸',40),(mod(ls_year -1924,10)+11)*2 -1,2)+mid(fill('子丑寅卯辰巳午未申酉戌亥',48),(mod(ls_year -1924,12)+13)*2 -1,2)
//3.星座(日期参数：date ls_date    返回参数：string):
mid("摩羯水瓶双鱼白羊金牛双子巨蟹狮子处女天秤天蝎射手摩羯",(month(ls_date)+sign(sign(day(ls_date) -(19+integer(mid('102123444423',month(ls_date),1))))+1))*4 -3,4)+'座'
//4.判断闰年(年份参数：int ls_year    返回参数：int 0=平年，1=闰年):
abs(sign(mod(sign(mod(abs(ls_year),4))+sign(mod(abs(ls_year),100))+sign(mod(abs(ls_year),400)),2)) -1)
//5.某月天数(日期参数：date ls_date    返回参数：int):
integer(28+integer(mid('3'+string(abs(sign(mod(sign(mod(abs(year(ls_date)),4))+sign(mod(abs(year(ls_date)),100))+sign(mod(abs(year(ls_date)),400)),2)) -1))+'3232332323',month(ls_date),1)))
//6.某月最后一天日期(日期参数：date ls_date    返回参数：date):
date(year(ls_date),month(ls_date),integer(28+integer(mid('3'+string(abs(sign(mod(sign(mod(abs(year(ls_date)),4))+sign(mod(abs(year(ls_date)),100))+sign(mod(abs(year(ls_date)),400)),2)) -1))+'3232332323',month(ls_date),1))))
//7.另一个求某月最后一天日期(日期参数：date ls_date    返回参数：date):
a.RelativeDate (date(year(ls_date)+sign(month(ls_date) -12)+1,mod(month(ls_date)+1,13)+abs(sign(mod(month(ls_date)+1,13)) -1),1),-1)
b.RelativeDate(date(year(ls_date)+integer(month(ls_date)/12),mod(month(ls_date),12)+1,1),-1)
//8.另一个求某月天数(日期参数：date ls_date    返回参数：int):
a.day(RelativeDate (date(year(ls_date)+sign(month(ls_date) -12)+1,mod(month(ls_date)+1,13)+abs(sign(mod(month(ls_date)+1,13)) -1),1),-1))
b.day(RelativeDate(date(year(ls_date)+integer(month(ls_date)/12),mod(month(ls_date),12)+1,1),-1))
//9.某月某日星期几--同ＰＢ系统函数DayName(日期参数：date ls_date    返回参数：string):
'星期'+mid('日一二三四五六',(mod(year(ls_date) -1 + int((year(ls_date) -1)/4) - int((year(ls_date) -1)/100) + int((year(ls_date) -1)/400) + daysafter(date(year(ls_date),1,1),ls_date)+1,7)+1)*2 -1,2)
//10.求相隔若干月份后的相对日期(日期参数：date ls_date 相隔月份(可取负数)：int ls_add_month 返回参数：date):
date(year(ls_date)+int((month(ls_date)+ls_add_month)/13),long(mid(fill('010203040506070809101112',48),(mod(month(ls_date)+ls_add_month -1,12)+13)*2 -1,2)),day(ls_date) -integer(right(left(string(day(RelativeDate (date(year(ls_date)+int((month(ls_date)+ls_add_month)/13)+sign(long(mid(fill('010203040506070809101112',48),(mod(month(ls_date)+ls_add_month -1,12)+13)*2 -1,2)) -12)+1,mod(long(mid(fill('010203040506070809101112',48),(mod(month(ls_date)+ls_add_month -1,12)+13)*2 -1,2))+1,13)+abs(sign(mod(long(mid(fill('010203040506070809101112',48),(mod(month(ls_date)+ls_add_month -1,12)+13)*2 -1,2))+1,13)) -1),1),-1)) -day(ls_date),'00')+'00000',5),3))/100)
//11.求某日在当年所处的周数(日期参数：date ls_date    返回参数：int):
//a.周始日为星期天
//a1
abs(int(-((daysafter( RelativeDate(date(year(ls_date),1,1), -mod(year(ls_date) -1 + int((year(ls_date) -1)/4) - int((year(ls_date) -1)/100) + int((year(ls_date) -1)/400) + 1,7) +1),ls_date)+1)/7)))
//a2(使用DayNumber函数)
abs(int(-((daysafter( RelativeDate(date(year(ls_date),1,1), -DayNumber(date(year(ls_date),1,1))+1),ls_date)+1)/7)))
//b.周始日为星期一
//b1
abs(int(-((daysafter( RelativeDate(date(year(ls_date),1,1), -integer(mid('6012345',mod(year(ls_date) -1 + int((year(ls_date) -1)/4) - int((year(ls_date) -1)/100) + int((year(ls_date) -1)/400) + 1,7),1))),ls_date)+1)/7)))
//b2(使用DayNumber函数)
abs(int(-((daysafter( RelativeDate(date(year(ls_date),1,1), -integer(mid('6012345',DayNumber(date(year(ls_date),1,1)),1))),ls_date)+1)/7)))
//12.求某日相对于过去某一日期所处的周数(日期参数：date ls_date_1(要求的某日),ls_date_2(过去的某日)    返回参数：int):
//注：ls_date_1>ls_date_2
//a.周始日为星期天
//a1
abs(int(-((daysafter( RelativeDate(ls_date_2, -mod(year(ls_date_2) -1 + int((year(ls_date_2) -1)/4) - int((year(ls_date_2) -1)/100) + int((year(ls_date_2) -1)/400) + daysafter(date(year(ls_date_2),1,1),ls_date_2)+ 1,7) +1),ls_date_1)+1)/7)))
//a2(使用DayNumber函数)
abs(int(-((daysafter( RelativeDate(ls_date_2, -DayNumber(ls_date_2)+1),ls_date_1)+1)/7)))
//b.周始日为星期一
//b1
abs(int(-((daysafter( RelativeDate(ls_date_2, -integer(mid('6012345',mod(year(ls_date_2) -1 + int((year(ls_date_2) -1)/4) - int((year(ls_date_2) -1)/100) + int((year(ls_date_2) -1)/400) + daysafter(date(year(ls_date_2),1,1),ls_date_2)+ 1,7) ,1))),ls_date_1)+1)/7)))
//b2(使用DayNumber函数)
abs(int(-((daysafter( RelativeDate(ls_date_2, -integer(mid('6012345',DayNumber(ls_date_2),1))),ls_date_1)+1)/7)))

//pb用纯函数实现在数据窗口中模拟资源管理器鼠标单击动作动态排序,并显示排序箭头   
//函数名:f_dwsort(datawindow fdw_dw,dwobject fdwo_dwo) return none
//说明:用于在数据窗口中模拟资源管理器鼠标单击动作动态排序,并显示排序箭头
//调用规则:在数据窗口控件clicked!中写入f_dwsort(this,dwo)
//参数:fdw_dw datawindow
//      fdwo_dwo dwobject
//返回值:无
String ls_clicked_pos,ls_col,ls_format,ls_tag
Long ll_pos
string ls_text,ls_column[]
int li_i
ls_clicked_pos = fdwo_dwo.Name
ll_pos = Pos(ls_clicked_pos,'_t')
If ll_pos >0 Then
//设置排序
ls_col = Left(ls_clicked_pos,ll_pos -1)
ls_tag = fdwo_dwo.tag
If ls_tag = ls_col + "A"    Then
fdwo_dwo.tag = ls_col + "D"
ls_format = ls_col+" A"
ELSEIF ls_tag = ls_col + "D"    Then
fdwo_dwo.tag = ls_col + "A"
ls_format = ls_col+" D"
Else
fdwo_dwo.tag = ls_col + "D"
ls_format = ls_col+" A"
End If
//设置列标题
for li_i = 1 to long(fdw_dw.object.datawindow.column.count)
ls_column[li_i] = fdw_dw.describe("#" + string(li_i) + ".Name") //得到列名
ls_text =    fdw_dw.Describe(ls_column[li_i] + "_t.text")
if right(ls_text,2)="▽" or right(ls_text,2)="△" then
ls_text = left(ls_text,len(ls_text) - 2)
end if
fdw_dw.modify(ls_column[li_i] + "_t.text='"+ls_text + "'")
next
ls_text = fdw_dw.Describe(ls_clicked_pos + ".text")
if right(ls_text,2)="▽" or right(ls_text,2)="△" then
ls_text = left(ls_text,len(ls_text) - 2)
end if
if right(ls_format,1) = 'A' then
fdw_dw.modify(ls_clicked_pos + ".text='"+ls_text + "△'")
elseif right(ls_format,1) = 'D' then
fdw_dw.modify(ls_clicked_pos + ".text='"+ls_text + "▽'")
end if
fdw_dw.SetSort(ls_format)
fdw_dw.Sort()
End If
//本程序在pb6.5下通过测试

//pb中取汉字串首字符的一个函数      zhoukan（收藏）
今天看到xuejun的一个取汉字首字符的函数，试用了一下，感觉很好用，不敢独享，拿出来跟大家分享：
$PBExportHeader$uf_getfirstletter.srf
$PBExportComments$ 返回给定汉字串的首字母串,    xuejun , 19990821
global type uf_getfirstletter from function_object
end type
forward prototypes
global function string uf_getfirstletter (string as_inputstring)
end prototypes
global function string uf_getfirstletter (string as_inputstring);//Function name    :    uf_GetFirstLetter
//Used to          :    返回给定汉字串的首字母串,即声母串
//Input Arguments:    as_InputString - string , 给定的汉字串
//Return Value     :    ls_ReturnString - String , 给定的汉字串的声母串,一律为小写
//Notice           :    1. 此方法基于汉字的国标汉字库区位编码的有效性，不符合此编码的系统此函数无效！
//                    2. 若汉字串含有非汉字字符,如图形符号或ASCII码,则这些非汉字字符将保持不变.
//Sample           :    ls_rtn =    uf_GetFirstLetter("中华人民共和国")
//                         ls_rtn will be : zhrmghg
//Scripts:
char        lc_FirstLetter[23]         //存放国标一级汉字不同读音的起始区位码对应读音
string      ls_ch                      //临时单元
string      ls_SecondSecTable          //存放所有国标二级汉字读音
string      ls_ReturnStr               //返回串
integer    li_SecPosValue[23]          //存放国标一级汉字不同读音的起始区位码
integer    i , j
integer    li_SectorCode               //汉字区码
integer    li_PositionCode             //汉字位码
integer    li_SecPosCode               //汉字区位码
integer    li_offset                   //二级字库偏移量
//Set initial value
li_SecPosValue[]={1601,1637,1833,2078,2274,2302,2433,2594,2787,3106,3212,3472,3635,3722,3730,3858,4027,4086,4390,4558,4684,4925,5249 }
lc_FirstLetter[]    = {"A", "B","C","D","E","F","G","H","J","K","L","M","N","O","P","Q","R","S","T","W","X","Y","Z"}
ls_SecondSecTable="CJWGNSPGCGNE[Y[BTYYZDXYKYGT[JNNJQMBSGZSCYJSYY[PGKBZGY[YWJKGKLJYWKPJQHY[W[DZLSGMRYPYWWCCKZNKYYGTTNJJNYKKZYTCJNMCYLQLYPYQFQRPZSLWBTGKJFYXJWZLTBNCXJJJJTXDTTSQZYCDXXHGCK[PHFFSS[YBGXLPPBYLL[HLXS[ZM[JHSOJNGHDZQYKLGJHSGQZHXQGKEZZWYSCSCJXYEYXADZPMDSSMZJZQJYZC[J[WQJBYZPXGZNZCPWHKXHQKMWFBPBYDTJZZKQHYLYGXFPTYJYYZPSZLFCHMQSHGMXXSXJ[[DCSBBQBEFSJYHXWGZKPYLQBGLDLCCTNMAYDDKSSNGYCSGXLYZAYBNPTSDKDYLHGYMYLCXPY[JNDQJWXQXFYYFJLEJPZRXCCQWQQSBNKYMGPLBMJRQCFLNYMYQMSQYRBCJTHZTQFRXQHXMJJCJLXQGJMSHZKBSWYEMYLTXFSYDSWLYCJQXSJNQBSCTYHBFTDCYZDJWYGHQFRXWCKQKXEBPTLPXJZSRMEBWHJLBJSLYYSMDXLCLQKXLHXJRZJMFQHXHWYWSBHTRXXGLHQHFNM[YKLDYXZPYLGG[MTCFPAJJZYLJTYANJGBJPLQGDZYQYAXBKYSECJSZNSLYZHSXLZCGHPXZHZNYTDSBCJKDLZAYFMYDLEBBGQYZKXGLDNDNYSKJSHDLYXBCGHXYPKDJMMZNGMMCLGWZSZXZJFZNMLZZTHCSYDBDLLSCDDNLKJYKJSYCJLKWHQASDKNHCSGANHDAASHTCPLCPQYBSDMPJLPZJOQLCDHJJYSPRCHN[NNLHLYYQYHWZPTCZGWWMZFFJQQQQYXACLBHKDJXDGMMYDJXZLLSYGXGKJRYWZWYCLZMSSJZLDBYD[FCXYHLXCHYZJQ[[QAGMNYXPFRKSSBJLYXYSYGLNSCMHZWWMNZJJLXXHCHSY[[TTXRYCYXBYHCSMXJSZNPWGPXXTAYBGAJCXLY[DCCWZOCWKCCSBNHCPDYZNFCYYTYCKXKYBSQKKYTQQXFCWCHCYKELZQBSQYJQCCLMTHSYWHMKTLKJLYCXWHEQQHTQH[PQ[QSCFYMNDMGBWHWLGSLLYSDLMLXPTHMJHWLJZYHZJXHTXJLHXRSWLWZJCBXMHZQXSDZPMGFCSGLSXYMJSHXPJXWMYQKSMYPLRTHBXFTPMHYXLCHLHLZYLXGSSSSTCLSLDCLRPBHZHXYYFHB[GDMYCNQQWLQHJJ[YWJZYEJJDHPBLQXTQKWHLCHQXAGTLXLJXMSL[HTZKZJECXJCJNMFBY[SFYWYBJZGNYSDZSQYRSLJPCLPWXSDWEJBJCBCNAYTWGMPAPCLYQPCLZXSBNMSGGFNZJJBZSFZYNDXHPLQKZCZWALSBCCJX[YZGWKYPSGXFZFCDKHJGXDLQFSGDSLQWZKXTMHSBGZMJZRGLYJBPMLMSXLZJQQHZYJCZYDJWBMYKLDDPMJEGXYHYLXHLQYQHKYCWCJMYYXNATJHYCCXZPCQLBZWWYTWBQCMLPMYRJCCCXFPZNZZLJPLXXYZTZLGDLDCKLYRZZGQTGJHHGJLJAXFGFJZSLCFDQZLCLGJDJCSNZLLJPJQDCCLCJXMYZFTSXGCGSBRZXJQQCTZHGYQTJQQLZXJYLYLBCYAMCSTYLPDJBYREGKLZYZHLYSZQLZNWCZCLLWJQJJJKDGJZOLBBZPPGLGHTGZXYGHZMYCNQSYCYHBHGXKAMTXYXNBSKYZZGJZLQJDFCJXDYGJQJJPMGWGJJJPKQSBGBMMCJSSCLPQPDXCDYYKY[CJDDYYGYWRHJRTGZNYQLDKLJSZZGZQZJGDYKSHPZMTLCPWNJAFYZDJCNMWESCYGLBTZCGMSSLLYXQSXSBSJSBBSGGHFJLYPMZJNLYYWDQSHZXTYYWHMZYHYWDBXBTLMSYYYFSXJC[DXXLHJHF[SXZQHFZMZCZTQCXZXRTTDJHNNYZQQMNQDMMG[YDXMJGDHCDYZBFFALLZTDLTFXMXQZDNGWQDBDCZJDXBZGSQQDDJCMBKZFFXMKDMDSYYSZCMLJDSYNSBRSKMKMPCKLGDBQTFZSWTFGGLYPLLJZHGJ[GYPZLTCSMCNBTJBQFKTHBYZGKPBBYMTDSSXTBNPDKLEYCJNYDDYKZDDHQHSDZSCTARLLTKZLGECLLKJLQJAQNBDKKGHPJTZQKSECSHALQFMMGJNLYJBBTMLYZXDCJPLDLPCQDHZYCBZSCZBZMSLJFLKRZJSNFRGJHXPDHYJYBZGDLQCSEZGXLBLGYXTWMABCHECMWYJYZLLJJYHLG[DJLSLYGKDZPZXJYYZLWCXSZFGWYYDLYHCLJSCMBJHBLYZLYCBLYDPDQYSXQZBYTDKYXJY[CNRJMPDJGKLCLJBCTBJDDBBLBLCZQRPPXJCJLZCSHLTOLJNMDDDLNGKAQHQHJGYKHEZNMSHRP[QQJCHGMFPRXHJGDYCHGHLYRZQLCYQJNZSQTKQJYMSZSWLCFQQQXYFGGYPTQWLMCRNFKKFSYYLQBMQAMMMYXCTPSHCPTXXZZSMPHPSHMCLMLDQFYQXSZYYDYJZZHQPDSZGLSTJBCKBXYQZJSGPSXQZQZRQTBDKYXZKHHGFLBCSMDLDGDZDBLZYYCXNNCSYBZBFGLZZXSWMSCCMQNJQSBDQSJTXXMBLTXZCLZSHZCXRQJGJYLXZFJPHYMZQQYDFQJJLZZNZJCDGZYGCTXMZYSCTLKPHTXHTLBJXJLXSCDQXCBBTJFQZFSLTJBTKQBXXJJLJCHCZDBZJDCZJDCPRNPQCJPFCZLCLZXZDMXMPHJSGZGSZZQLYLWTJPFSYASMCJBTZKYCWMYTCSJJLJCQLWZMALBXYFBPNLSFHTGJWEJJXXGLLJSTGSHJQLZFKCGNNNSZFDEQFHBSAQTGYLBXMMYGSZLDYDQMJJRGBJTKGDHGKBLQKBDMBYLXWCXYTTYBKMRTJZXQJBHLMHMJJZMQASLDCYXYQDLQCAFYWYXQHZ "
//Get it !
ls_ReturnStr = ""   
For i=1 to Len(as_InputString)                  //依次处理as_InputString中每个字符
      ls_ch=Mid(as_InputString , i , 1)     
        If Asc(ls_ch)<128    then                        //    非汉字
            ls_returnStr = ls_returnStr+ls_ch      //    不变
        Else                                                      //    是汉字
            ls_ch = Mid(as_InputString , i , 2)          // 取出此汉字
            li_SectorCode = Asc(Left(ls_ch, 1)) - 160          //区码
            li_PositionCode = Asc(Right(ls_ch, 1)) - 160    //位码
            li_SecPosCode = li_SectorCode*100 +    li_PositionCode              // 区位码
            If li_SecPosCode>1600    and    li_SecPosCode<5590    then          //    第一个字符
                For j=23 to 1 Step -1                // 找声母
                    If li_SecPosCode>=li_SecPosValue[j] then
                          ls_returnStr = ls_returnStr +    lc_FirstLetter[j]
                          Exit
                    End if
                Next
            Else                                                //    第一个字符
                li_offset = (li_SectorCode - 56 ) *94 + li_PositionCode - 1        // 计算偏移量
                If li_offset>=0    and li_offset<=3007        then                              //二区汉字
                    ls_returnStr = ls_returnStr + Mid(ls_SecondSecTable, li_offset , 1)        //取出此字声母
                End if
            End if
            i = i+1                    //      指向下一个汉字
      End if
Next                                // 处理完毕
//Return result
Return      lower( ls_returnStr )     //返回 as_InputString 的声母串
end function

//选用Grid数据窗口方式时避免表头上方也出现表格线。
用Grid数据窗口方式能够实现表格式报表输出，但是如在表头上方不加以控制或处理，它将出现
Detail Band中各数据列的表格线，这是我们所不需要的。解决问题的参考方法是：
①.可在Header Band中的表头上方增加一文本框，让该文本框足够宽且能覆盖所有的数据列， 同时将
垂直长度调整Header Band中的表头上部平齐。
②.在文本框的Properties...窗口中，将该文本框的显示内容清为空，在Font标签页中将字体的背景
颜色(Background)设置为与数据窗口的背景色相同，并在Position标签页中将其Layer(层次)修改为
Foreound，单击OK按钮，马上就能看出效果。

//如何在POWER BUILDER中使用WINSOCK控件
随着资源共享和实时通讯的需要，很多计算机应用程序早已甩开单兵作战的模式，转入联合行动。
网络在计算机世界里，越来越发挥着举足轻重的作用。在WINDOWS应用程序中，处理实时通讯最常用到
的还是MICROSOFT公司提供的WINSOCK控件。许多资料都细述了WINSOCK在VB中的使用方法，就连WINDOWS
本身提供的hlp文件也是针对VB而写的。笔者因为实际应用的需要，琢磨出了WINSOCK控件在PB中的应用
方法。好东西不敢独自享用，拿出来与大家共享。
下面以一个简单程序为例，说明WINSOCK控件在PB中的使用：
一、在窗口中添加WINSOCK控件：
在应用中新开一个窗口，在窗口画板中点击controls-->OLE菜单项，弹出Insert object窗口，单击
Insert control标签，从列表框中双击选定Microsoft Winsock control，将winsock的图标贴在窗口上。
在程序中该控件名称定为winsock_a（甲方）和winsock_b（乙方）。
二、设置信息输入输出文本框：
在窗口中增加一个按钮cb_1,两个单行文本框sle_1,sle_2，分别用于输入要发送的字符串和接受对方发送
的字符串
三、设置通讯协议：
WINSOCK控件允许用户以UDP和TCP两种协议中任选一种进行通讯。
1.UDP协议设置：UDP协议是一种无连接的通讯协议，在通讯之前，需要绑定remotehost和remoteport
属性，如果需要双向通讯，还要设置localport属性。
在甲方（本机地址为：134.1.1.1)窗口的Open事件中加入如下语句：
                  winsock_a.object.protocol=1
//winsock通讯协议设为UDP协议
                  winsock_a.object.remotehost="134.1.1.2"
//对方的ip地址
                  winsock_a.object.remoteport=6000
//对方的winsock通讯端口号
                  winsock_a.object.localport=6001
//本机的winsock通讯端口号
                  winsock_a.object.bind
//绑定通讯协议
在乙方（本机地址为：134.1.1.2)窗口的Open事件中加入如下语句：
                  winsock_b.object.protocol=1
//winsock通讯协议设为UDP协议
                  winsock_b.object.remotehost="134.1.1.1"
//对方的ip地址
                  winsock_b.object.remoteport=6001
//对方的winsock通讯端口号
                  winsock_b.object.localport=6000
//本机的winsock通讯端口号
                  winsock_b.object.bin
//绑定通讯协议
2.TCP协议设置：TCP协议在通讯前需要进行连接。
在甲方（作为服务器端）窗口的Open事件中加入如下语句：
                  winsock_a.object.protocol=0
//winsock通讯协议设为TCP协议
                  winsock_a.object.localport=6001
//本机的winsock通讯端口号
                  winsock_a.listen()
//启动监听
在甲方winsock_a控件的Connectionrequest事件中加入如下语句：
                  //接受到对方的连接请求后
                  if winsock_a.object.state<>0 then
                          winsock_a.close()
                  end if
                  winsock_a.accept(requestID)
//建立直接连接
                  //requestID是Connectionrequest事件自己的参数
在乙方（作为客户端）窗口的Open事件中加入如下语句：
                  winsock_b.object.protocol=0
//winsock通讯协议设为TCP协议
                  winsock_b.object.remotehost="134.1.1.2"
//对方的ip地址
                  winsock_b.object.remoteport=6000
//对方的winsock通讯端口号
                  winsock_b.connect()    //发出连接请求
3.无论采用哪种协议，都要在窗口的Close事件中加入如下语句：
                  if winsock_a/*或winsock_b*/.object.state<>0 then
                          winsock_a.close()
                  end if
否则可能第二次使用时发生异常问题
三、开始通讯
在按钮cb_1（caption属性设为‘发送’）的click事件中加入如下语句：
winsock_a/*或winsock_b*/.object.send (sle_1.text)
在winsock_a/*或winsock_b*/控件的dataarrival事件中加入如下语句：
//接受到对方数据后
string datastr1
winsock_a/*或winsock_b*/.object.getdata (def datastr1)
sle_2.text=datastr1    //将数据字符串显示在文本框中
以上程序实际上体现了聊天器的底层工作原理，稍加修改扩充就可以做成一个很好的聊天软件