STM32F10X启动代码注释



;* 文件名 : startup_stm32f10x_hd.s
;* 库版本 : V3.5.0
;* 说明   : 此文件为STM32F10x高密度设备的MDK工具链的启动文件
;* 该模块执行以下操作:
;* -设置初始堆栈指针（SP）
;* -设置初始程序计数器（PC）为复位向量，并在执行main函数前初始化系统时钟
;* -设置向量表入口为异常事件的入口地址
;* -复位之后处理器为线程模式，优先级为特权级，堆栈设置为MSP主堆栈
;*

Stack_Size      EQU     0x00000200  ;定义堆栈的大小1K

;AREA 命令指示汇编器汇编一个新的代码段或数据段。
;段是独立的、指定的、不可见的代码或数据块，它们由链接器处理.
;段是独立的、命名的、不可分割的代码或数据序列。一个代码段是生成一个应用程序的最低要求
;默认情况下，ELF(Executable and Linking Format是一种对象文件的格式)段在四字节边界上对齐。
;expression 可以拥有 0 到 31 的任何整数。段在 2的expression次方 字节边界上对齐
----------------------------------------------------------------------------------------
AREA    STACK, NOINIT, READWRITE, ALIGN=3  ;堆栈段，未初始化，允许读写，8字节边界对齐
----------------------------------------------------------------------------------------
;说明: Cortex-M3的指令地址要求是字边界对齐（4字节）；但是代码段是8字节边界对齐的

Stack_Mem   SPACE   Stack_Size ;分配堆栈空间，把首地址赋给Stack_Mem
__initial_sp ;初始化堆栈指针，指向堆栈顶.

;此处有个一个问题讨论，关于栈顶在RAM中所处位置问题，很多初学者一直以为是编译器特意放在HEAP段之后是有意为之;并且认为这样可以利用heap未分配空间来防止未知的栈溢出问题
;这种理解是错误的，链接器并不会为栈的位置做特殊的处理，而且这样做也并不会利用heap段
;在此文件的最后对堆栈的初始化代码中可以看出他们是两个互相独立的数据区。
;此处出现的现象是因为MDK按数据段的字母顺序链接数据段的地址的，所以此处造成了堆的地址在栈的前面的假象，不要窃以为是有某种特殊的约定。
                                                 
; <h> Heap Configuration
; <o> Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>

Heap_Size   EQU   0x00000200  ;定义堆的大小1K

AREA    HEAP, NOINIT, READWRITE, ALIGN=3 ;堆段,未初始化,允许读写,堆数据段8字节边界对齐
__heap_base                   ;标号__heap_base,表示堆空间起始地址.
Heap_Mem   SPACE   Heap_Size  ;分配堆空间
__heap_limit                  ;标号__heap_limit,表示堆空间结束地址.与__heap_base配合限制堆的大小

PRESERVE8  ; 命令指定当前文件保持栈的八字节对齐.告诉编译器以8字节对齐.
THUMB      ; 告诉编译器使用THUMB指令集，THUMB 必须位于使用新语法的任何Thumb代码之前

;EXPORT 命令声明一个符号，可由链接器用于解释各个目标和库文件中的符号引用，相当于声明了一个全局变量
;GLOBAL 与 EXPORT相同
;以下为向量表，在复位时被映射到FLASH的0地址
;定义只读数据段，实际上是在CODE区（假设STM32从FLASH启动，则此中断向量表起始地址即为0x8000000）
                AREA    RESET, DATA, READONLY ;复位段,只包含数据，只读
                EXPORT  __Vectors             ;标号__Vectors，表示中断向量表入口地址
                EXPORT  __Vectors_End         ;中断向量表结束
                EXPORT  __Vectors_Size        ;中断向量表大小
               
