基于S3C2440的bootloader详细分析

来源：互联网发布：sql server建表自增长编辑：程序博客网时间：2024/05/20 21:47

s3c2440的Bootloader启动第一阶段代码

1、包含头文件

GET option.inc

GET memcfg.inc

GET 2440addr.inc

注释：

汇编程序指令不能顶格写

*.inc代表头文件，汇编语言专用

GET 伪指令用于将一个源文件包含到当前的源文件中，并将被包含的源文件在当前位置进行汇编处理。可以使用 INCLUDE代替 GET。

汇编程序中常用的方法是在某源文件中定义一些宏指令，用 EQU 定义常量的符号名称，用 MAP 和FIELD 定义结构化的数据类型，然后用 GET 伪指令将这个源文件包含到其他的源文件中。GET 伪指令只能用于包含源文件，包含目标文件需要使用 INCBIN 伪指令

2、设置SDRAM自刷新

BIT_SELFREFRESH EQU (1<<22)

/*这句话的意思是：“BIT_SELFREFRESH”就是“将刷新控制寄存器的第22位置1”的意思。SDRAM:同步动态随机存储器，相当于c里面 #define BIT_SELFREFRESH (1<<22)；就是第22位置1的意思。

动态存储器（Dynamic RAM）都存在刷新问题。这里主要采用自动刷新方式。每隔一段时间向SDRAM发一条刷新命令。

EQU伪指令的作用类似于C语言中的#define.用于为一个常量定义名称

（1）ARM 有7 种模式，用户模式，快速中断模式，中断模式，管理模式，中止模式，未定义模式和系统模式（咱们这里只用了6种）；

（2）系统堆栈的初始化主要是给各个处理器模式分配堆栈空间。堆栈是为中断或程序跳转服务的，当发生中断或程序跳转时，需要将当前处理器的状态及一些参数保持在堆栈中，当中断处理完毕以后或程序执行完后返回时，再将堆栈保存的现场数据进行恢复，以保证原来的程序正确运行

/*对CPSR的后8位进行设置*/

;Pre-defined constants //预定义6中工作模式

USERMODE EQU 0x10 //用户模式 00010000

FIQMODE EQU 0x11 //快速中断模式 00010001

IRQMODE EQU 0x12 //中断模式 00010010

SVCMODE EQU 0x13 //监管模式 00010011

ABORTMODE EQU 0x17 //异常中断模式 00010111

UNDEFMODE EQU 0x1b //未定义模式 000011011

MODEMASK EQU 0x1f // 模式掩码，多出来的 000011111

NOINT EQU 0xc0 //取消中断 11000000

;The location of stacks //设置6中工作模式的堆栈的起始地址

/*定义各种模式下使用的堆栈起始地址，_STACK_BASEADDRESS是由option.inc定义的,在option.inc中定义了_STACK_BASEADDRESS EQU 0x33ff8000*/

//堆栈是为中断或程序跳转服务的，当发生中断或程序跳转时，需要将当前处理器的状态及一些参数保持在堆栈中，当中断处理完毕以后或程序执行完后返回时，再将堆栈保存的现场数据进行恢复，以保证原来的程序正确运行

//堆栈初始化及ARM工作模式切换

UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~

SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~

UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~

AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~

IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~

FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~

/*下面一段要遇到的问题提前注释如下：

1、tasm.exe是什么程序，有什么作用???

就是THUMB汇编编译文件

2、CONFIG是在哪里定义了???

CONFIG为汇编器的内置变量，内置变量有很多

如果要汇编成ARM指令则值为32，如果要汇编成THUMB指令则值为16。

3、[、]、| 的用法怎样???

"["表示"if","|"表示"else","]"表示"endif"

ARM板上电时处于ARM状态，故无论指令为ARM集还是THUMB集，都先强制成ARM集，待init.s初始化完成后，再转换；下面这一段是为了统一目前的处理工作状态和软件编译方式。

//检查在tasm.exe里是否设置了采用THUMB（16位）代码，判断是不是thumb指令

;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.

GBLL THUMBCODE

/*定义THUMBCODE全局变量（逻辑型），注意，其中，GBLL为伪指令，定义全局逻辑型变量*/

[ {CONFIG} = 16

//如果发现是用16位代码的话，表示目前使用的是tasm.exe编译，thumb 编译方式

THUMBCODE SETL {TRUE}

//把THUMBCODE设置为TURE，SETL也为伪指令，用于给一个逻辑变量赋值

CODE32 //CODE32；指示汇编编译器后面的指令为32位的ARM指令,

伪指令本身并不进行程序状态的切换.要进行状态切换,可以使用BX指令操作. （暂且把处理器设置成为ARM模式，以方便初始化）

| //否则是ARM模式

THUMBCODE SETL {FALSE}

]

这段代码的意思：说白了整个预编译段就是为了说明要ARM的当前状态和编译器的状态统一而已。这里他只是给了个标准的例子，实际大多数情况不需要啦。但是上面的config==16只说明你编译器当前使用的是TASM.EXE，但现在由于 Thumb-capable ARM processors start in ARM state（注意是MCU的状态和编译器无关），所以要使两者一致编译出来的代码才能被运行，使用CODE32 使编译器也处于ARMASM.EXE状态，CODE16/32只会影响编译器，只有BX会改变processors state，只要两者一致就好。这段代码根据是否使用了TASM.EXE设置了全局变量THUMBCODE 的值，但是由于ARM PROCESSOR处于ARM state，所以后面都要用CODE32标识指令。

// 宏定义MOV_PC_LR，作用：子程序返回

// THUMB模式和ARM模式的子程序返回的方法是不同的，所以这里判断是不//是THUMB模式。

MACRO //宏定义

MOV_PC_LR //宏名

[ THUMBCODE //判断THUMBCODE是否为真；

bx lr

//若lr最低位为1，则转入THUMB指令；若lr最低位为0，则转入ARM指令。//参考资料“常用汇编指令及汇编P27”

/*如果目标地址是THUMB指令，在ARM模式中，要用BX指令转THUMB，是跳到THUMB指令，并转换模式。lr为链接寄存器，也可以使用其他寄存器，例如RM*/

mov pc,lr

/*否则，就是目标地址是ARM模式，就直接把函数返回地址赋给PC，PC为程序计数器，作用是存放下一条要执行的指令的首地址；*/

]

MEND //宏定义结束

