[无聊]扫雷外挂(for win2000)
来源:互联网 发布:怎么查看淘宝买家信息 编辑:程序博客网 时间:2024/05/17 02:00
终于有时间干些无聊的事情了.于是偶打开Delphi,在Form1上摆了一个按钮,命名为Button1(汗,多标准的名字),然后输入以下代码:
unit Main;
interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;
const
BOMB_MAP_MAX_SIZE = 32 * 24;
ADDR_MAPHEIGHT = $01005A68;
ADDR_MAPWIDTH = $010056F8;
ADDR_BOMBMAP = $01005720;
type
TWinMineData = class
private
FData: PByteArray;
FWidth: Integer;
FHeight: Integer;
public
constructor Create;
destructor Destroy; override;
procedure Init(AWnd: HWND);
function GetAt(X, Y: Integer): Byte;
property Width: Integer read FWidth;
property Height: Integer read FHeight;
end;
TForm1 = class(TForm)
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
function GetBlockPoint(AWnd: HWND; X, Y: Integer): TPoint;
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.Button1Click(Sender: TObject);
var
Wnd: HWND;
Data: TWinMineData;
I, J: Integer;
Pt: TPoint;
begin
Wnd := FindWindow('扫雷', nil);
if Wnd = 0 then ShowMessage('请先启动扫雷')
else
begin
Data := TWinMineData.Create;
try
Data.Init(Wnd);
for J := 0 to Data.Height - 1 do
begin
for I := 0 to Data.Width - 1 do
begin
Pt := GetBlockPoint(Wnd, I, J);
if (Data.GetAt(I, J) and $80) <> 0 then
begin
PostMessage(Wnd, WM_RBUTTONDOWN, 0, MAKELPARAM(Pt.X, Pt.Y));
PostMessage(Wnd, WM_RBUTTONUP, 0, MAKELPARAM(Pt.X, Pt.Y));
end
else
begin
PostMessage(Wnd, WM_LBUTTONDOWN, 0, MAKELPARAM(Pt.X, Pt.Y));
PostMessage(Wnd, WM_LBUTTONUP, 0, MAKELPARAM(Pt.X, Pt.Y));
end;
end;
end;
finally
FreeAndNil(Data);
end;
end;
end;
{ TWinMineData }
constructor TWinMineData.Create;
begin
FData := AllocMem(BOMB_MAP_MAX_SIZE);
end;
destructor TWinMineData.Destroy;
begin
FreeMem(FData);
inherited;
end;
function TWinMineData.GetAt(X, Y: Integer): Byte;
begin
Result := FData[Y * 32 + (X + 1)];
end;
procedure TWinMineData.Init(AWnd: HWND);
var
ProcId: Cardinal;
HProc: HMODULE;
Readed: Cardinal;
begin
ProcId := 0;
GetWindowThreadProcessId(AWnd, ProcId);
if ProcId = 0 then raise Exception.Create('process id get failed');
HProc := OpenProcess(PROCESS_VM_READ, False, ProcId);
try
ReadProcessMemory(HProc, Pointer(ADDR_MAPWIDTH), @FWidth, 4, Readed);
ReadProcessMemory(HProc, Pointer(ADDR_MAPHEIGHT), @FHeight, 4, Readed);
ReadProcessMemory(HProc, Pointer(ADDR_BOMBMAP), FData, BOMB_MAP_MAX_SIZE, Readed);
finally
CloseHandle(HProc);
end;
end;
function TForm1.GetBlockPoint(AWnd: HWND; X, Y: Integer): TPoint;
begin
Result.X := X * 16 + 19;
Result.Y := Y * 16 + 64;
end;
end.
于是偶也当了一回达淫-___-b 惭愧惭愧~~
- [无聊]扫雷外挂(for win2000)
- [再次无聊]扫雷外挂for win2000&xp
- 扫雷外挂
- 扫雷外挂
- 扫雷山寨外挂
- "扫雷外挂" 原理篇
- 扫雷外挂制作
- 扫雷外挂程序开发
- MFC扫雷外挂的编程
- Win7 32bit 扫雷外挂
- 扫雷外挂的设计与实现
- 扫雷外挂的设计与实现
- VC编程——XP扫雷外挂
- Windows Xp 扫雷外挂(控制台版)
- 【源码备份】XP下扫雷外挂
- "扫雷外挂" 之C++ 程序篇
- Delphi外挂辅助技术入门篇、Windows扫雷程序示例
- 【我的程序】Minekiller——扫雷外挂
- fasd
- 参考:揭开IE自动弹出广告窗之谜
- EBright电子闪光系列-仓储管理系统
- ASP.NET 中 Cookie 的基本知识
- Microsoft系统课程讲座及下载
- [无聊]扫雷外挂(for win2000)
- 为什么要出国? (转)
- 网格计算借技术整合东风 渐入主流IT视野
- linux 下的多线程编程
- Web服务器开发环境下的线程安全问题
- 做一个专业的IT管理人才必备的十大能力
- 短消息发送代码
- 把VOB格式转换成其它格式的工具
- DVD转RMVB及DVD转AVI相关教程