;DCD 命令分配一个或多个字的存储器，在四个字节的边界上对齐，并定义存储器的运行时初值。
__Vectors      

                DCD     __initial_sp      ;Top of Stack 栈顶指针,被放在向量表的开始,FLASH的0地址,复位后首先装载栈顶指针
                DCD     Reset_Handler     ;Reset Handler 复位异常,装载完栈顶后,第一个执行的,并且不返回
                DCD     NMI_Handler       ;NMI Handler    不可屏蔽中断
                DCD     HardFault_Handler ;Hard Fault Handler 硬件错误中断
                DCD     MemManage_Handler ;MPU Fault Handler 内存管理错误中断
                DCD     BusFault_Handler  ;Bus Fault Handler  总线错误中断,一般发生在数据访问异常,比如fsmc访问不当
                DCD     UsageFault_Handler;Usage Fault Handler 用法错误中断,一般是预取值,或者位置指令,数据处理等错误
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     SVC_Handler                ; SVCall Handler  系统调用异常，主要是为了调用操作系统内核服务
                DCD     DebugMon_Handler           ; Debug Monitor Handler 调试监视异常
                DCD     0                          ; Reserved
------------------------------------------------------------------------------------------------------------------------------------------------------------------
               ;DCD     PendSV_Handler             ; PendSV Handler,挂起异常
               ;此处可以看见用作了uCOS-II的上下文切换异常，这是被推荐使用的，因为Cortex-M3会在异常发生时自动保存R0-R3，
               ; R12,R13(堆栈指针SP)，R14(链接地址，也叫返回地址LR，在异常返回时使用)，R15（程序计数器PC，为当前应用程序+4）和中断完成时自动回复，
               ;我们只需保存R4-R11,大大减少了中断响应和上下文切换的时间。
;说明：此处涉及到一个中断保存寄存器问题：因为在所有的运行模式下，未分组寄存器都指向同一个物理寄存器，他们未被系统用作特殊的用途
;因此，在中断或者异常处理进行模式转换时，由于不同模式（此处为"线程"和"特权"）均使用相同的物理寄存器，可能会造成寄存器中数据的破坏
;这也是常说的"关键代码段"和"l临界区"保护的原因。
                ;DCD     SysTick_Handler            ; SysTick Handler  滴答定时器，为操作系统内核时钟
--------------------------------------------------------------------------------------------------------------------------------------------------------------------
                DCD     OS_CPU_PendSVHandler
                DCD     OS_CPU_SysTickHandler

                 ;External Interrupts                    以下为外部中断向量表
                 DCD     WWDG_IRQHandler        ; Window Watchdog
                 DCD     PVD_IRQHandler             ; PVD through EXTI Line detect
                 DCD     TAMPER_IRQHandler     ; Tamper
                 DCD     RTC_IRQHandler             ; RTC
                 DCD     FLASH_IRQHandler         ; Flash
                 DCD     RCC_IRQHandler             ; RCC
                 DCD     EXTI0_IRQHandler           ; EXTI Line 0
                 DCD     EXTI1_IRQHandler           ; EXTI Line 1
                 DCD     EXTI2_IRQHandler           ; EXTI Line 2
                 DCD     EXTI3_IRQHandler           ; EXTI Line 3
                 DCD     EXTI4_IRQHandler           ; EXTI Line 4
                 DCD     DMA1_Channel1_IRQHandler   ; DMA1 Channel 1
                 DCD     DMA1_Channel2_IRQHandler   ; DMA1 Channel 2
                 DCD     DMA1_Channel3_IRQHandler   ; DMA1 Channel 3
                 DCD     DMA1_Channel4_IRQHandler   ; DMA1 Channel 4
                 DCD     DMA1_Channel5_IRQHandler   ; DMA1 Channel 5
                 DCD     DMA1_Channel6_IRQHandler   ; DMA1 Channel 6
                 DCD     DMA1_Channel7_IRQHandler   ; DMA1 Channel 7
                 DCD     ADC1_2_IRQHandler          ; ADC1 & ADC2
                 DCD     USB_HP_CAN1_TX_IRQHandler   ; USB High Priority or CAN1 TX
                 DCD     USB_LP_CAN1_RX0_IRQHandler ; USB Low  Priority or CAN1 RX0
                 DCD     CAN1_RX1_IRQHandler        ; CAN1 RX1
                 DCD     CAN1_SCE_IRQHandler        ; CAN1 SCE
                 DCD     EXTI9_5_IRQHandler             ; EXTI Line 9..5
                 DCD     TIM1_BRK_IRQHandler         ; TIM1 Break
                 DCD     TIM1_UP_IRQHandler           ; TIM1 Update
                 DCD     TIM1_TRG_COM_IRQHandler    ; TIM1 Trigger and Commutation
                 DCD     TIM1_CC_IRQHandler                 ; TIM1 Capture Compare
                 DCD     TIM2_IRQHandler            ; TIM2
                 DCD     TIM3_IRQHandler            ; TIM3
                 DCD     TIM4_IRQHandler            ; TIM4
                 DCD     I2C1_EV_IRQHandler         ; I2C1 Event
                 DCD     I2C1_ER_IRQHandler         ; I2C1 Error
                 DCD     I2C2_EV_IRQHandler         ; I2C2 Event
                 DCD     I2C2_ER_IRQHandler         ; I2C2 Error
                 DCD     SPI1_IRQHandler            ; SPI1
                 DCD     SPI2_IRQHandler            ; SPI2
                 DCD     USART1_IRQHandler          ; USART1
                 DCD     USART2_IRQHandler          ; USART2
                 DCD     USART3_IRQHandler          ; USART3
                 DCD     EXTI15_10_IRQHandler       ; EXTI Line 15..10
                 DCD     RTCAlarm_IRQHandler        ; RTC Alarm through EXTI Line
                 DCD     USBWakeUp_IRQHandler       ; USB Wakeup from suspend
                 DCD     TIM8_BRK_IRQHandler        ; TIM8 Break
                 DCD     TIM8_UP_IRQHandler         ; TIM8 Update
                 DCD     TIM8_TRG_COM_IRQHandler    ; TIM8 Trigger and Commutation
                 DCD     TIM8_CC_IRQHandler         ; TIM8 Capture Compare
                 DCD     ADC3_IRQHandler               ; ADC3
                 DCD     FSMC_IRQHandler              ; FSMC
                 DCD     SDIO_IRQHandler              ; SDIO
                 DCD     TIM5_IRQHandler               ; TIM5
                 DCD     SPI3_IRQHandler               ; SPI3
                 DCD     UART4_IRQHandler           ; UART4
                 DCD     UART5_IRQHandler           ; UART5
                 DCD     TIM6_IRQHandler            ; TIM6
                 DCD     TIM7_IRQHandler            ; TIM7
                 DCD     DMA2_Channel1_IRQHandler   ; DMA2 Channel1
                 DCD     DMA2_Channel2_IRQHandler   ; DMA2 Channel2
                 DCD     DMA2_Channel3_IRQHandler   ; DMA2 Channel3
                 DCD     DMA2_Channel4_5_IRQHandler ; DMA2 Channel4 & Channel5
 __Vectors_End   ;向量表结束标志