//宏定义MOVEQ_PC_LR，作用：带相等条件判断的子程序返回。与宏定义MOV_PC_LR类似

/*注意：这里多出来的“EQ”是指CPSR程序状态寄存器的Z是否等于1，如果等于1则执行bx或mov等指令，作用于上个宏类似。*/

MACRO //宏定义

MOVEQ_PC_LR //宏名

[ THUMBCODE

bxeq lr

moveq pc,lr

]

MEND

//宏定义结束

//下面就是开始建立中断向量表的过程

下面这个宏是用于第一次查表过程的实现中断向量的重定向,你会发现在_ISR_STARTADDRESS=0x33FF_FF00里定义的第一级中断向量表是采用型如Handle***的方式的。而在程序的ENTRY处(程序开始处)采用的是b Handler***的方式.在这里Handler***就是通过HANDLER这个宏和Handle***进立联系的. 这种方式的优点就是真正定义的向量数据在内存空间里,而不是在ENTRY处的ROM(FLASH)空间里, 这样,我们就可以在程序里灵活的改动向量的数据了.其中HANDLER是一个宏,用于查找中断处理程序的入口地址.这些地址存放在由HandleXXX指向的表项中,该表定位在RAM高端,基地址为_ISR_STARTADDRESS.假如_ISR_STARTADDRESS为 0x800000000,当IRQ中断时,根据b HandlerFIQ,先跳转，再根据^ _ISR_STARTADDRESS基地址+HandleIRQ 的偏移地址(4*6)得到的中断地址 ;0x80000000+0x00000024=0x80000024

这个宏是用于第一次查表过程的实现中断向量的重定向。那么这样做有什么优点呢？

这种方式的优点就是真正定义的向量数据放到内存空间RAM里,而不是在ENTRY（地址0x0）处的ROM(FLASH)空间里, 这样,我们就可以在程序里灵活的改动中断向量的数据了（因为ROM是只读的，而RAM为可读可写的）。

在这里HANDLER是一个宏，就负责查找中断处理程序的入口地址。这些中断入口地址存放在由HandleXXX指向的表项中，该表定位在RAM高端，它的基地址为_ISR_STARTADDRESS。

例如：_ISR_STARTADDRESS为0x800000000,当IRQ中断时,根据b HandlerFIQ,先跳转再根据_ISR_STARTADDRESS基地址+HandleIRQ的偏移地址(4*6)得到的中断地址0x80000000+0x00000024=0x80000024

/*大致的作用就是把宏的第一个参数$HandlerLabel 转换成一个标号，然后让程序跳转到第二个参数$HandleLabel （为一个地址）对应的值的地址去*/

//这样做的目的是为了后面多种中断不需要每一个都写这么多代码

//该代码主要实现跳转功能，把异常处理程序地址HandleXXX送到PC中。例如//产生IRQ中断时，PC会被强制设置为0x18，执行指令：b HandlerIRQ

MACRO

$HandlerLabel HANDLER $HandleLabel

/*注解：$HandlerLabel 为标号，字符串型；HANDLER 为宏名；$HandleLabel 为参数，指针型。*/

/*在ARM体系中，每个指针变量占4个字节，这就解释了这里为什么每个标号分配了四个字节的空间，里面放的就是函数指针*/

$HandlerLabel //定义标号

sub sp,sp,#4 ; //把栈顶指针减4，留出一个字的空间（用于保存跳转地址的值）sp=sp-4

stmfd sp!,{r0}

//首先把sp减4，然后把将要使用的r0寄存器入栈，堆栈寻址方式，要加{}。

ldr r0, =$HandleLabel

//给寄存器r0赋值，将HandleXXX的址址放入r0，加载指定地址上的数据(字),放入Rd中

ldr r0, [r0]

//给寄存器r0赋值

//把HandleXXX所指向的内容(也就是中断程序的入口)放入r0

//加[]表示r0寄存器里的地址所对应的值，不加[]表示r0寄存器里的地址

