无线局域网自动切换IP批处理文件

@echo off
title=自动切换ip地址
color 0A
rem *************** 自动切换ip地址程序 ***************
rem    主要用于不同网络环境自动切换
rem **************************************************
set find=%SystemRoot%\System32\find.exe
set config=%SystemRoot%\System32\ipconfig.exe
goto :start
:start
cls
echo                     ╭─────────────╮
echo       ╭──────┤    IP地址自动设置程序    ├─────────╮
echo       │            ╰─────────────╯                  │
echo       │本程序能为您自动或手动设置合适的IP,网关及DNS                │
echo       │Design By: Lee                                              │
echo       ╰──────────────────────────────╯
echo.
echo        1. 设置成静态IP
echo        2. 设置成动态ip
echo        Q. 退出
echo       ==========================================================
set type=
set /P type=      请选择: [1],[2]或[Q]?
if /I "%type%"=="1" goto :goictstatic
if /I "%type%"=="2" goto :godormdyn
if /I "%type%"=="Q" goto :end
goto :start
:goictstatic
set vADDR=192.168.12.8
set vMASK=255.255.255.0
set vGATE=192.168.12.2
set vDNS1=192.168.12.2
set vDNS2=0.0.0.0
echo.
echo       将IP地址设置成 %vADDR%
echo       子网掩码设置成 %vMASK%
echo       网关地址设置成 %vGATE%
echo       DNS:%vDNS1%
echo.
echo       正在设置IP地址,子网掩码及网关地址
netsh interface ipv4 set address name="无线网络连接" source=static %vADDR% %vMASK% %vGATE%
echo       正在设置DNS
netsh interface ipv4 set dns name="无线网络连接" source=static addr=%vDNS1% register=PRIMARY
netsh interface ipv4 add dns name="无线网络连接" addr=0.0.0.0 index=2
goto :showip
:godormdyn
echo.
echo 正在设置动态IP地址，请稍候!
netsh interface ipv4 set address name="无线网络连接" source=dhcp
echo 正在设置动态DNS地址，请稍候!
netsh interface ipv4 set dns name="无线网络连接" source=dhcp
goto :showip
:showip
cls
ipconfig/all
::netsh int ip show address
echo.
echo    按任一键退出程序!
pause >nul
:end
echo