__Vectors_Size  EQU  __Vectors_End - __Vectors ;计算向量表地址空间大小

;|.text|用于表示由 C 编译程序产生的代码段，或用于以某种方式与 C 库关联的代码段
AREA    |.text|, CODE, READONLY   ;定义C编译器源代码的代码段，只读
               
;Reset handler复位中断服务程序，PROC…ENDP结构表示程序的开始和结束
 Reset_Handler   PROC
                 ;声明复位中断向量Reset_Handler为全局属性,这样外部文件就可以调用此复位中断服务
                 EXPORT  Reset_Handler             [WEAK]  ;此处[WEAK]表示弱定义，优先执行其他文件的定义
                 IMPORT  __main
                 IMPORT  SystemInit
                 LDR     R0, =SystemInit   ;装载寄存器指令
                 BLX     R0                ;带链接的跳转，切换指令集          
                 LDR     R0, =__main
                 BX      R0                ;跳转到__use_two_region_memory进行堆栈初始化.然后进入main函数不返回.切换指令集
                 ENDP
                
;Dummy Exception Handlers (infinite loops which can be modified)

NMI_Handler      PROC
                 EXPORT  NMI_Handler                [WEAK]
                 B       .
                 ENDP
;斜杠'\'的作用-将两行或更多行连接起来
 HardFault_Handler\
                 PROC
                 EXPORT  HardFault_Handler          [WEAK]
                 B       .
                 ENDP
 MemManage_Handler\
                 PROC
                 EXPORT  MemManage_Handler          [WEAK]
                 B       .
                 ENDP
 BusFault_Handler\
                 PROC
                 EXPORT  BusFault_Handler           [WEAK]
                 B       .
                 ENDP
 UsageFault_Handler\
                 PROC
                 EXPORT  UsageFault_Handler         [WEAK]
                 B       .
                 ENDP
 SVC_Handler     PROC
                 EXPORT  SVC_Handler                [WEAK]
                 B       .
                 ENDP
 DebugMon_Handler\
                 PROC
                 EXPORT  DebugMon_Handler           [WEAK]
                 B       .
                 ENDP
 OS_CPU_PendSVHandler  PROC
                 EXPORT  OS_CPU_PendSVHandler       [WEAK]
                 B       .
                 ENDP
 OS_CPU_SysTickHandler PROC
                 EXPORT  OS_CPU_SysTickHandler      [WEAK]
                 B       .
                 ENDP