str r0,[sp,#4]

//;store the contents(ISR) of HandleXXX to stack把中断服务程序(ISR)压入栈

//把寄存器r0保存到sp+4处，sp没有改变

ldmfd sp!,{r0,pc}

//;POP the work register and pc(jump to ISR) 用出栈的方式恢复r0的原值和为pc设定新值(完成了到ISR的转跳)

//把栈顶的两个字弹出，分别保存到r0、pc

MEND

//所以，通过上面的分析可以看出，$HandlerLabel HANDLER $HandleLabel是让//PC跳转到$HandleLabel中存放的地址执行。

在这里用IMPORT伪指令(和c语言的extren一样)引入|Image$$RO$$Base|, ;|Image$$RO$$Limit|...等比较古怪的变量是编译器生成的. ;RO, RW, ZI这三个段都保存在Flash中,但RW,ZI在Flash中 ;的地址肯定不是程序运行时变量所存储的位置,因此我们的程序在初始化时应该把Flash中的RW,ZI拷贝到RAM的对应位置.这些变量是通过ADS的工程设置里面 ;设定的RO Base和RW Base设定的, 最终由编译脚本和连接程序导入程序. ;实际上RW,ZI在Flash中的位置就紧接着RO存储.我们知道Image$$RO$$Base, ;Image$$RO$$Limit, 那么Image$$RO$$Limit就是RW(ROM data)的开始.

/*一个正在执行的ARM程序由RO,RW,ZI三个段组成，其中RO(只读)为代码段，RW(读写)是已经初始化的全局变量，ZI是未初始化的全局变量。

bootloader要将RW段复制到RAM中，并将ZI段清零。编译器使用下列方式来记录各段的起始和结束地址*/

/*这些标号的值是通过编译器设定来确定的*/

// IMPORT是引用其他文件中定义的内容

// IMPORT 伪指令用于通知编译器要使用的标号在其他的源文件中定义，但要在当前源文件中引用，而且无论当前源文件是否引用该标号，该标号均会被加入到当前源文件的符号表中。

IMPORT |Image$$RO$$Base|

//; Base of ROM code，ROM code(也就是代码)的开始地址

IMPORT |Image$$RO$$Limit|

// ; End of ROM code (=start of ROM data)， ROM code的结束地址(=ROM data的开始地址)

IMPORT |Image$$RW$$Base|

//; Base of RAM to initialise，RAM 的起始地址

IMPORT |Image$$ZI$$Base|

//; Base and limit of area，ZI初始化的起始地址

IMPORT |Image$$ZI$$Limit|

// ; to zero initialise，ZI初始化的结束地址

//由于RW和ZI相连，所以|Image$$ZI$$Base|==|Image$$RW$$Limit|

在这里用IMPORT伪指令(和c语言的extren一样)引入外部变量MMU的快速总线 ; 同步模式和异步总线模式两个变量

IMPORT MMU_SetAsyncBusMode //用于把CPU的总线模式设置为同步模式

IMPORT MMU_SetFastBusMode //用于把CPU的总线模式设置为异步总线模式

//这里引入一些在其它文件中实现在函数,包括为我们所熟知的main函数

IMPORT Main ; The main entry of mon program

//注：Main函数在u2440mon.c这个文件里。找的好辛苦啊！

初始化程序init中必须指明入口地址，因为处理器复位（仿真时，装载image）后PC 要找到入口开始执行代码，当各种异常或是中断产生的时候也要找到各个异常的入口开始执行代码。从这里开始就是真正的代码入口了！

AREA 伪指令用于定义一个代码段或数据段.ARM 汇编程序设计采用分段式设计,一个 ARM 源程序至少需要一个代码段,大的程序可以包含多少个代码段及数据段.

CODE 为定义代码段.默认属性为 READONLY；

READONLY 指定本段为只读,代码段的默认属性为READONLY；

板子上电和复位后程序开始从位于0x0处开始执行，硬件刚刚上电复位后程序从这里开始执行跳转到标为ResetHandler处执行

AREA Init,CODE,READONLY

//这表明下面的是一个名为Init的代码段

ENTRY //程序的入口点(调试用)

/*板子上电和复位后，程序开始从位于0x0处开始执行，硬件刚刚上电复位后，程序从这里开始执行跳转到标号为ResetHandler处执行*/

/* ENTRY只是定义一个普通的入口点，且在程序中可以多处定义，如果要使用它作为整个映像文件的唯一入口点，还需要设置链接器中的相关选项。

EXPORT __ENTRY // EXPORT表示可以被其他程序调用

//导出符号_ENTRY

__ENTRY

//复位

ResetEntry //复位后入口

;1)The code, which converts to Big-endian, should be in little endian code.

;2)The following little endian code will be compiled in Big-Endian mode.

; The code byte order should be changed as the memory bus width.

;3)The pseudo instruction,DCD can t be used here because the linker generates error.

1,ASSERT :DEF:ENDIAN_CHANGE ;ASSERT 是断言伪指令,语法是:ASSERT +逻辑表达式 ;def 是逻辑伪操作符,格式为: :DEF:label,作用是:判断label是否定义过 ;

2,下面的四句指令能且只能执行一句,并且前三句若执行跳转后处理程序的最后一句也是 ;b ResetHandler ;3," [ " 相当于 if ;" | "相当于else ;" ] " 相当于endif

ASSERT :DEF:ENDIAN_CHANGE

// ASSERT断言错误伪指令，这里表示是否定义过ENDIAN_CHANGE

[ ENDIAN_CHANGE

//如果定义了ENDIAN_CHANGE ，这个参数在option.inc里定义为FALSE,所以这个if不执行，ARM采用的是大端模式

ASSERT :DEF:ENTRY_BUS_WIDTH

//这里表示是否定义过ENTRY_BUS_WIDTH，如果没有定义ENTRY_BUS_WIDTH就报错

[ ENTRY_BUS_WIDTH=32

b ChangeBigEndian ; 跳转到ChangeBigEndian DCD 0xea000007，在后面有ChangeBigEndian

]

[ ENTRY_BUS_WIDTH=16

andeq r14,r7,r0,lsl #20 ;

/*当标志状态寄存器CPSR的Z位=1时,r14=r7+r0逻辑左移20位，执行DCD 0x0007ea00改变大小端模式

]

[ ENTRY_BUS_WIDTH=8

streq r0,[r0,-r10,ror #1] ; 当标志状态寄存器CPSR的Z位=1时…，执行DCD 0x070000ea 改变大小端模式

]

| //注意，| 是else的意思

//如果没有定义总线宽度,则跳转到复位中断

bResetHandler

//复位处理程序，我们的程序由于ENDIAN_CHANGE设成FALSE就到这儿了,转跳到复位程序入口

]

中断向量表一般位于启动代码的开始部分，它是用户程序与启动代码之间以及启动代码的各部分之间联系的纽带。它由一个一个的跳转函数组成，它就象一个普通的散转函数，只不过散转的过程中有硬件机制参与，当系统发生异常时，ARM 处理器会通过硬件机制强制将PC 指针指向中断向量表中对应的异常跳转函数存储的地址，然后程序会跳转到相应的中断服务程序去执行。

#define pISR_RESET (*(unsigned *)(_ISR_STARTADDRESS+0x0))

#define pISR_UNDEF (*(unsigned *)(_ISR_STARTADDRESS+0x4))

#define pISR_SWI (*(unsigned *)(_ISR_STARTADDRESS+0x8))

#define pISR_PABORT (*(unsigned *)(_ISR_STARTADDRESS+0xc))

#define pISR_DABORT (*(unsigned *)(_ISR_STARTADDRESS+0x10))

#define pISR_RESERVED (*(unsigned *)(_ISR_STARTADDRESS+0x14))

#define pISR_IRQ (*(unsigned *)(_ISR_STARTADDRESS+0x18))

#define pISR_FIQ (*(unsigned *)(_ISR_STARTADDRESS+0x1c))

在“addr.h”里定义

// 2 创建异常中断的入口函数

//异常向量的入口函数是由8 个跳转指令组成的，这8 个跳转指令需要按照顺序//放置到固定的地址上，地址是0x00～0x1c，这8 个跳转指令是ARM 汇编指令，//所以条指令占4 个字节的位置。

b HandlerUndef

;handler for Undefined mode 未定义异常，遇到无法识别的指令时0x04

b HandlerSWI

;handler for SWI interrupt，软中断异常0x08

b HandlerPabort

;handler for PAbort指令预取错误时进入0x0c 处理终止程序访问终止模式

b HandlerDabort

;handler for DAbort数据访问不能完成时进入0x10 处理数据访问终止模式

b .

;reserved, 保留 0x14 "."代表指令的地址，即表示进行死循环

b HandlerIRQ

;handler for IRQ interrupt发生IRQ 中断时进入0x18

b HandlerFIQ

;handler for FIQ interrupt发生FIQ 中断时进入0x1c

;@0x20 "@" 存储区位置计数器的当前值

b EnterPWDN ; Must be @0x20.

下面是改变大小端的程序,这里采用直接定义机器码的方式,至说为什么这么做 ;就得问三星了，反正我们程序里这段代码也不会去执行,不用去管它

ChangeBigEndian

;@0x24

[ ENTRY_BUS_WIDTH=32

/* DCD用于分配一段字内存单元,并用伪指令中的expr初始化.DCD伪指令分配的内存需要字对齐,一般可用来定义数据表格或其它常数.&与DCD 同义. */

DCD0xee110f10;0xee110f10 => mrc p15,0,r0,c1,c0,0

DCD0xe3800080;0xe3800080 => orr r0,r0,#0x80; //Big-endian

DCD0xee010f10;0xee010f10 => mcr p15,0,r0,c1,c0,0

]