Default_Handler PROC
                 ; 输出异常向量表标号，方便外部实现异常的具体功能 ， [WEAK] 是弱定义的意思，如果外部定义了，优先执行外部定义，否则下面的函数定义
                 EXPORT  WWDG_IRQHandler            [WEAK]
                 EXPORT  PVD_IRQHandler             [WEAK]
                 EXPORT  TAMPER_IRQHandler          [WEAK]
                 EXPORT  RTC_IRQHandler             [WEAK]
                 EXPORT  FLASH_IRQHandler           [WEAK]
                 EXPORT  RCC_IRQHandler             [WEAK]
                 EXPORT  EXTI0_IRQHandler           [WEAK]
                 EXPORT  EXTI1_IRQHandler           [WEAK]
                 EXPORT  EXTI2_IRQHandler           [WEAK]
                 EXPORT  EXTI3_IRQHandler           [WEAK]
                 EXPORT  EXTI4_IRQHandler           [WEAK]
                 EXPORT  DMA1_Channel1_IRQHandler   [WEAK]
                 EXPORT  DMA1_Channel2_IRQHandler   [WEAK]
                 EXPORT  DMA1_Channel3_IRQHandler   [WEAK]
                 EXPORT  DMA1_Channel4_IRQHandler   [WEAK]
                 EXPORT  DMA1_Channel5_IRQHandler   [WEAK]
                 EXPORT  DMA1_Channel6_IRQHandler   [WEAK]
                 EXPORT  DMA1_Channel7_IRQHandler   [WEAK]
                 EXPORT  ADC1_2_IRQHandler          [WEAK]
                 EXPORT  USB_HP_CAN1_TX_IRQHandler  [WEAK]
                 EXPORT  USB_LP_CAN1_RX0_IRQHandler [WEAK]
                 EXPORT  CAN1_RX1_IRQHandler        [WEAK]
                 EXPORT  CAN1_SCE_IRQHandler        [WEAK]
                 EXPORT  EXTI9_5_IRQHandler         [WEAK]
                 EXPORT  TIM1_BRK_IRQHandler        [WEAK]
                 EXPORT  TIM1_UP_IRQHandler         [WEAK]
                 EXPORT  TIM1_TRG_COM_IRQHandler    [WEAK]
                 EXPORT  TIM1_CC_IRQHandler         [WEAK]
                 EXPORT  TIM2_IRQHandler            [WEAK]
                 EXPORT  TIM3_IRQHandler            [WEAK]
                 EXPORT  TIM4_IRQHandler            [WEAK]
                 EXPORT  I2C1_EV_IRQHandler         [WEAK]
                 EXPORT  I2C1_ER_IRQHandler         [WEAK]
                 EXPORT  I2C2_EV_IRQHandler         [WEAK]
                 EXPORT  I2C2_ER_IRQHandler         [WEAK]
                 EXPORT  SPI1_IRQHandler            [WEAK]
                 EXPORT  SPI2_IRQHandler            [WEAK]
                 EXPORT  USART1_IRQHandler          [WEAK]
                 EXPORT  USART2_IRQHandler          [WEAK]
                 EXPORT  USART3_IRQHandler          [WEAK]
                 EXPORT  EXTI15_10_IRQHandler       [WEAK]
                 EXPORT  RTCAlarm_IRQHandler        [WEAK]
                 EXPORT  USBWakeUp_IRQHandler       [WEAK]
                 EXPORT  TIM8_BRK_IRQHandler        [WEAK]
                 EXPORT  TIM8_UP_IRQHandler         [WEAK]
                 EXPORT  TIM8_TRG_COM_IRQHandler    [WEAK]
                 EXPORT  TIM8_CC_IRQHandler         [WEAK]
                 EXPORT  ADC3_IRQHandler               [WEAK]
                 EXPORT  FSMC_IRQHandler              [WEAK]
                 EXPORT  SDIO_IRQHandler               [WEAK]
                 EXPORT  TIM5_IRQHandler               [WEAK]
                 EXPORT  SPI3_IRQHandler               [WEAK]
                 EXPORT  UART4_IRQHandler           [WEAK]
                 EXPORT  UART5_IRQHandler           [WEAK]
                 EXPORT  TIM6_IRQHandler            [WEAK]
                 EXPORT  TIM7_IRQHandler            [WEAK]
                 EXPORT  DMA2_Channel1_IRQHandler   [WEAK]
                 EXPORT  DMA2_Channel2_IRQHandler   [WEAK]
                 EXPORT  DMA2_Channel3_IRQHandler   [WEAK]
                 EXPORT  DMA2_Channel4_5_IRQHandler [WEAK]
 ; 如下只是定义一个空函数
 WWDG_IRQHandler
 PVD_IRQHandler
 TAMPER_IRQHandler
 RTC_IRQHandler
 FLASH_IRQHandler
 RCC_IRQHandler
 EXTI0_IRQHandler
 EXTI1_IRQHandler
 EXTI2_IRQHandler
 EXTI3_IRQHandler
 EXTI4_IRQHandler
 DMA1_Channel1_IRQHandler
 DMA1_Channel2_IRQHandler
 DMA1_Channel3_IRQHandler
 DMA1_Channel4_IRQHandler
 DMA1_Channel5_IRQHandler
 DMA1_Channel6_IRQHandler
 DMA1_Channel7_IRQHandler
 ADC1_2_IRQHandler
 USB_HP_CAN1_TX_IRQHandler
 USB_LP_CAN1_RX0_IRQHandler
 CAN1_RX1_IRQHandler
 CAN1_SCE_IRQHandler
 EXTI9_5_IRQHandler
 TIM1_BRK_IRQHandler
 TIM1_UP_IRQHandler
 TIM1_TRG_COM_IRQHandler
 TIM1_CC_IRQHandler
 TIM2_IRQHandler
 TIM3_IRQHandler
 TIM4_IRQHandler
 I2C1_EV_IRQHandler
 I2C1_ER_IRQHandler
 I2C2_EV_IRQHandler
 I2C2_ER_IRQHandler
 SPI1_IRQHandler
 SPI2_IRQHandler
 USART1_IRQHandler
 USART2_IRQHandler
 USART3_IRQHandler
 EXTI15_10_IRQHandler
 RTCAlarm_IRQHandler
 USBWakeUp_IRQHandler
 TIM8_BRK_IRQHandler
 TIM8_UP_IRQHandler
 TIM8_TRG_COM_IRQHandler
 TIM8_CC_IRQHandler
 ADC3_IRQHandler
 FSMC_IRQHandler
 SDIO_IRQHandler
 TIM5_IRQHandler
 SPI3_IRQHandler
 UART4_IRQHandler
 UART5_IRQHandler
 TIM6_IRQHandler
 TIM7_IRQHandler
 DMA2_Channel1_IRQHandler
 DMA2_Channel2_IRQHandler
 DMA2_Channel3_IRQHandler
 DMA2_Channel4_5_IRQHandler
                 B       .

                ENDP

                ALIGN ; 默认是字对齐方式，也说明了代码是4字节对齐的

;*******************************************************************************
; User Stack and Heap initialization
;*******************************************************************************
;IF…ELSE…ENDIF结构，判断是否使用DEF:__MICROLIB
;若使用DEF:__MICROLIB，则将__initial_sp，__heap_base，__heap_limit亦即栈顶地址，堆始末地址赋予全局属性，使外部程序可以使用
                  IF      :DEF:__MICROLIB ;如果使用
               
                  EXPORT  __initial_sp
                  EXPORT  __heap_base
                  EXPORT  __heap_limit
                
                  ELSE
;定义全局标号__use_two_region_memory
;声明全局标号__user_initial_stackheap，这样外程序也可调用此标号

                  IMPORT  __use_two_region_memory  ; 两区堆栈空间，堆和栈有各自的空间地址
                  EXPORT  __user_initial_stackheap
                 
;标号__user_initial_stackheap，表示用户堆栈初始化程序入口
;分别保存栈顶指针和栈大小，堆始地址和堆大小至R0，R1，R2，R3寄存器
 __user_initial_stackheap
 ; 此处是初始化两区的堆栈空间，堆是从由低到高的增长，栈是由高向低生长的，两个是互相独立的数据段，并不能交叉使用

                  LDR     R0, =  Heap_Mem
                  LDR     R1, = (Stack_Mem + Stack_Size)
                  LDR     R2, = (Heap_Mem +  Heap_Size)
                  LDR     R3, = Stack_Mem
                  BX      LR

                 ALIGN

                 ENDIF

                 END  ; END 命令指示汇编器，已到达一个源文件的末尾