[ ENTRY_BUS_WIDTH=16

DCD 0x0f10ee11

DCD 0x0080e380 //DCD伪指令定义一个32位存储单元,并初始化

DCD 0x0f10ee01

]

[ ENTRY_BUS_WIDTH=8

DCD 0x100f11ee

DCD 0x800080e3

DCD 0x100f01ee

]

DCD 0xffffffff ;swinv 0xffffff is similar with NOP and run well in both endian mode.

/*DCD用于分配一段字内存单元,并用伪指令中的expr初始化.DCD伪指令分配的内存需要字对齐,一般可用来定义数据表格或其它常数.&与DCD同义. */

DCD 0xffffffff

b ResetHandler

;进入掉电模式功能，注：2440有四种电源模式，参考2440A中文手册第60页

; 1. SDRAM 必须在自刷新模式.

; 2. 所有中断必须屏蔽 for SDRAM/DRAM self-refresh.

; 3. LCD 关闭for SDRAM/DRAM self-refresh.

; 4. The I-cache 可能需要开启.

; 5. The location of the following code may have not to be changed.

//如第前面所说,这里采用HANDLER宏去建立Hander***和Handle***之间的联系

HandlerFIQ HANDLER HandleFIQ

HandlerIRQ HANDLER HandleIRQ

HandlerUndef HANDLER HandleUndef

HandlerSWI HANDLER HandleSWI

HandlerDabort HANDLER HandleDabort

HandlerPabort HANDLER HandlePabort

=============================================================

;这一段程序就是用来进行第二次查表的过程了.如果说第一次查表是由硬件来完成的,那这一次查表就是由软件来实现的了. 为什么要查两次表?? ;没有办法,ARM把所有的中断都归纳成一个IRQ中断异常和一个FIRQ中断异常,第一次查表主要是查出是什么异常,可我们总要知道是这个中断异常中的什么中断呀!没办法了,再查一次表呗!

下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置1 ，置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务中断就将pc置为中断服务函数首地址

;//外部中断号判断，通过中断服务程序入口地址存储器的地址偏移确定

;//PC=[HandleEINT0+[INTOFFSET]]

;============================================================

//创建查找IRQ 中断源程序

IsrIRQ

sub sp,sp,#4

// ;reserved for PC，给PC寄存器保留，预留pc返回指针的存储位置

stmfd sp!,{r8-r9}

//把r8-r9压入栈，INTOFFSET的值在2440addr.inc中定义为0x4a000014

ldr r9,=INTOFFSET

/*中断偏移寄存器中的值表明了是哪个IRQ模式的中断请求，在INTPND寄存器中*/

//把中断偏移INTOFFSET的地址装入r9

ldr r9,[r9]

//把中断偏移INTOFFSET的值装入r9

ldr r8,=HandleEINT0

// HandleEINT0 的地址就是中断的入口地址，把向量表的入口HandleEINT0装入r8

add r8,r8,r9,lsl #2 // r8=r8+ r9<<2，逻辑左移就相当于乘以4

ldr r8,[r8] //取[r8]地址的数据放入R8

//装入中断服务程序的入口