1、 AREA指令：伪指令，用于定义代码段或数据段，后跟属性标号。其中比较重要的一个标号为“READONLY”者“READWRITE”，其中“READONLY”表示该段为只读属性，联系到STM32的内部存储介质，具有只读属性的段保存于FLASH区，即0x8000000地址后。而“READWRITE”表示该段为“可读写”属性，“可读写”段保存于SRAM区，即0x2000000地址后。由此可以知道，堆栈段位于SRAM空间，中断向量表放置与FLASH区，而这也是整片启动代码中最先被放进FLASH区的数据。因此可以得到一条重要的信息：0x8000000地址存放的是栈顶地址__initial_sp，0x8000004地址存放的是复位中断向量Reset_Handler（STM32使用32位总线，因此存储空间为4字节对齐）。
2、 DCD指令：作用是开辟一段空间，其意义等价于C语言中的地址符“&”。因此建立的中断向量表则类似于使用C语言定义了一个指针数组，其每一个成员都是一个函数指针，分别指向各个中断服务函数。
3、 标号：前文多处使用了“标号”一词。标号主要用于表示一片内存空间的某个位置，等价于C语言中的“地址”概念。地址仅仅表示存储空间的一个位置，从C语言的角度来看，变量的地址，数组的地址或是函数的入口地址在本质上并无区别。
4、 __main标号并不表示C程序中的main函数入口地址，也并不是跳转至main函数开始执行C程序。__main标号表示C/C++标准实时库函数里的一个初始化子程序__main的入口地址。该程序的一个主要作用是初始化堆栈（对于程序清单来说则是跳转__user_initial_stackheap标号进行初始化堆栈的），并初始化映像文件，最后跳转C程序中的main函数。这就解释了为何所有的C程序必须有一个main函数作为程序的起点——因为这是由C/C++标准实时库所规定的——并且不能更改，因为C/C++标准实时库并不对外界开发源代码。至此可以总结一下STM32的启动文件和启动过程。首先对栈和堆的大小进行定义，并在代码区的起始处建立中断向量表，其第一个表项是栈顶地址，第二个表项是复位中断服务入口地址。然后在复位中断服务程序中跳转¬¬C/C++标准实时库的__main函数，完成用户堆栈等的初始化后，跳转.c文件中的main函数开始执行C程序。假设STM32被设置为从内部FLASH启动（这也是最常见的一种情况），中断向量表起始地位为0x8000000，则栈顶地址存放于0x8000000处，而复位中断服务入口地址存放于0x8000004处。当STM32遇到复位信号后，则从0x80000004处取出复位中断服务入口地址，继而执行复位中断服务程序，然后跳转__main函数，最后进入mian函数，来到C的世界。
5、函数返回和异常返回都可能用到了BX LR
函数调用的最后使用BX LR 返回，LR对应的是BL functionName的下一条指令的地址（当然如果函数中再用到了BL指令, 需要先push LR,等返回了以后再POP LR）
异常返回如果使用BX LR的形式，LR的值只不过定义了一下返回时从哪个堆栈出栈（PSP or MSP），已经没有地址的意义了，具体返回地址都是根据选择的堆栈弹出的PC值决定的。
如果LR的值不是0xffffxxxx类型的，则PC跳至LR[31:1]，而根据LR[0:0]则决定跳转后处理器进入的状态。如果LR[0:0]=1，则进入Thumb状态，否则进入ARM状态。 在CM3中不支持ARM状态，所以LR[0:0]必须是1——也就是LR必须是奇数。在CM3中，如果以0xffff开头则有特殊的含义，命名为EXC_RETURN，它指示正在从异常返回，并决定返回的方式，在《Cortex-M3权威指南》中有重点介绍