str r8,[sp,#8] //将R8中的数据放入[sp+8]的地址中

//把入口压入堆栈

ldmfd sp!,{r8-r9,pc} //将地址从堆栈中弹出给PC

//出栈 LTORG ;声明文字池

/*LTORG用于声明一个文字池,在使用LDR伪指令时,要在适当的地址加入LTORG声明文字池,这样就会把要加载的数据保存在文字池内,再用 ARM 的加载指令读出数据.(若没有使用 LTORG 声明文字池,则汇编器会在程序末尾自动声明.)*/

LTORG //用于声明一个数据缓冲池

/*上电和复位后，程序开始从位于0x0 处执行b ResetHandler 程序跳转到这里执行，将看门狗，中断之类的程序关掉，以免打扰初始化程序的进行。*/

/*板子上电复位后执行几个步骤。这里通过标号在注释中加1，2，3....标示标号表示执行顺序*/

;1.禁止看门狗屏蔽所有中断

ResetHandler //复位处理程序

ldr r0,=WTCON ;watch dog disable，关闭看门狗

ldr r1,=0x0 ; bit[5]: 0 - disable; 1 - enable (reset 默认)

str r1,[r0] //禁止看门狗

/* WTCON 为看门狗控制寄存器，此处将其写入0x0，就是禁止它的所有功能，包括定时器定时，溢出中断及溢出复位。

ldr r0,=INTMSK

ldr r1,=0xffffffff ;all interrupt disable

str r1,[r0]

/* INTMSK 为中断屏蔽寄存器，写入0xffffffff，就是禁止所有的中断产生，因为中断向量表还未初始化，如果此时产生中断会使程序进入未知的状态而跑飞。因为外设的中断太多，INTMSK 不够用，还需要INTSUBMSK 来将剩余的中断源也禁止掉。

ldr r0,=INTSUBMSK // INTSUBMSK中断次级屏蔽寄存器 11位

ldr r1,=0x7fff ;all sub interrupt disable

str r1,[r0]

//下面代码网上没有

;led显示

[ {FALSE}

; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);

; Led_Display

ldr r0,=GPFCON

ldr r1,=0x5500

str r1,[r0]

ldr r0,=GPFDAT

ldr r1,=0x10

str r1,[r0]

]

2、根据工作频率设置PLL

//在ARM处理器中，有这个PLL模块，用来提高时钟频率的。在PLL中有个PLL倍频值(M)还有一个PLL分频值(P)。

;To reduce PLL lock time, adjust the LOCKTIME register.

ldr r0,=LOCKTIME //设置pll锁定时间

ldr r1,=0xffffff //Pll锁定寄存器S3C2410默认为0XFFFFF

str r1,[r0] //S3C2440默认为0XFFFFFFFF

[ PLL_ON_START //在option.inc中定义，初始化为真

; Added for confirm clock divide. for 2440.

; Setting value Fclk:Hclk:Pclk

//参考“FLCK、HCLK和PCLK的关系.txt”文件

ldr r0,=CLKDIVN

ldr r1,=CLKDIV_VAL ; 0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4, 5=1:4:8, 6=1:3:3, 7=1:3:6.

str r1,[r0]

[ CLKDIV_VAL>1 ; means Fclk:Hclk is not 1:1.

mrc p15,0,r0,c1,c0,0

orr r0,r0,#0xc0000000;R1_nF:OR:R1_iA

mcr p15,0,r0,c1,c0,0

mrc p15,0,r0,c1,c0,0

bic r0,r0,#0xc0000000;R1_iA:OR:R1_nF

mcr p15,0,r0,c1,c0,0

]

;Configure UPLL

ldr r0,=UPLLCON

ldr r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV)

str r1,[r0]

nop ; Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting hardware be completed.

nop

;Configure MPLL

ldr r0,=MPLLCON

ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;Fin=16.9344MHz

str r1,[r0]

]

;Check if the boot is caused by the wake-up from SLEEP mode.

// 判断是否在睡眠状态启动，如果是，则跳转到WAKEUP_SLEEP

ldr r1,=GSTATUS2

ldr r0,[r1]

tst r0,#0x2

;In case of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.

bne WAKEUP_SLEEP // WAKEUP_SLEEP在后面有定义

;EXPORT StartPointAfterSleepWakeUp

;StartPointAfterSleepWakeUp

;Set memory control registers

;============================================================

;设置内存控制器等寄存器的值,因为这些寄存器是连续排列的,所以采用如下办法对这些寄存器进行连续设置.其中用到了SMRDATA的数据,这在代码后面有定义

初始化内存控制器其实就是对S3C2440 的memory bank 进行设置，使其扩展的存储器或外部设备能够被处理器通过内存控制器正确读写。

由于S3C2440 的最终应用程序是在SDRAM（bank6）中运行，并与C 语言变量等的用户数据,各种模式的堆栈,中断向量表,都被定位在SDRAM 的空间，所以它必须在涉及这些处理之前完成初始化工作。

;============================================================

;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序

;SMRDATA map在下面的程序中定义

;SMRDATA中涉及的值请参考memcfg.inc程序

;ldr r0,=SMRDATA

adrl r0, SMRDATA

ldr r1,=BWSCON ;BWSCON Address

add r2, r0, #52 ;End address of SMRDATA一共13 个寄存器

ldr r3, [r0], #4

str r3, [r1], #4

cmp r2, r0

bne %B0

;delay

mov r0, #&1000

subs r0, r0, #1

bne %B1

;===

;这段是功能寄存器初始化，把13 个存储控制器的内容批量的读取到了对应的特殊功能寄存器中，首先是下面有一个数据区SMRDATA，在程序的后面有定义，这个数据区给13 个寄存器分配52 字节的地址空间。在上面的代码中，r0 是这个数据区的起始地址，r2 是数据区的结束地址，r1 是寄存器的起始地址。这样，用一个判断语句就可以把内存中的数据赋给这13 个存储控制寄存器了。

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;; When EINT0 is pressed, Clear SDRAM

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; check if EIN0 button is pressed

这一段检测EINT0是否被按下，假如EINT0被按下，则清空SDRAM

; ldr r0,=GPFCON

; ldr r1,=0x0

; str r1,[r0]

; ldr r0,=GPFUP

; ldr r1,=0xff

; str r1,[r0]

;

; ldr r1,=GPFDAT

; ldr r0,[r1]

; bic r0,r0,#(0x1e<<1) ; bit clear

; tst r0,#0x1

; bne %F1

; Clear SDRAM Start

; ldr r0,=GPFCON

; ldr r1,=0x55aa

; str r1,[r0]

; ldr r0,=GPFUP

; ldr r1,=0xff

; str r1,[r0]

; ldr r0,=GPFDAT

; ldr r1,=0x0

; str r1,[r0] ;LED=****

;Clear SDRAM End

;很明显可以看出，程序利用r1~r8这几个寄存器把0x30000000到0x34000000的内存全部清零了

// 初始化堆栈

;Initialize stacks

bl InitStacks ；初始化堆栈

;==========================================================

; Setup IRQ handler//建立中断表

ldr r0,=HandleIRQ ;This routine is needed

ldr r1,=IsrIRQ ;if there isn t 'subs pc,lr,#4' at 0x18, 0x1c

str r1,[r0]

;===========================================================

;// 判断是从nor启动还是从nand启动

;下面这段代码进行复制前的判断，因为从 NAND Flash 与从NOR Flash 启动的复制过程是大不相同的。这段程序能在nor nand flash 运行，也可以在内存中运行。在nor nand flash运行，需要拷贝数据； BWSCON 的[2:1]反映了外部引脚 OM[1:0]:若 OM[1:0] != 00, 从NOR FLash 启动或直接在内存运行;若 OM[1:0] 00，则为从Nand Flash 启动

;===========================================================

;bl Led_Test

ldr r0, =BWSCON

ldr r0, [r0]

ands r0, r0, #6 ;OM[1:0] != 0, NOR FLash boot

bne NORRoCopy ;don t read nand flash，;若从NOR启动，跳转到标号copy_proc_beg

adr r0, ResetEntry ;OM[1:0] == 0, NAND FLash boot // ADR 装载参照的地址=sub r0,pc,#0x268;

cmp r0, #0 ;if use Multi-ice,//JTAG调试时是直接下载到内存中运行，不需要再从nand拷贝

bne InitRamZero ;don t read nand flash for boot

;nop

;=====================================================================

ldr r0, =BWSCON

ldr r0, [r0]

ands r0, r0, #6

bne copy_proc_beg ;若从NOR启动，跳转到标号copy_proc_beg

adr r0, ResetEntry ;从NOR或NAND启动，ResetEntry 都为0, 但上面已经排除了NOR启动

cmp r0, #0 ;所以入口是0 地址表示是从 NAND 的 StepingStone启动

bne copy_proc_beg ;若从 NOR 启动，跳转到标号 copy_proc_beg。否则往下执行

;nop

;=====================================================================

;===========================================================

;//将程序从nandflash拷贝到sdram

;===========================================================

nand_boot_beg

bl ClearSdram

mov r5, #NFCONF

;set timing value

ldr r0, =(7<<12)|(7<<8)|(7<<4)

str r0, [r5]

;enable control

ldr r0, =(0<<13)|(0<<12)|(0<<10)|(0<<9)|(0<<8)|(1<<6)|(1<<5)|(1<<4)|(1<<1)|(1<<0)

str r0, [r5, #4]

bl ReadNandID

mov r6, #0

ldr r0, =0xecF1

cmp r5, r0

beq %F1

; ldr r0, =0xecda

; cmp r5, r0

mov r6, #1 ;Nandaddr(寻址周期 0:4 1:5)

bl ReadNandStatus

=============================================================

bl ReadNandID ;接着读取NAND的ID号,结果保存在r5里

mov r6, #0 ;r6设初值0.

ldr r0, =0xec73 ;期望的NAND ID号

cmp r5, r0 ;这里进行比较,r5是读取到的ID

beq %F1 ;相等的话就跳到下一个1标号处

ldr r0, =0xec75 ;这是另一个期望值

cmp r5, r0 ;这里进行比较

beq %F1 ;相等的话就跳到下一个1标号处

mov r6, #1 ;若ID不是0xec73 或 0xec75, 设置 r6=1，否则 r61

bl ReadNandStatus ;读取NAND状态,结果放在r1里

=============================================================

mov r8, #0 ;r8设初值0,意义为页号(start page address)

ldr r9, =ResetEntry ；设初值为 ResetEntry 的绝对地址 |Image$$RO$$Base|=0x30000000,

mov r10,#32 ;+081010 feiling

ands r0, r8, #0x3f ;如果是第一页，则检测坏块

bne %F3

mov r0, r8

bl CheckBadBlk

cmp r0, #0

addne r8, r8, #64 ;每块的页数此处有BUG r8同时也做计数用。。

addne r10,r10,#64 ;+081010 feiling

bne %F4

mov r0, r8

mov r1, r9

bl ReadNandPage

add r9, r9, #2048 ;每页的字节数

add r8, r8, #1 ;页数＋1

cmp r8, r10 ;要拷贝的页数 081010 pht:#32->r10

bcc %B2

mov r5, #NFCONF ;DsNandFlash

ldr r0, [r5, #4]

bic r0, r0, #1

str r0, [r5, #4]

ldr pc, =InitRamZero;此处跳转到内存空间 LDR 装载数据，寻址灵活。但不改变PSR

;要装载一个被存储的‘状态’并正确的恢复它可以这样写：ldr r0, [base] 换行 moves pc, r0

;=============================================================================================

;若是从NAND启动，则拷贝工作已经在nand_boot_beg中完成，所以直接跳转到main

;若是从NOR启动，则将RO和RW部分都拷贝到内存，然后跳转到内存运行（也可在NOR中运行，只是速度稍慢）

;

;注：若在NOR中直接运行，需把RO/BASE改为0并定义RW/BASE 会跳过RO拷贝

;=============================================================================================

NORRoCopy ;copy_proc_beg by pht

bl ClearSdram

adr r0, ResetEntry ;判断是否在ROM中运行，ROM即RO指定的地址从NOR启动时ResetEntry为0

ldr r2, BaseOfROM ;如果是则跳转到RwCopy 否则的话，将程序拷贝到ROM地址

cmp r0, r2

beq NORRwCopy

ldr r3, TopOfROM ;

ldmia r0!, {r4-r7}

stmia r2!, {r4-r7}

cmp r2, r3

bcc %B0

NORRwCopy

ldr r0, TopOfROM

ldr r1, BaseOfROM

sub r0, r0, r1 ;TopOfROM-BaseOfROM得到从0开始RW的偏移地址

ldr r2, BaseOfBSS ;将RW部分的数据从ROM拷贝到RAM

ldr r3, BaseOfZero

cmp r2, r3

ldrcc r1, [r0], #4

strcc r1, [r2], #4

bcc %B0

InitRamZero

mov r0, #0

ldr r2, BaseOfZero

ldr r3, EndOfBSS

cmp r2, r3 ;初始化Zero部分不管从哪里启动，这部分都需要执行

strcc r0, [r2], #4

bcc %B1

ldr pc, =CEntry ;goto compiler address

; [ CLKDIV_VAL>1 ; means Fclk:Hclk is not 1:1.

; bl MMU_SetAsyncBusMode

; |

; bl MMU_SetFastBusMode ; default value.

; ]

CEntry

bl Main ;Don t use main() because ......

b .

;=========================================================

ClearSdram

mov r1,#0

mov r2,#0

mov r3,#0

mov r4,#0

mov r5,#0

mov r6,#0

mov r7,#0

mov r8,#0

ldr r9,=0x00700000 ;for wince

ldr r0,=0x30000000

stmia r0!,{r1-r8}

subs r9,r9,#32

bne %B0

mov pc,lr

;===========================================================

;function initializing stacks堆栈初始化

InitStacks

;Don t use DRAM,such as stmfd,ldmfd......

;SVCstack is initialized before

;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'

//UndefMode 堆栈

mrs r0,cpsr

bic r0,r0,#MODEMASK

orr r1,r0,#UNDEFMODE|NOINT

msr cpsr_cxsf,r1 ;UndefMode

ldr sp,=UndefStack ; UndefStack=0x33FF_5C00

//AbortMode 堆栈

orr r1,r0,#ABORTMODE|NOINT

msr cpsr_cxsf,r1 ;AbortMode

ldr sp,=AbortStack ; AbortStack=0x33FF_6000

//IRQMode 堆栈

orr r1,r0,#IRQMODE|NOINT

msr cpsr_cxsf,r1 ;IRQMode

ldr sp,=IRQStack ; IRQStack=0x33FF_7000

//FIQMode 堆栈

orr r1,r0,#FIQMODE|NOINT

msr cpsr_cxsf,r1 ;FIQMode

ldr sp,=FIQStack ; FIQStack=0x33FF_8000

//SVCMode 堆栈
bic r0,r0,#MODEMASK|NOINT

orr r1,r0,#SVCMODE

msr cpsr_cxsf,r1 ;SVCMode

ldr sp,=SVCStack ; SVCStack=0x33FF_5800

;USER mode has not be initialized.

mov pc,lr

;The LR register won t be valid if the current mode is not SVC mode.

;===========================================================

ReadNandID

mov r7,#NFCONF

ldr r0,[r7,#4] ;NFChipEn();

bic r0,r0,#2

str r0,[r7,#4]

mov r0,#0x90 ;WrNFCmd(RdIDCMD);

strb r0,[r7,#8]

mov r4,#0 ;WrNFAddr(0);

strb r4,[r7,#0xc]

1 ;while(NFIsBusy());

ldr r0,[r7,#0x20]

tst r0,#1

beq %B1

ldrb r0,[r7,#0x10] ;id = RdNFDat()<<8;

mov r0,r0,lsl #8

ldrb r1,[r7,#0x10] ;id |= RdNFDat();

orr r5,r1,r0

ldr r0,[r7,#4] ;NFChipDs();

orr r0,r0,#2

str r0,[r7,#4]

mov pc,lr

ReadNandStatus

mov r7,#NFCONF

ldr r0,[r7,#4] ;NFChipEn();

bic r0,r0,#2

str r0,[r7,#4]

mov r0,#0x70 ;WrNFCmd(QUERYCMD);

strb r0,[r7,#8]

ldrb r1,[r7,#0x10] ;r1 = RdNFDat();

ldr r0,[r7,#4] ;NFChipDs();

orr r0,r0,#2

str r0,[r7,#4]

mov pc,lr

WaitNandBusy

mov r0,#0x70 ;WrNFCmd(QUERYCMD);

mov r1,#NFCONF

strb r0,[r1,#8]

1 ;while(!(RdNFDat()&0x40));

ldrb r0,[r1,#0x10]

tst r0,#0x40

beq %B1

mov r0,#0 ;WrNFCmd(READCMD0);

strb r0,[r1,#8]

mov pc,lr

CheckBadBlk

mov r7, lr

mov r5, #NFCONF

bic r0,r0,#0x3f ;addr &= ~0x3f;

ldr r1,[r5,#4] ;NFChipEn()

bic r1,r1,#2

str r1,[r5,#4]

mov r1,#0x00 ;WrNFCmd(READCMD)

strb r1,[r5,#8]

mov r1, #0 ;2048&0xff

strb r1,[r5,#0xc] ;WrNFAddr(2048&0xff);

mov r1, #8 ;(2048>>8)&0xf

strb r1,[r5,#0xc]

strb r0,[r5,#0xc] ;WrNFAddr(addr)

mov r1,r0,lsr #8 ;WrNFAddr(addr>>8)

strb r1,[r5,#0xc]

cmp r6,#0 ;if(NandAddr)

movne r1,r0,lsr #16 ;WrNFAddr(addr>>16)

strb r1,[r5,#0xc]

mov r1,#0x30 ;WrNFCmd(0x30)

strb r1,[r5,#8]

; cmp r6,#0 ;if(NandAddr)

; movne r0,r0,lsr #16 ;WrNFAddr(addr>>16)

; strneb r0,[r5,#0xc]

; bl WaitNandBusy ;WaitNFBusy()

;don t use WaitNandBusy, after WaitNandBusy will read part A!

mov r0, #100

subs r0, r0, #1

bne %B1

ldr r0, [r5, #0x20]

tst r0, #1

beq %B2

ldrb r0, [r5,#0x10] ;RdNFDat()

sub r0, r0, #0xff

; mov r1,#0 ;WrNFCmd(READCMD0)

; strb r1,[r5,#8]

ldr r1,[r5,#4] ;NFChipDs()

orr r1,r1,#2

str r1,[r5,#4]

mov pc, r7

ReadNandPage

mov r7,lr

mov r4,r1

mov r5,#NFCONF

ldr r1,[r5,#4] ;NFChipEn()

bic r1,r1,#2

str r1,[r5,#4]

mov r1,#0 ;WrNFCmd(READCMD0)

strb r1,[r5,#8]

strb r1,[r5,#0xc] ;WrNFAddr(0)

strb r0,[r5,#0xc] ;WrNFAddr(addr)

mov r1,r0,lsr #8 ;WrNFAddr(addr>>8)

strb r1,[r5,#0xc]

cmp r6,#0 ;if(NandAddr)

movne r1,r0,lsr #16 ;WrNFAddr(addr>>16)

strb r1,[r5,#0xc]

mov r1,#0x30 ;WrNFCmd(0x30)

strb r1,[r5,#8]

ldr r0,[r5,#4] ;InitEcc()

orr r0,r0,#0x10

str r0,[r5,#4]

bl WaitNandBusy ;WaitNFBusy()

mov r0,#0 ;for(i=0; i<2048; i++)

ldrb r1,[r5,#0x10] ;buf[i] = RdNFDat()

strb r1,[r4,r0]

add r0,r0,#1

bic r0,r0,#0x10000 ;?

cmp r0,#0x800

bcc %B1

ldr r0,[r5,#4] ;NFChipDs()

orr r0,r0,#2

str r0,[r5,#4]

mov pc,r7

;--------------------LED test

EXPORT Led_Test

Led_Test

mov r0, #0x56000000

mov r1, #0x5500

str r1, [r0, #0x50]

mov r1, #0x50

str r1, [r0, #0x54]

mov r2, #0x100000

subs r2, r2, #1

bne %B1

mov r1, #0xa0

str r1, [r0, #0x54]

mov r2, #0x100000

subs r2, r2, #1

bne %B2

b %B0

mov pc, lr

;===========================================================

LTORG

;GCS0->SST39VF1601

;GCS1->16c550

;GCS2->IDE

;GCS3->CS8900

;GCS4->DM9000

;GCS5->CF Card

;GCS6->SDRAM

;GCS7->unused

SMRDATA DATA

; Memory configuration should be optimized for best performance

; The following parameter is not optimized.

; Memory access cycle parameter strategy

; 1) The memory settings is safe parameters even at HCLK=75Mhz.

; 2) SDRAM refresh period is for HCLK<=75Mhz.

DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))

DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC)) ;GCS0

DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC)) ;GCS1

DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC)) ;GCS2

DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC)) ;GCS3

DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC)) ;GCS4

DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC)) ;GCS5

DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN)) ;GCS6

DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN)) ;GCS7

DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Tsrc<<18)+(Tchr<<16)+REFCNT)

DCD 0x32 ;SCLK power saving mode, BANKSIZE 128M/128M

;DCD 0x02 ;SCLK power saving disable, BANKSIZE 128M/128M

DCD 0x20 ;MRSR6 CL=2clk

DCD 0x20 ;MRSR7 CL=2clk

BaseOfROM DCD |Image$$RO$$Base|

TopOfROM DCD |Image$$RO$$Limit|

BaseOfBSS DCD |Image$$RW$$Base|

BaseOfZero DCD |Image$$ZI$$Base|

EndOfBSS DCD |Image$$ZI$$Limit|

ALIGN

;Function for entering power down mode

; 1. SDRAM should be in self-refresh mode.

; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.

; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.

; 4. The I-cache may have to be turned on.

; 5. The location of the following code may have not to be changed.

;void EnterPWDN(int CLKCON);

EnterPWDN

mov r2,r0 ;r2=rCLKCON

tst r0,#0x8 ;SLEEP mode?

bne ENTER_SLEEP

ENTER_STOP

ldr r0,=REFRESH

ldr r3,[r0] ;r3=rREFRESH

mov r1, r3

orr r1, r1, #BIT_SELFREFRESH

str r1, [r0] ;Enable SDRAM self-refresh

mov r1,#16 ;wait until self-refresh is issued. may not be needed.

0 subs r1,r1,#1

bne %B0

ldr r0,=CLKCON ;enter STOP mode.

str r2,[r0]

mov r1,#32

0 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.

bne %B0 ;2) Or wait here until the CPU&Peripherals will be turned-off

; Entering SLEEP mode, only the reset by wake-up is available.

ldr r0,=REFRESH ;exit from SDRAM self refresh mode.

str r3,[r0]

MOV_PC_LR

ENTER_SLEEP

;NOTE.

;1) rGSTATUS3 should have the return address after wake-up from SLEEP mode.

ldr r0,=REFRESH

ldr r1,[r0] ;r1=rREFRESH

orr r1, r1, #BIT_SELFREFRESH

str r1, [r0] ;Enable SDRAM self-refresh

mov r1,#16 ;Wait until self-refresh is issued,which may not be needed.

0 subs r1,r1,#1

bne %B0

ldr r1,=MISCCR

ldr r0,[r1]

orr r0,r0,#(7<<17) ;Set SCLK0=0, SCLK1=0, SCKE=0.

str r0,[r1]

ldr r0,=CLKCON ; Enter sleep mode

str r2,[r0]

b . ;CPU will die here.

WAKEUP_SLEEP

;Release SCLKn after wake-up from the SLEEP mode.

ldr r1,=MISCCR

ldr r0,[r1]

bic r0,r0,#(7<<17) ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.

str r0,[r1]

;Set memory control registers

ldr r0,=SMRDATA

ldr r1,=BWSCON ;BWSCON Address

add r2, r0, #52 ;End address of SMRDATA

ldr r3, [r0], #4

str r3, [r1], #4

cmp r2, r0

bne %B0

mov r1,#256

0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.

bne %B0

ldr r1,=GSTATUS3 ;GSTATUS3 has the start address just after SLEEP wake-up

ldr r0,[r1]

mov pc,r0

;=====================================================================

; Clock division test

; Assemble code, because VSYNC time is very short

;=====================================================================

EXPORT CLKDIV124

EXPORT CLKDIV144

CLKDIV124

ldr r0, = CLKDIVN

ldr r1, = 0x3 ; 0x3 = 1:2:4

str r1, [r0]

; wait until clock is stable

nop

ldr r0, = REFRESH

ldr r1, [r0]

bic r1, r1, #0xff

bic r1, r1, #(0x7<<8)

orr r1, r1, #0x470 ; REFCNT135

str r1, [r0]

nop

mov pc, lr

CLKDIV144

ldr r0, = CLKDIVN

ldr r1, = 0x4 ; 0x4 = 1:4:4

str r1, [r0]

; wait until clock is stable

nop

ldr r0, = REFRESH

ldr r1, [r0]

bic r1, r1, #0xff

bic r1, r1, #(0x7<<8)

orr r1, r1, #0x630 ; REFCNT675 - 1520

str r1, [r0]

nop

mov pc, lr

//1 创建中断向量表

中断向量表创建到SDRAM 高位地址上，主要是因为SDRAM 的地址位置需要放置执行的映象程序，而且在SDRAM 中查找向量表速度会快很多。中断向量表放置时需要字对齐。

ALIGN ；通过添加补丁字节使当前位置满足一定的对齐方式

;可读写的数据段

AREA RamData, DATA, READWRITE

^ _ISR_STARTADDRESS

; _ISR_STARTADDRESS=0x33FF_FF00，定义一个结构化的内存表（storage map）的首地址

HandleReset # 4 //定义一个结构化内存表中的数据域，该域为4 个字节

HandleUndef # 4

HandleSWI # 4

HandlePabort # 4

HandleDabort # 4

HandleReserved # 4

HandleIRQ # 4

HandleFIQ # 4

;Don t use the label 'IntVectorTable',

;The value of IntVectorTable is different with the address you think it may be.

;IntVectorTable

;@0x33FF_FF20

HandleEINT0 # 4

HandleEINT1 # 4

HandleEINT2 # 4

HandleEINT3 # 4

HandleEINT4_7 # 4

HandleEINT8_23 # 4

HandleCAM # 4 ; Added for 2440.

HandleBATFLT # 4

HandleTICK # 4

HandleWDT # 4

HandleTIMER0 # 4

HandleTIMER1 # 4

HandleTIMER2 # 4

HandleTIMER3 # 4

HandleTIMER4 # 4

HandleUART2 # 4

;@0x33FF_FF60

HandleLCD # 4

HandleDMA0 # 4

HandleDMA1 # 4

HandleDMA2 # 4

HandleDMA3 # 4

HandleMMC # 4

HandleSPI0 # 4

HandleUART1 # 4

HandleNFCON # 4 ; Added for 2440.

HandleUSBD # 4

HandleUSBH # 4

HandleIIC # 4

HandleUART0 # 4

HandleSPI1 # 4

HandleRTC # 4

HandleADC # 4

;@0x33FF_FFA0

END